// tabParametr
let
   Source = Excel.CurrentWorkbook(){[Name="tabParametr"]}[Content],
    typed = Table.TransformColumnTypes(Source,{{"Код поставщика", Int64.Type}, {"Срок поставки", Int64.Type}, {"Дни поставки", Text.Type}, {"Периодичность", type text}, {"Частота", Int64.Type}, {"С даты", type date}, {"Дата окончания", type date}}),
    get = (rec) =>
    let
        weekDays = List.Transform(Text.Split(rec[#"Дни поставки"], ","), each Number.From(_)),
        dates = Table.FromColumns({List.Dates(rec[#"С даты"], Duration.Days(rec[#"Дата окончания"] - rec[#"С даты"]) + 1, #duration(1, 0, 0, 0))}, {"Дата поставки"}),
        addWeekDay = Table.AddColumn(dates, "День недели", each Date.DayOfWeek([#"Дата поставки"]) + 1),
        info = List.Transform(weekDays, (item) => 
        let
            daysOfWeek = Table.SelectRows(addWeekDay, each [#"День недели"] = item),
            subTable = Table.SelectRows(Table.AddIndexColumn(daysOfWeek, "idx"), each Number.Mod([idx], rec[Частота]) = 0)
        in
            subTable[[#"Дата поставки"]]
        )
    in
        Table.Combine(info),
    addCalendar = Table.AddColumn(typed, "temp", each get(_)),
    expanded = Table.ExpandTableColumn(addCalendar, "temp", {"Дата поставки"}, {"Дата поставки"}),
    addWeekDayName = Table.AddColumn(expanded, "День недели", each Date.DayOfWeekName([#"Дата поставки"], "ru-RU")),
    return = Table.Sort(addWeekDayName,{{"Код поставщика", Order.Ascending}, {"Дата поставки", Order.Ascending}})
in
    return

let
    Source = Excel.CurrentWorkbook(){[Name="tabParametr"]}[Content],
    #"Changed Type" = Table.TransformColumnTypes(Source,{{"Код поставщика", Int64.Type}, {"Срок поставки", Int64.Type}, {"Дни поставки", type text}, {"Периодичность", type text}, {"Частота", Int64.Type}, {"С даты", type date}, {"Дата окончания", type date}}),
    Custom1 = Table.TransformColumns(#"Changed Type", {{"Дни поставки", each Text.Split(_,","), type list}}),
    #"Expanded {0}" = Table.ExpandListColumn(Custom1, "Дни поставки"),
    #"Changed Type1" = Table.TransformColumnTypes(#"Expanded {0}",{{"Дни поставки", Int64.Type}}),
    #"Added Custom" = Table.AddColumn(#"Changed Type1", "Даты", (row)=> 
        let
            Даты = List.Dates(row[С даты],Duration.Days(row[Дата окончания]-row[С даты])+1,#duration(1,0,0,0)),
            Custom2 = #table(type table [Дата поставки=date], List.Zip({Даты})),
            #"Inserted Day of Week" = Table.AddColumn(Custom2, "День недели", each Date.DayOfWeek([Дата поставки],Day.Monday)+1, type number),
            #"Inserted Start of Month" = Table.AddColumn(#"Inserted Day of Week", "Начало месяца", each Date.StartOfMonth([Дата поставки]), type date),
            FilteredRows = Table.SelectRows(#"Inserted Start of Month", each [День недели] = row[Дни поставки]),
            RemovedDayOfW = Table.RemoveColumns(FilteredRows,{"День недели"}),

            AlternateWeeks = if row[Частота] > 1 then Table.AlternateRows(RemovedDayOfW, 1, row[Частота]-1, 1) else RemovedDayOfW,

            GroupedMonths = Table.Group(RemovedDayOfW, {"Начало месяца"}, {{"Дата поставки", each List.Min([Дата поставки]), type date}}),
            AlternateMonths = if row[Частота] > 1 then Table.AlternateRows(GroupedMonths, 1, row[Частота]-1, 1) else GroupedMonths,
            Alternate = if row[Периодичность] = "неделя" then AlternateWeeks else AlternateMonths
        in
            Alternate),
    #"Expanded {0}1" = Table.ExpandTableColumn(#"Added Custom", "Даты", {"Дата поставки"}, {"Дата поставки"}),
    #"Changed Type2" = Table.TransformColumnTypes(#"Expanded {0}1",{{"Дата поставки", type date}}),
    #"Sorted Rows" = Table.Sort(#"Changed Type2",{{"Код поставщика", Order.Ascending}, {"Дата поставки", Order.Ascending}}),
    #"Inserted Day Name" = Table.AddColumn(#"Sorted Rows", "Название дня", each Date.DayOfWeekName([Дата поставки]), type text),
    #"Reordered Columns" = Table.ReorderColumns(#"Inserted Day Name",{"Код поставщика", "Срок поставки", "Дни поставки", "Периодичность", "Частота", "С даты", "Дата окончания", "Название дня", "Дата поставки"})
in
    #"Reordered Columns"