Страницы: 1
RSS
УНИК из 2+ таблиц, Формула, возвращающая уникальные элементы из 2+ таблиц, результат динамический массив
 
Давно не могу найти решение следующей ситуации:

есть 2+ умных таблиц, из них необходимо получить динамический массив уникальных элементов из них (может быть 1 столбец, может быть несколько)

пробовал в функции УНИК первый аргумент указать как (Таблица1; Таблица2), выдает ошибку

просьба подсказать решение
Excel 2021 LTSC
 
setmefree, Попробуйте так:
=УНИК(СОРТ(ВСТОЛБИК(Зарплаты[1];Премии[1];Сдельные[1])))
Вредить легко, помогать трудно.
 
Для Excel 365:
=УНИК(СОРТ(ВСТОЛБИК(Зарплаты:Сдельные!A2:A4)))
или
=УНИК(СОРТ(ТЕКСТРАЗД(ОБЪЕДИНИТЬ("|";;Зарплаты[1];Премии[1];Сдельные[1]);;"|")))
Изменено: Бахтиёр - 20.06.2024 15:07:06
 
Цитата
написал:
Попробуйте так:
можно я тоже попробую, только дай мне функцию ВСТОЛБИК... ;)
или я что-то пропустил, но мой ексель такой функции не знает.....  8-0  хех...  
Изменено: BodkhiSatva - 20.06.2024 15:04:33
 
Странное поведение
Встаньте на листе Свод
=ОБЪЕДИНИТЬ(";";1; - Выделите 3 листа Зарплаты:Сдельные!A2:A50 например - формула выведет всё перечисление через ;
и потом даст ошибку знач
Что бы это было
Код
=СОРТ(ФИЛЬТР.XML("<j><i>"&ПОДСТАВИТЬ(ОБЪЕДИНИТЬ(";";1;Зарплаты[1];Премии[1];Сдельные[1]);";";"</i><i>")&"</i></j>";"//i[not(preceding::*=.)]"))
Изменено: Тимофеев - 20.06.2024 15:13:07
 
Цитата
Тимофеев: Что бы это было
Тоже не понял прикола.
Сначала возвращает результат, если на ячейке нажать F2 потом Enter выдаёт ошибку #ЗНАЧ

Воспроизвёл такие действия во вновь созданной книге --> формула нормально отрабатывает, ошибку не выдаёт
Изменено: Бахтиёр - 20.06.2024 15:54:15
 
Цитата
написал:
setmefree , Попробуйте так:
Цитата
написал:
=УНИК(СОРТ(ВСТОЛБИК(Зарплаты:Сдельные!A2:A4)))
функция отличная, жаль мне недоступная(
спасибо за отклик
Excel 2021 LTSC
 
Цитата
setmefree:  жаль мне недоступная(
У вас должна сработать формула от Тимофеева (пост №5)
Изменено: Бахтиёр - 20.06.2024 16:12:17
 
Цитата
написал:
У вас должна сработать формула от Тимофеева (пост №5)
сработало, только результат строка
функции наподобие текствмассив нет, чтоб результат в массив превратить
Excel 2021 LTSC
 
тут подобное было . Наработки той темы можно использовать
Изменено: БМВ - 21.06.2024 12:57:40
По вопросам из тем форума, личку не читаю.
 
Цитата
написал:
тут  подобное было . Наработки той темы можно использовать
спасибо за наводку, решение найдено
Excel 2021 LTSC
 
заметил, что формулу LET обычно завершают так:

=LET(
a;111;
b;a+222;
b)

почему такая практика используется? можно же вместо строки <b;a+222;b> сразу <a+222> написать
Excel 2021 LTSC
 
Цитата
setmefree:   спасибо за наводку, решение найдено
Очень даже не плохо  ;)
ну или как в изначальном варианте - "с конца"
=LET(a;Зарплаты[1];b;Премии[1];c;Сдельные[1];d;ЧСТРОК(a);e;ЧСТРОК(b);f;ЧСТРОК( c);g;ПОСЛЕД(d+e+f);x;ЕСЛИМН(g>d+e;ИНДЕКС(c;g-d-e);g>d;ИНДЕКС(b;g-d);1;ИНДЕКС(a;g));x)
Цитата
У вас должна сработать формула от Тимофеева (пост №5)
сработало, только результат строка
странно у меня вполне работает (чуть поджал):
=ФИЛЬТР.XML("<l><i>"&ОБЪЕДИНИТЬ("</i><i>";1;Зарплаты[1];Премии[1];Сдельные[1])&"</i></l>";"//i")
Но, как где-то уже писалось, эта функция достаточно "тормознутая"
Цитата
=LET(a;111;b;a+222;b)
почему такая практика используется? можно же вместо строки <b;a+222;b> сразу <a+222> написать
можно и сразу
Так удобнее делать отладку формулы, да и вообще в любой момент можно вместо последнего аргумента, не меняя ничего до него, вставить любой параметр или выражение и посмотреть что он возвращает
Изменено: Павел \Ʌ/ - 22.06.2024 11:52:46
 
Павел \Ʌ/, мне кажется просто дело вкуса. В UDF многие сперва используюn переменную "Result" и в конце присваивают имени функции это значение. тут аналогия.
По вопросам из тем форума, личку не читаю.
 
Цитата
написал:
=ФИЛЬТР.XML("  "&ОБЪЕДИНИТЬ("  ";1;Зарплаты[1];Премии[1];Сдельные[1])&"  ";"//i")
отличное решение, реально работает, жаль лайк нельзя ставить

оптимизировал свое решение, буду решать какое использовать в работе
Excel 2021 LTSC
 
По поводу поджатия [not(preceding::*=.)] - оставляет уникальные, т.е. уник уже не нужен
Страницы: 1
Наверх