Поиск  Пользователи  Правила  Войти
Форумы "Планета Excel" » Вопросы по Microsoft Excel
Страницы: 1
RSS
Собрать в одну ячейку значения из многих других
 
#1
12.02.2026 22:11:40
Здравствуйте.

Помогите, пожалуйста, решить задачу.
Необходимо собрать из некоторых ячеек строки информацию в одну ячейку.
из G8, R8, O8 и т.д (выделены красным) в одну конечную ячейку.  
 
 
 
#2
12.02.2026 22:13:36
Анна Х, добрый вечер. Версия эксель какая? В новых версиях есть функция ОБЪЕДИНИТЬ(), для старых можно так (формула массива с доп столбцом):
=СЦЕП(ИНДЕКС(A8:BC8;;ПОИСКПОЗ($BI$1:$BI$11;$A$6:$BC$6;0))&"/")
Изменено: Alex - 12.02.2026 22:27:18
 
 
 
#3
12.02.2026 22:26:32
2019 года (версия 2508 (сборка 16.0.19127.20302 64-разрядная.
Эта информация нужна?
 
 
 
#4
12.02.2026 22:30:44
Анна Х, тогда так можно (формула массива) =ОБЪЕДИНИТЬ("/";ИСТИНА;ИНДЕКС(A8:BC8;;ПОИСКПОЗ($BI$1:$BI$11;$A$6:$BC$6;0)))
Изменено: Alex - 12.02.2026 22:31:08
 
 
 
#5
12.02.2026 23:15:02
Здравствуйте.
Можно с добавлением дополнительного столбца (у меня это колонка BJ). В него ввести такую формулу:

=СЦЕПИТЬ(ЕСЛИ(ДЛСТР(G8)<>0;G8;"");ЕСЛИ(ДЛСТР(K8)<>0;"/"&K8;"");ЕСЛИ(ДЛСТР(O8)<>0;"/"&O8;"");ЕСЛИ(ДЛСТР(S8)<>0;"/"&S8;"");ЕСЛИ(ДЛСТР(W8)<>0;"/"&W8;"");ЕСЛИ(ДЛСТР(AA8)<>0;"/"&AA8;"");ЕСЛИ(ДЛСТР(AE8)<>0;"/"&AE8;"");ЕСЛИ(ДЛСТР(AI8)<>0;"/"&AI8;"");ЕСЛИ(ДЛСТР(AM8)<>0;"/"&AM8;"");ЕСЛИ(ДЛСТР(AQ8)<>0;"/"&AQ8;"");ЕСЛИ(ДЛСТР(AU8)<>0;"/"&AU8;""))

И в итоговый столбец такую (проверяем если первый символ / то удаляем его):

=ЕСЛИ(ЛЕВСИМВ(BJ8;1)="/";ПРАВСИМВ(BJ8;ДЛСТР(BJ8)-1);BJ8)

Если в колонке G всегда будет значение то хватит первой формулы и дополнительный столбец не потребуется.
Изменено: Aлeкceй - 12.02.2026 23:16:14
 
 
 
#6
13.02.2026 09:29:08
Может так, Вы бы поконкретнее написали, что именно хотите видеть, судя по файлу с примером так:
Код
=ОБЪЕДИНИТЬ(" / ";1;B8:BC8)
Изменено: Msi2102 - 13.02.2026 09:32:33
 
 
 
#7
13.02.2026 15:38:24
Цитата
собрать из ...выделены красным
если критерий именно цвет, то макросом
если числа (отличные от нуля):
=ПОДСТАВИТЬ(ПОДСТАВИТЬ(СЖПРОБЕЛЫ(СЦЕП(ЕСЛИ(ЕЧИСЛО(1/A$6:BC$6);ПОДСТАВИТЬ(A8:BC8;" ";"_")&" ";"")));" ";" / ");"_";" ")
для определенных значений:
=ПОДСТАВИТЬ(ПОДСТАВИТЬ(СЖПРОБЕЛЫ(СЦЕП(ПОДСТАВИТЬ(ИНДЕКС(A8:BC8;Ч(ИНДЕКС(ПОИСКПОЗ({1:2:3:4:5:6:7:8:9:10:11};A$6:BC$6;);)));" ";"_")&" "));" ";" / ");"_";" ")
 
 
 
#8
14.02.2026 19:49:32
Цитата
написал:
Может так, Вы бы поконкретнее написали, что именно хотите видеть, судя по файлу с примером так:
Нет, так не подойдет, потому что объединится информация со всей строки, а мне нужно чтобы объединилась в одну информация только из граф, которые выделены красным.
Критерий - не цвет, а именно текст, который содержится в строке (по ячейкам, которые выделены красным). Т.е. в общую ячейку должна поспасть именно эта информация из примера
Конфета   "солнышко" / Конфета "ночка" / Вафли / Молочная начинка   цветная, вкусная
Остальные графы пустые по этой строке, поэтому только 4 значения. Сама таблица очень большая. У кого-то будет всегда пусто, потмоу что все графы будут пустые, у кого-то - только одной, а у кого-то все заполненные будут.  
 
 
 
#9
14.02.2026 20:20:56
мой вариант не подошёл из-за дополнительного столбца?
попробуйте такую формулу (может можно и задать диапазон, но так точно в объединение попадут только красные ячейки):
Код
=ОБЪЕДИНИТЬ(" / ";1;G8;K8;O8;S8;W8;AA8;AE8;AI8;AM8;AQ8;AU8)
Изменено: Aлeкceй - 14.02.2026 21:13:31
 
 
 
#10
14.02.2026 21:31:17
Здравствуйте!
Ещё вариант (у меня дома 2016, может в 2019 можно проще и короче):
Код
=ЕСЛИ(ГПР(1;$G$6:$BC$8;3;0)<>"";ГПР(1;$G$6:$BC$8;3;0);"")&ЕСЛИ(ГПР(2;$G$6:$BC$8;3;0)<>"";"/ "&СИМВОЛ(10)&ГПР(2;$G$6:$BC$8;3;0);"")&ЕСЛИ(ГПР(3;$G$6:$BC$8;3;0)<>"";"/ "&СИМВОЛ(10)&ГПР(3;$G$6:$BC$8;3;0);"")&ЕСЛИ(ГПР(4;$G$6:$BC$8;3;0)<>"";"/ "&СИМВОЛ(10)&ГПР(4;$G$6:$BC$8;3;0);"")&ЕСЛИ(ГПР(5;$G$6:$BC$8;3;0)<>"";"/ "&СИМВОЛ(10)&ГПР(5;$G$6:$BC$8;3;0);"")&ЕСЛИ(ГПР(6;$G$6:$BC$8;3;0)<>"";"/ "&СИМВОЛ(10)&ГПР(6;$G$6:$BC$8;3;0);"")&ЕСЛИ(ГПР(7;$G$6:$BC$8;3;0)<>"";"/ "&СИМВОЛ(10)&ГПР(7;$G$6:$BC$8;3;0);"")&ЕСЛИ(ГПР(8;$G$6:$BC$8;3;0)<>"";"/ "&СИМВОЛ(10)&ГПР(8;$G$6:$BC$8;3;0);"")&ЕСЛИ(ГПР(9;$G$6:$BC$8;3;0)<>"";"/ "&СИМВОЛ(10)&ГПР(9;$G$6:$BC$8;3;0);"")&ЕСЛИ(ГПР(10;$G$6:$BC$8;3;0)<>"";"/ "&СИМВОЛ(10)&ГПР(10;$G$6:$BC$8;3;0);"")&ЕСЛИ(ГПР(11;$G$6:$BC$8;3;0)<>"";"/ "&СИМВОЛ(10)&ГПР(11;$G$6:$BC$8;3;0);"")
Изменено: DAB - 14.02.2026 21:32:53
 
 
 
#11
14.02.2026 22:58:53
Исходные данные: именованный диапазон (A7:BC8) с именем «data»
pq (v1)
pq (v2)
 
 
 
#12
15.02.2026 01:53:41
Ещё вариант с пользовательской функцией на основе приёма из этой статьи:
https://www.planetaexcel.ru/techniques/7/205/
См файл
Изменено: DAB - 15.02.2026 01:54:38
 
 
 
#13
23.02.2026 17:19:43
ОГРОМНОЕ спасибо! Все получилось, все работает.

Спасибо.
 
 
 
Страницы: 1
Читают тему
Наверх