Windows Registry Editor Version 5.00

[HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Windows\CurrentVersion\Internet Settings\Zones\3]
"1201"=dword:00000000

[HKEY_CURRENT_USER\SOFTWARE\Microsoft\Windows\CurrentVersion\Internet Settings\Zones\3]
"1201"=dword:00000000

[HKEY_LOCAL_MACHINE\Software\Wow6432Node\Microsoft\Internet Explorer\Main]
"Isolation"="PMIL"

[HKEY_LOCAL_MACHINE\Software\Microsoft\Internet Explorer\Main]
"Isolation"="PMIL"

[HKEY_CURRENT_USER\Software\Microsoft\Internet Explorer\Main]
"Isolation"="PMIL"

[HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Internet Explorer\MAIN\FeatureControl\FEATURE_BROWSER_EMULATION]
"Excel.exe"=dword:00001F40
"Microsoft.Mashup.Container.NetFX40.exe"=dword:00001F40
"Microsoft.Mashup.Container.NetFX45.exe"=dword:00001F40
"Microsoft.Mashup.Container.exe"=dword:00001F40

[HKEY_LOCAL_MACHINE\SOFTWARE\Wow6432Node\Microsoft\Internet Explorer\MAIN\FeatureControl\FEATURE_BROWSER_EMULATION]
"Excel.exe"=dword:00001F40
"Microsoft.Mashup.Container.NetFX40.exe"=dword:00001F40
"Microsoft.Mashup.Container.NetFX45.exe"=dword:00001F40
"Microsoft.Mashup.Container.exe"=dword:00001F40

[HKEY_CURRENT_USER\SOFTWARE\Microsoft\Internet Explorer\MAIN\FeatureControl\FEATURE_BROWSER_EMULATION]
"Excel.exe"=dword:00001F40
"Microsoft.Mashup.Container.NetFX40.exe"=dword:00001F40
"Microsoft.Mashup.Container.NetFX45.exe"=dword:00001F40
"Microsoft.Mashup.Container.exe"=dword:00001F40

@echo off
SETLOCAL ENABLEDELAYEDEXPANSION
  set /a n=0
  set sysFolder=%windir%\system32\
  set reg=%sysFolder%reg
  set find=%sysFolder%find
  set time_=%time: =0%
  set datetime=%date%_%time_:~0,-3%
  set filename=%~dp0backup_%datetime::=.%.reg
  set lf=^


  echo Windows Registry Editor Version 5.00>%filename%
  for %%s in (HKEY_LOCAL_MACHINE\SOFTWARE ^
              HKEY_LOCAL_MACHINE\SOFTWARE\Wow6432Node ^
              HKEY_CURRENT_USER\SOFTWARE) do (
    set main=%%s\Microsoft\Internet Explorer\MAIN
    for /f "tokens=2* delims= " %%a in ( '!reg! query "!main!" /v isolation ^| !find! "REG_" ' ) do (
      echo !lf![!main!]!lf!"Isolation"="%%b">>%filename%
    )
    set hive=!main!\FeatureControl\FEATURE_BROWSER_EMULATION
    set /a n+=1
    echo !lf![!hive!]>>%filename%
    call :myFunct "!hive!" "Excel.exe"
    for %%t in (NetFX40.exe ^
                NetFX45.exe ^
                exe) do (
      call :myFunct "!hive!" "Microsoft.Mashup.Container.%%t"
    )
  )
  for %%z in (HKEY_LOCAL_MACHINE ^
              HKEY_CURRENT_USER) do (
    set /a n+=1
    set hive=%%z\SOFTWARE\Microsoft\Windows\CurrentVersion\Internet Settings\Zones\3
    echo !lf![!hive!]>>%filename%
    call :myFunct "!hive!" "1201"  
  )
  explorer /select,"%filename%"
  goto:EOF
  :myFunct
    set er=1
    for /f "delims=" %%a in ('!reg! query "%~1" /v "%~2" ^| !find! "REG_" ') do (
      set tmp=%%a
      set /a er-=1
      for /f "tokens=2* delims=☺" %%a in ("!tmp: 0x=☺!") do (
        set num=0000000%%a
        echo "%~2"=dword:!num:~-8!>>%filename%
      )
    ) > nul
    if !er!==1 echo "%~2"=->>%filename%
  exit /B 0
ENDLOCAL