Поиск  Пользователи  Правила  Войти
Форумы "Планета Excel" » Вопросы по Microsoft Excel
Страницы: 1
RSS
поиск последнего значения в строке (нечетных столбцов), Необходимо с помощью формулы найти в диапазоне (M10:AH10) последнее значение в нечетном столбце (без VBA, без использования дополнительных столбцов)
 
#1
14.05.2025 20:01:01
Всем привет, экель 2021 (версия 2109). Помогите пожалуйста найти решение:
Необходимо с помощью формулы найти в диапазоне (M10:AH10) последнее значение в нечетном столбце (без VBA, без использования дополнительных столбцов)
 
 
 
#2
14.05.2025 20:23:19
Здравствуйте.
Попробуйте такую формулу массива в АК11
Код
=ЕСЛИОШИБКА(ИНДЕКС(A11:AH11;МАКС((Таблица1[@]<>"")*ЕНЕЧЁТ(СТОЛБЕЦ(Таблица1[@]))*СТОЛБЕЦ(Таблица1[@])));"Пусто")
Изменено: gling - 14.05.2025 22:13:01
 
 
 
#3
14.05.2025 20:33:39
=IFERROR(LOOKUP(2,1/(MOD(COLUMN(M11:AH11)-COLUMN(M11)+1,2)=1)/(M11:AH11<>""),M11:AH11),"пусто")
CTRL-SHIFT-ENTER если будет брыкаться. Проверить на 2021 не могу.
Изменено: Metanor - 14.05.2025 20:36:22
 
 
 
#4
14.05.2025 21:38:12
Цитата
написал:
=IFERROR(LOOKUP(2,1/(MOD(COLUMN(M11:AH11)-COLUMN(M11)+1,2)=1)/(M11:AH11<>""),M11:AH11),"пусто")CTRL-SHIFT-ENTER если будет брыкаться. Проверить на 2021 не могу.
функция MOD не работает
 
 
 
#5
14.05.2025 21:40:10
gling, Спасибо, работает...
 
 
 
#6
14.05.2025 21:57:30
gling, подскажите еще момент,

почему так работает:
Код
=ЕСЛИОШИБКА(ИНДЕКС(A11:AH11;МАКС((Таблица1[@]<>"")*ЕНЕЧЁТ(СТОЛБЕЦ(Таблица1[@]))*СТОЛБЕЦ(Таблица1[@])));"Пусто")
а так не работает: =ЕСЛИОШИБКА(ИНДЕКС(M11:AH11;МАКС((Таблица1[@]<>"")*ЕНЕЧЁТ(СТОЛБЕЦ(Таблица1[@]))*СТОЛБЕЦ(Таблица1[@])));"Пусто"), возвращает "пусто" ???

P.S. в исходнике опечатка (диапазон нужный M11:AH11)
 
 
 
#7
14.05.2025 22:25:29
Эта часть формулы (МАКС((Таблица1[@]<>"")*ЕНЕЧЁТ(СТОЛБЕЦ(Таблица1[@]))*СТОЛБЕЦ(Таблица1[@])))) ищет не пустой-нечётный максимальный (т.е. последний в строке) номер столбца. А так как столбцы начинают счёт с столбца А, то и в ИНДЕКС(A11:AH11 начинается со столбца А. Если использовать ИНДЕКС(M11:AH11, тогда от найденного номера столбца, надо отнять число 10, так как таблица начинается с 11 столбца, Будет так МАКС((Таблица1[@]<>"")*ЕНЕЧЁТ(СТОЛБЕЦ(Таблица1[@]))*СТОЛБЕЦ(Таблица1[@])))-10
Но наверно правильнее будет чуток подправленная формула.
Код
=ЕСЛИ(СУММ((M11:AH11<>"")*ЕНЕЧЁТ(СТОЛБЕЦ($M$1:$AH$1)));ИНДЕКС(A11:AH11;МАКС((M11:AH11<>"")*ЕНЕЧЁТ(СТОЛБЕЦ($M$1:$AH$1))*СТОЛБЕЦ($M$1:$AH$1)));"Нечётные пусты")
Изменено: gling - 14.05.2025 22:38:25
 
 
 
#8
14.05.2025 23:42:24
Вы как всегда отзывчивы, и на высоте!👌
 
 
 
#9
15.05.2025 07:51:35
Цитата
matrix39 написал:
функция MOD не работает
РАБОТАЕТ
но можно и так
=IFERROR(LOOKUP(2;1/MOD(COLUMN(M13:AH13)-COLUMN(M13)+1;2)/(M13:AH13<>"");M13:AH13);"пусто")
или
=IFERROR(LOOKUP(2;1/ISODD(COLUMN(M11:AH11)-COLUMN(M11)+1)/(M11:AH11<>"");M11:AH11);"пусто")
По вопросам из тем форума, личку не читаю.
 
 
 
#10
15.05.2025 08:05:51
pq
 
 
 
#11
15.05.2025 12:41:06
Цитата
написал:
let    from = Excel.CurrentWorkbook(){[Name="Таблица1"]}[Content],    to = Table.ToList(from,(x)=>List.Last(List.Split(x,2)){0})in    to
без VBA нужно...
 
 
 
#12
15.05.2025 12:50:43
Цитата
БМВнаписал:
РАБОТАЕТно можно и так=IFERROR(LOOKUP(2;1/MOD(COLUMN(M13:AH13)-COLUMN(M13)+1;2)/(M13:AH13<>"");M13:AH13);"пусто")или=IFERROR(LOOKUP(2;1/ISODD(COLUMN(M11:AH11)-COLUMN(M11)+1)/(M11:AH11<>"");M11:AH11);"пусто")
да, перевел на русский, работает, спасибо!
Metanor, ваша тоже работает теперь :)  спасибо!

скорректировать нужно - находить последнее числовое значение ("0+6" - текстовое значение)
 
 
 
#13
15.05.2025 14:21:19
=IFERROR(LOOKUP(2,1/(MOD(COLUMN(M11:AH11)-COLUMN(M11)+1,2))/(ISNUMBER(M11:AH11)),M11:AH11),"пусто")
пользуясь улучшениями БМВ,  убрад =1 и вставил isnumber():)
 
 
 
#14
15.05.2025 14:24:52
=IFERROR(LOOKUP(2;1/ISODD(COLUMN(M11:AH11)-COLUMN(B11)+1)/ISNUMBER(M11:AH11);M11:AH11);"пусто")
По вопросам из тем форума, личку не читаю.
 
 
 
#15
15.05.2025 14:25:22
Metanor, БМВ отлично! Спасибо
Изменено: matrix39 - 15.05.2025 14:34:38
 
 
 
#16
15.05.2025 17:44:36
Здравствуйте!
pq
 
 
 
Страницы: 1
Читают тему
Наверх