Поиск  Пользователи  Правила  Войти
Форумы "Планета Excel" » Вопросы по Microsoft Excel
Страницы: 1
RSS
Подстановка значений из другой таблицы по нескольким условиям, Прошу помочь с формулой, выдающей значения из другой таблицы при совпадении условий
 
#1
12.02.2026 16:39:55
Добрый день, Уважаемые! Прошу помочь с формулой для расчета всех наименований в одном столбце в зависимости от переменных. Чтобы не создавать отдельный столбец в кучей ЕСЛИ для каждого наименования, а прописать все условия в отдельной таблице
Изменено: Bravo9 - 12.02.2026 16:41:58
 
 
 
#2
12.02.2026 16:55:56
Код
=(((ВПР(A:A;S:X;2;0)=1)*(B2=1)+(ВПР(A:A;S:X;3;0)=1)*(C2=1)+(ВПР(A:A;S:X;4;0)=1)*(D2=1)+(ВПР(A:A;S:X;5;0)=1)*(E2=1))>0)*ВПР(A:A;S:X;6;0)
А точно серая собака 800?
 
 
 
#3
12.02.2026 17:00:25
Мог ошибиться, сейчас посмотрю. Спасибо за формулу, целый день ломал голову
 
 
 
#4
12.02.2026 17:02:04
Bravo9, добрый день. Еще вариант (формула массива)
=ЕСЛИ(СУММ(--(ИНДЕКС($T$2:$W$6;ПОИСКПОЗ(A2;$S$2:$S$6;0);ПОИСКПОЗ($B$1:$E$1;$T$1:$W$1;0))=B2:E2))=СУММ(--ЕЧИСЛО(ИНДЕКС($T$2:$W$6;ПОИСКПОЗ(A2;$S$2:$S$6;0);0)));ВПР(A2;$S$2:$X$6;6;0);0)
 
 
 
#5
12.02.2026 17:04:11
По3 3, 0 и 0 совпало, значит 800. Типа если Собака точно не Белая и не Синяя, то 800, а все другие нас не волнуют, там 0
 
 
 
#6
12.02.2026 17:08:22
Цитата
написал:
ЕСЛИ(СУММ(--(ИНДЕКС($T$2:$W$6;ПОИСКПОЗ(A2;$S$2:$S$6;0);ПОИСКПОЗ($B$1:$E$1;$T$1:$W$1;0))=B2:E2))=СУММ(--ЕЧИСЛО(ИНДЕКС($T$2:$W$6;ПОИСКПОЗ(A2;$S$2:$S$6;0);0)));ВПР(A2;$S$2:$X$6;6;0);0)
Кошка должна содержать Белый цвет, и не должна содержать Зеленый. Наличие или отсутствие остальных цветов нас не волнует. Формула работает только на наличие, но все равно спасибо
 
 
 
#7
12.02.2026 17:14:15
так?
=ЕСЛИ(СУММПРОИЗВ(--(B2:E2=ИНДЕКС(T$2:W$6;ПОИСКПОЗ(A2;S$2:S$6;);)))=2;ВПР(A2;S$2:X$6;6;);)
 
 
 
#8
12.02.2026 17:18:02
Цитата
написал:
=ЕСЛИ(СУММПРОИЗВ(--(B2:E2=ИНДЕКС(T$2:W$6;ПОИСКПОЗ(A2;S$2:S$6;)))=2;ВПР(A2;S$2:X$6;6;)
А так все работает просто отлично, спасибо Вам большое! Сейчас буду разбираться как устроена формула. Еще раз большое Спасибо!
 
 
 
#9
12.02.2026 19:02:00
Цитата
написал:
Формула работает только на наличие
А можно по подробнее о каком наличии идет речь? Во-вторых, Чем результат мной предложенной формулы отличается от результата ПавелW, ? В-третьих, в таблице 2 всегда только 2 цвета указано Истина/Ложь?, Если нет, то формула от ПавелW, выдаст неверный результат, т.к. явно указано
Цитата
написал:
)))=2
А так принцип работы наших формул похож, если что :)  
Изменено: Alex - 12.02.2026 19:06:09
 
 
 
#10
12.02.2026 19:33:18
Там где 1, формула работает, а где 0 нет. Просто вставьте пожалуйста формулу от Павла и сравните с Вашей
 
 
 
#11
12.02.2026 19:37:07
Bravo9, так а я что в приложенном файле сделал? Вы файл хоть окрывали?
Изменено: Alex - 12.02.2026 19:37:56
 
 
 
#12
12.02.2026 20:07:08
Ой, извините, не туда посмотрел. Спасибо большое, все работает!  
 
 
 
#13
13.02.2026 15:49:40
Цитата
Alex,   Чем результат мной предложенной формулы отличается от результата ПавелW
решения действительно похожи (честно не подглядывал))
Цитата
в таблице 2 всегда только 2
достаточно вместо двойки подставить СЧЁТ(ИНДЕКС(T$2:W$6;ПОИСКПОЗ(A2;S$2:S$6;);))
Bravo9, можно  и без "табл2":
=ВЫБОР(ПОИСКПОЗ(A2;{"Кошка":"Собака":"Лошадь":"Корова":"Коза"};);И(B2=1;E2=0)*1000;И(B2=0;D2=0)*800;И(B2=1;C2=0)*500;И(B2=1;D2=0)*250;И(B2=1;D2=1)*1500)
 
 
 
#14
13.02.2026 16:33:38
Вот ещё вариант массивный
=ЕСЛИ(СУММ(--ЕСЛИОШИБКА(($T$2:$W$6/($S$2:$S$6=A2))=B2:E2;0))>1;ВПР(A2;$S$2:$X$6;6;0);0)
 
 
 
#15
13.02.2026 19:20:24
ПавелW,  Смысл этой таблицы чтобы не писать 100 условий ЕСЛИ(И. В табличку вставил 1, 0 и условия ЕСЛИ работают, каждый раз не надо прописывать и менять удобно. Спасибо
 
 
 
#16
14.02.2026 07:43:16
можно и так:
=ВПР(A2;S$2:X$6;6;)*(СУММПРОИЗВ((S$2:S$6=A2)*((T$2:W$6=B2:E2)=ЕЧИСЛО(T$2:W$6)))=4)
...где 4 - общее кол-во критериев
 
 
 
Страницы: 1
Читают тему
Наверх