Добавить исключение для макроса EXCEL

Добавить исключение для макроса EXCEL, удаление русских символов

Пользователь

Сообщений: 5 Регистрация: 25.04.2016

25.04.2016 18:07:25

Здравствуйте, есть макрос, который прописан ниже. Работает на одну функцию — удаление всех русских символов, работает хорошо. Но есть проблема, нужно сделать исключение для макроса, чтобы определенное словосочетание, или несколько слов из русских символов он не учитывал, и не удалял. (слова известны, их нужно только прописать в исключении) Можете помочь?

Код

Function Del_Rus(sStr As String)
Dim li As Long
For li = 192 To 255[/COLOR]
sStr = Replace(sStr, Chr(li), "")
Next li
sStr = Replace(sStr, Chr(168), "")
sStr = Replace(sStr, Chr(184), "")
Del_Rus = sStr
End Function

Игорь

Пользователь

Сообщений: 3695 Регистрация: 23.12.2012

25.04.2016 18:15:45

1) добавляем по очереди все слова в коллекцию

Код
dim coll as new collection coll.add "слово1" coll.add "фраза вторая"

2) меняем в тексте все фразы на $+ номер фразы+$

Код
For i = 1 To coll.count sStr = replace(sStr , coll(i), "$" & i & "$") Next i

3) выполняем замены символов вашим кодом
4) обратные замены кодов слов на слова

Код
For i = 1 To coll.count sStr = replace(sStr, "$" & i & "$" , coll(i)) Next i

Надстройки для Excel Парсинг сайтов Мониторинг цен конкурентов

tracer Пользователь Сообщений: 5 Регистрация: 25.04.2016	#3 25.04.2016 18:20:35 Спасибо за ответ. НО только я не очень пока знаю как эти макросы редактировать. Позавчера я вообще не знал об этой функции. Если не сложно, можно сразу скинуть готовый макрос, или описать более понятно)

Игорь

Пользователь

Сообщений: 3695 Регистрация: 23.12.2012

25.04.2016 19:41:19

Код

Function Del_Rus(sStr As String)
    Dim li As Long, coll As New Collection, i&

    ' добавляем по очереди все слова в коллекцию
    coll.Add "слово1"
    coll.Add "фраза вторая"

    ' меняем в тексте все фразы на $+номер_фразы+$
    For i = 1 To coll.Count
        sStr = Replace(sStr, coll(i), "$" & i & "$")
    Next i

    ' выполняем замены символов вашим кодом
    For li = 192 To 255
        sStr = Replace(sStr, Chr(li), "")
    Next li
    sStr = Replace(sStr, Chr(168), "")
    sStr = Replace(sStr, Chr(184), "")

    ' обратные замены кодов слов на слова
    For i = 1 To coll.Count
        sStr = Replace(sStr, "$" & i & "$", coll(i))
    Next i

    Del_Rus = sStr
    Set coll = Nothing
End Function

Надстройки для Excel Парсинг сайтов Мониторинг цен конкурентов

tracer Пользователь Сообщений: 5 Регистрация: 25.04.2016	#5 26.04.2016 09:39:29 Спасибо) вот теперь все отлично работает)

Читают тему