а надо куда?

нужно, чтобы артикул воспринимался эксом как текст в любом случае  
например, вставьте " " перед цифрами и сортируйте

странно

Нет, извиняюсь, не правильно.  
А вот если вместо пробела добавить 0 (т.е.0511, 0511A) - то ОК.

Да, там действительно много странного... Я скопировал номера из реальной базы, м.б. это как-то связано с форматом ячеек? (Там формат "# ###")  
 
(Кстати пробелы впереди легко исчезают, если выделить ячейку)  
 
А можно ли все-таки как-то макросом решить эту проблему? Чтобы Excel при сортировке понимала, что впереди - это цифры и нужно сначала отсортировать по ним?

Вариант

MCH буквы по алфавиту не сортирует! :(  
Мой алгоритм должен помочь :)

.

andre, а у Вас в конце может быть только одна буква или возможно несколько? С одной можно будет просто сделать и точно быстрее 40 сек, а с несколькими сложнее...)

По порядку или нет - это неважно. Предлагаю вот такой вариант (красивости от ув. MCH, надеюсь он не возражает:).  
ЗЫ. Если используются только прописные англ. буквы, в коде 1000 можно заменить на 100.  
<EM><STRONG>Файл удален</STRONG> - велик размер - [<STRONG>МОДЕРАТОРЫ</STRONG>]</EM>

Влад, не сортируются столбцы после пустых колонок...  
По-видимому сортируется только непрерывная область, а в реальной базе есть пробелы в данных...Выделение базы перед сортировкой не помогает...

Немного исправил код с учетом Ваших пожеланий (работает без доп. столбца). Прошу прощения за предыдущий пост, не обратил внимания, что файл "распух" после экспериментов)  
ЗЫ. Формат ячеек "# ###" замените на Общий.

{quote}{login=}{date=30.08.2012 09:16}{thema=}{post}Не знаете ли вы случайно, какой задать формат столбцу, чтобы номера с буквами выглядели так же, как и с цифрами (сейчас у меня "# ###" - номера без букв выглядят так: 14 534, а с буквами 14534A (но это, конечно, не существенно...){/post}{/quote}  
Текст можно так отформатировать только макросом, при этом лучше использовать моноширинный шрифт, например, Courier New. Код такой:  
 
Sub MySort()  
 
 ' --> Константы для настройки (вписать реальные)  
 Const DataTopRow = "A2:BW2" ' первая строка с данными  
 Const SortColumn = "A"      ' сортируемый столбец  
 ' <-- Конец констант для настройки  
 
 Dim c&, cs&, r&, rs&, s$  
 Dim a(), b()  
 Dim LastCell As Range, Rng As Range  
 
 ' Определить диапазон данных  
 With ActiveSheet.Range(DataTopRow)  
   c = .EntireRow.Columns(SortColumn).Column - .Column + 1  
   Set LastCell = .Parent.Cells.SpecialCells(xlCellTypeLastCell)  
   rs = LastCell.Row - .Row + 1  
   If rs < 2 Then MsgBox "Нет данных": Exit Sub  
   Set Rng = .Resize(rs)  
 End With  
 
 ' Создать в a() числовые значения сортируемого столбца, а в b()-отформатированные  
 a() = Rng.Columns©.Value  
 b() = a()  
 For r = 1 To rs  
   If VarType(a(r, 1)) = vbString Then  
     s = Right$(a(r, 1), 1)  
     a(r, 1) = Val(a(r, 1))  
     If s >= "A" Then  
       b(r, 1) = Format(a(r, 1), "# ###") & s  
       a(r, 1) = a(r, 1) + Asc(s) * 0.001  
     End If  
   End If  
 Next  
 
 ' Отключить перерисовку экрана  
 Application.ScreenUpdating = False  
   
 ' Отформатировать сортируемый столбец, скопировав в него b()  
 With Rng.Columns©  
   .Value = b()  
   .Font.Name = "Courier New" ' моноширинный шрифт  
   .HorizontalAlignment = xlRight  
   .NumberFormat = "# ###_."  
 End With  
   
 ' Скопировать a() правее рабочего диапазона, отсортировать и очистить  
 With Range(Rng, LastCell)  
   cs = .Columns.Count + 1  
   With .Resize(, cs)  
     .Columns(cs).Value = a  
     .Sort .Cells(1, cs), xlAscending, Header:=xlNo  
     .Columns(cs).ClearContents  
   End With  
 End With  
   
 ' Включить перерисовку экрана  
 Application.ScreenUpdating = True  
 
 ' Восстановить UsedRange  
 With Rng.Parent.UsedRange: End With  
 
End Sub

Александр, в коде используется SpecialCells(xlCellTypeLastCell) – последняя используемая ячейка, на которую устанавливается курсор по нажатию Ctrl-End.    
 
Если где-нибудь за пределами используемых ячеек (UsedRange), например, запишем в ячейку что-нибудь, а затем очистим ее содержимое, то по Ctrl-End мы уже попадем в эту очищенную (новую последнюю) ячейку. Если сохранить книгу, то последняя ячейка возвращается на свое законное место, то же самое обычно происходит при обращении к UsedRange.  
 
Код для проверки:  
 
Sub Test()  
 With Workbooks.Add.Sheets(1)  
     
   ' Добавим данные на чистый лист  
   .Range("D2:E5") = "UsedRange"  
     
   ' Проверим адрес последней ячейки  
   Debug.Print 1, .Cells.SpecialCells(xlCellTypeLastCell).Address  
     
   ' Запишем и удалим что-нибудь в ячейке правее и ниже данных  
   .Range("F10").Value = 1  
   .Range("F10").ClearContents  
     
   ' Адрес последней ячейки изменится  
   Debug.Print 2, .Cells.SpecialCells(xlCellTypeLastCell).Address  
     
   ' Восстановим правильное положение последней ячейки, просто обратившись к UsedRange  
   With .UsedRange: End With  
     
   ' Адрес последней ячейки вернется на свое место  
   Debug.Print 3, .Cells.SpecialCells(xlCellTypeLastCell).Address  
     
 End With  
End Sub