Option Explicit

Public WithEvents q1 As CommandBarButton  ' удалить столбец
Public WithEvents q2 As CommandBarButton  ' вставить столбец

Public WithEvents cb As CommandBars

Dim n As Long

Private Sub cb_OnUpdate()
  If q2 Is Nothing Then
    Init
    n = n + 1
    If Not q2 Is Nothing Then
      Set cb = Nothing
      Debug.Print n
    End If
  End If
End Sub

Private Sub q1_Click(ByVal Ctrl As Office.CommandBarButton, CancelDefault As Boolean)
    If ActiveWorkbook.Name = ThisWorkbook.Name And ActiveSheet.Name = Sheet2.Name Then
        If Selection.Rows.Count = ActiveSheet.Rows.Count Then
          If MsgBox("Вы хотите удалить " & IIf(Selection.Columns.Count = 1, "выделенный столбец", _
                    "выделенные столбцы"), vbYesNo + vbQuestion) <> vbYes Then
              CancelDefault = True
          End If
        End If
    End If
End Sub

Private Sub q2_Click(ByVal Ctrl As Office.CommandBarButton, CancelDefault As Boolean)
    If ActiveWorkbook.Name = ThisWorkbook.Name And ActiveSheet.Name = Sheet2.Name Then
        If Selection.Rows.Count = ActiveSheet.Rows.Count Then
          If MsgBox("Вы хотите вставить " & IIf(Selection.Columns.Count = 1, "столбец", "столбцы"), vbYesNo + vbQuestion) <> vbYes Then
              CancelDefault = True
          End If
        End If
    End If
End Sub

Private Sub Init()
    With Application.CommandBars
        If q1 Is Nothing Then Set q1 = .FindControl(ID:=294)
        If q2 Is Nothing Then Set q2 = .FindControl(ID:=3183)
    End With
End Sub

Private Sub Workbook_Open()
    Set cb = Application.CommandBars
    Init
End Sub