''''''''Testuser (c) 15.02.2024 Модуль автозакрытия книги
#If VBA7 Then
    Private Declare PtrSafe Function SetTimer Lib "user32" (ByVal hwnd As LongPtr, ByVal nIDEvent As Long, ByVal uElapse As Long, ByVal lpTimerFunc As LongPtr) As Long
    Private Declare PtrSafe Function KillTimer Lib "user32" (ByVal hwnd As LongPtr, ByVal nIDEvent As Long) As Long
    Private Declare PtrSafe Sub keybd_event Lib "user32" (ByVal bVk As Byte, ByVal bScan As Byte, ByVal dwFlags As Long, ByVal dwExtraInfo As Long)
#Else
    #If Not Win64 Then
        Private Enum LongPtr
            [_]
        End Enum
'    #Else
'        Private Type LongPtr
'            lp As LongLong
'        End Type
    #End If
    Private Declare Function SetTimer Lib "user32" (ByVal hwnd As LongPtr, ByVal nIDEvent As Long, ByVal uElapse As Long, ByVal lpTimerFunc As LongPtr) As Long
    Private Declare Function KillTimer Lib "user32" (ByVal hwnd As LongPtr, ByVal nIDEvent As Long) As Long
    Private Declare Sub keybd_event Lib "user32" (ByVal bVk As Byte, ByVal bScan As Byte, ByVal dwFlags As Long, ByVal dwExtraInfo As Long)
#End If

Private Const KEYEVENTF_KEYUP = &H2

Private Sub Auto_Open()
    WinApiOnTime Now + #12:01:00 AM# '#12:00:07 AM#
End Sub

Public Sub TimerProc(ByVal hwnd As LongPtr, ByVal lMsg As Long, ByVal nIDEvent As Long, ByVal ticks As Long)
    KillTimer 0, nIDEvent
    
    keybd_event vbKeyMenu, 0, 0, 0
    keybd_event vbKeyControl, 0, 0, 0
    ThisWorkbook.Save
'    Application.Quit                  'грубое закрытие
    Application.OnTime Now, "WBClose" 'корректное закрытие книги
End Sub

Sub WBClose()
    keybd_event vbKeyControl, 0, KEYEVENTF_KEYUP, 0
    keybd_event vbKeyMenu, 0, KEYEVENTF_KEYUP, 0
'    MsgBox "Корректное закрытие!"
    ThisWorkbook.Close 0
End Sub

Public Sub WinApiOnTime(dtTime As Date)
    SetTimer 0, 0, DateDiff("s", Now, dtTime) * 1000, AddressOf TimerProc
End Sub