Option Explicit

Private Sub Worksheet_Change(ByVal Target As Range)
    Dim i           As Long
    Dim existingRow As Long

    If Target.Column <> 1 Or Target.Cells.Count > 1 Then Exit Sub
    If IsEmpty(Target.Value) Then Exit Sub

    Application.EnableEvents = False
    Application.ScreenUpdating = False

    With ThisWorkbook.Worksheets("Лист2")

        Dim matchRow As Variant
        matchRow = Application.Match(Target.Value, .Range("A:A"), 0)

        If Not IsError(matchRow) Then
            Target.Value = .Cells(matchRow, 1).Value
        Else
            Application.EnableEvents = True
            Application.ScreenUpdating = True
            Exit Sub
        End If

    End With

    Dim lastRow     As Long
    lastRow = Me.Cells(Me.Rows.Count, 1).End(xlUp).Row

    For i = 1 To lastRow

        If i <> Target.Row Then

            If Me.Cells(i, 1).Value = Target.Value Then
                existingRow = i
                Exit For
            End If

        End If

    Next i

    If existingRow > 0 Then

        Dim countVal As Long
        countVal = Me.Cells(existingRow, 2).Value

        Me.Cells(existingRow, 2).Value = countVal + 1
        Me.Rows(Target.Row).Delete
    Else
        Target.Offset(0, 1).Value = 1
    End If

    Application.EnableEvents = True
    Application.ScreenUpdating = True
End Sub