'v2
Sub myFilter()
    Dim aUniq As Variant
    aUniq = GetUniq(Sheets(1).Range("L:L"), Sheets(1).Range("K:K"))
    If IsEmpty(aUniq) Then Exit Sub
    
    PrintArray Sheets(2).Range("A:A"), aUniq
End Sub

Private Function GetUniq(rr As Range, rb As Range) As Variant
    Dim arr As Variant, brr As Variant
    arr = Intersect(rr, rr.Parent.UsedRange).Value
    brr = Intersect(Intersect(rr, rr.Parent.UsedRange).EntireRow, rb.EntireColumn).Value
    
    Dim dic As Object, bic As Object
    Set dic = CreateObject("Scripting.Dictionary")
    
    Dim ya As Long
    For ya = 1 To UBound(arr, 1)
        Select Case arr(ya, 1)
        Case "", 0
        Case Else
            Select Case brr(ya, 1)
            Case "", 0
            Case Else
                
                If dic.Exists(arr(ya, 1)) Then
                    Set bic = dic(arr(ya, 1))
                Else
                    Set bic = CreateObject("Scripting.Dictionary")
                End If
                bic(brr(ya, 1)) = Empty
                
                Set dic(arr(ya, 1)) = bic
            End Select
        End Select
    Next
    
    If dic.Count > 0 Then
        ReDim arr(1 To dic.Count, 1 To 1)
        brr = arr
        For ya = 1 To UBound(arr, 1)
            arr(ya, 1) = dic.Keys()(ya - 1)
            brr(ya, 1) = Join(dic.Items()(ya - 1).Keys(), ", ")
        Next
        
        GetUniq = Array(arr, brr)
    End If
End Function

Private Sub PrintArray(rr As Range, arr As Variant)
    With rr.Cells(rr.Rows.Count, 1).End(xlUp).Cells(2, 1).Resize(UBound(arr(0), 1), UBound(arr(0), 2))
        .Value = arr(0)
        .Columns(2).Value = arr(1)
    End With
End Sub