Поиск  Пользователи  Правила  Войти
Форумы "Планета Excel" » Вопросы по Microsoft Excel
Страницы: 1
RSS
Расчет итоговой суммы компенсации аренды жилья в зависимости от периода договора аренды, Расчет итоговой суммы компенсации аренды жилья в зависимости от периода договора аренды
 
#1
28.07.2026 08:59:02

Здравствуйте!
Помогите пожалуйста с формулой для расчета суммы компенсации аренды жилья в зависимости от периода договора аренды:
Данные:
1) Стоимость аренда 1 месяца по договору 50 000 рублей;
 2) Срок действия договора с 20.09.2026 по 20.02.2027.
Найти итоговую сумму за весь период.

Решение:
(50 000 руб / 30 кал.дн сент х 11 кал.дн. действия в сент) за первый неровный месяц + 4 полных месяца (окт-янв) х 50 000 руб + (50 000 / 28 к.д. х 20 к.д) последний неровный месяц =18333,33+200000+35714,29=254 047,62 (должно так получится)
 
 
 
#2
28.07.2026 09:31:27
Файл Excel не получается вложить
 
 
 
#3
28.07.2026 09:36:22
AlexeyKuz, =(ДатаОкончания-ДатаНачала)*50000/30, если считать подолжительность месяца в среднем 30 дней
 
 
 
#4
28.07.2026 09:40:36
Спасибо, но тут точность нужна как в ручном расчете
 
 
 
#5
28.07.2026 10:01:40
Цитата
AlexeyKuz написал:
точность нужна как в ручном расчете
тогда так =(DAYSINMONTH(D4)-DAY(D4)+1)*F4/DAYSINMONTH(D4)+DAY(E4)*F4/DAYSINMONTH(E4)+DATEDIF(D4;DATE(YEAR(E4);MONTH(E4);1);"m")*F4

в D4 начальная дата, в E4 - конечная, F4 - платеж за месяц

на русском наверное так =(ДНЕЙВМЕС(D4)-ДЕНЬ(D4)+1)*F4/ДНЕЙВМЕС(D4)+ДЕНЬ(E4)*F4/ДНЕЙВМЕС(E4)+РАЗНДАТ(D4;ДАТА(ГОД(E4);МЕСЯЦ(E4);1);"m")*F4
 
 
 
#6
28.07.2026 10:24:13
DEl
Изменено: Muxa K - 28.07.2026 12:49:29 (Да. всё не верно.)
 
 
 
#7
28.07.2026 10:31:58
Muxa K, посчитайте по своей формуле для конечной даты 19.02.2027
 
 
 
#8
28.07.2026 10:40:19
Del
Изменено: Muxa K - 28.07.2026 12:49:02 (Да. всё не верно.)
 
 
 
#9
28.07.2026 11:19:44
Цитата
Muxa K написал:
Так вроде всё норм:
а теперь для 21.02.2027 :)
 
 
 
#10
28.07.2026 13:56:42
Цитата
bigorq написал:
а теперь для 21.02.2027
Паразитируя на Вашей формуле, русский вариант получился такой:
Код
=(ДЕНЬ(КОНМЕСЯЦА(A1;0))-ДЕНЬ(A1)+1)/ДЕНЬ(КОНМЕСЯЦА(A1;0))*C1+ДЕНЬ(B1)/ДЕНЬ(КОНМЕСЯЦА(B1;0))*C1+РАЗНДАТ(КОНМЕСЯЦА(A1;0)+1;ДАТА(ГОД(B1);МЕСЯЦ(B1);1);"m")*C1

A1 — начальная дата;
B1 — конечная дата;
C1 — аренда в месяц.
p.s. и как назло сегодня работы навалили.
 
 
 
#11
28.07.2026 14:00:25
Здравствуйте.
Если договор на месяц, без учёта дней в месяце, следовательно за январь и за февраль плата должна быть одинаковой. Значит, если нет отговорки о длительности месяца в днях, стоимость за любой месяц =50000 руб.
Попробуйте
Код
=РАЗНДАТ(ДатаНачала;ДатаКонца;"M")*50000
Изменено: gling - 28.07.2026 14:12:33
 
 
 
#12
28.07.2026 15:18:45
добавил файл
 
 
 
#13
28.07.2026 15:19:34
Не получается вложить файл с данными, можете пожалуйста расчет в Excel скинуть
 
 
 
#14
28.07.2026 17:39:15
Цитата
AlexeyKuz написал:
расчет в Excel
в excel оказывается нет ДНЕЙВМЕС(), заменил на ДЕНЬ(КОНМЕСЯЦА())
 
 
 
#15
28.07.2026 18:03:55
Расчет из сообщения #1 можно выполнить по формуле:
Код
=СУММПРОИЗВ(((A1+СТРОКА(1:365)-1)>=A1)*((A1+СТРОКА(1:365)-1)<=B1)*C1/ТЕКСТ(КОНМЕСЯЦА((A1+СТРОКА(1:365)-1);0);"Д"))

при условии как уже было написано ранее

Цитата
написал:
A1 — начальная дата;
B1 — конечная дата;
C1 — аренда в месяц.

Изменено: gling - 28.07.2026 18:08:32
 
 
 
#16
28.07.2026 20:54:05
Еще вариант. Вроде корректно работает в соответствии с описанным в первом сообщении алгоритмом.
=C2*(DAY(EOMONTH(A2;0)-A2+1)/DAY(EOMONTH(A2; 0))+(YEAR(B2)-YEAR(A2))*12+MONTH(B2)-MONTH(A2)-1+DAY(B2)/DAY(EOMONTH(B2; 0)))

Вариант от gling, дает другой результат. Указал в файле.

В одном не разобрался. Если выставить нач. дату 20.09.2026 и дату окончания 20.10.2026 то сумма составит 50,591.40. Почему - не понятно. Проверил с другими вариантами, результат тот же.
 
 
 
#17
28.07.2026 21:26:53
Цитата
memo написал:
Почему - не понятно
потому что из 31 дня 20 считаются по 1612 руб с мелочью. Интереснее если нач. дата 30.09.2026 а конечная 30.10.2026. У меня получается 50053.76, у вас 100053,76
 
 
 
#18
28.07.2026 21:44:21
Цитата
bigorq написал:
Интереснее если нач. дата 30.09.2026 а конечная 30.10.2026. У меня получается 50053.76, у вас 100053,76
Странно, конечно, что у вас так считается,
Скрин

Цитата
bigorq написал:
потому что из 31 дня 20 считаются по 1612 руб с мелочью.
А это точно отвечает условиям контракта?
Хотя, перепроверил и видимо, да.
Изменено: memo - 28.07.2026 21:58:33
 
 
 
#19
28.07.2026 22:32:19
Цитата
memo написал:
Странно, конечно
возможно calc врёт, хотя разобрался начало летоисчисления разное DAY(EOMONTH(A2;0)-A2+1) возвращает в calc 31
Изменено: bigorq - 28.07.2026 22:33:22
 
 
 
#20
28.07.2026 23:00:13
Цитата
bigorq написал:
DAY(EOMONTH(A2;0)-A2+1) возвращает в calc 31
А если так: (DAY(EOMONTH(A2;0))-DAY(A2)+1)?
 
 
 
#21
28.07.2026 23:02:21
Цитата
memo написал:
А если так:
так 1
 
 
 
#22
28.07.2026 23:09:11
Цитата
написал:
Вариант от  gling , дает другой результат. Указал в файле.
Результат тот же. Вы чутка изменили формулу вместо КОНМЕСЯЦА((A2+..... , прописали КОНМЕСЯЦА((B2+......
И наверно всё же дату окончание не надо включать в расчёт, а то получится двойная оплата за этот день, при заключении другого договора где эта дата будет являться началом арены.
Эту часть нужно записать без равенства, так: ((A2+СТРОКА(1:365)-1)>=A2)*((A2+СТРОКА(1:365)-1)<B2)
Или можно ещё вариант:
Код
=РАЗНДАТ(A2;B2;"M")*C2+РАЗНДАТ(A2;B2;"MD")*(C2/ДЕНЬ(КОНМЕСЯЦА(B2;0)))

Но конечно же результат будет другим. А который из них больше подходит, пусть автор сам выбирает.

Но делить стоимость аренды на количество дней в месяце и потом складывать, я считаю не правильно. Если хотите считать по дням, то лучше наверно в договоре оговаривать суточную аренду, так будет более точно. Ведь месяц это с первого до первое (исключительно) или с 20 по 20 (исключительно), а за остальные дни добирать уже разделив на количество дней в месяце, как в предложенном варианте выше.

Тоже конечно вариант не точного расчета, так как при переходящем месяце расчет ведется по длине месяца окончания договора. Но можно попробовать и это как то обыграть.

Всё на усмотрение автора.

Изменено: gling - 29.07.2026 00:06:54
 
 
 
#23
28.07.2026 23:29:22
Цитата
bigorq написал:
так 1
Значит Calc так считает.
OFF: От себя добавлю, что одно время я в нем работал, и не понравилось.
gling,
Вы правы, был невнимателен. Пошагово проверял и еще удивлялся почему не совпадает  :)
 
 
 
#24
29.07.2026 08:49:47
Цитата
написал:
Цитата AlexeyKuz  написал:расчет в Excelв excel оказывается нет ДНЕЙВМЕС(), заменил на ДЕНЬ(КОНМЕСЯЦА())

Прикрепленные файлы
AlexeyKuz_1.xlsx  (8.02 КБ)
Спасибо! А возможно формулу допилить на случай, если действие договора например в одном месяце с 01.07. по 15.07., сейчас в таком случае выходит в формуле ошибка
 
 
 
#25
29.07.2026 09:37:51
Цитата
AlexeyKuz написал:
А возможно формулу допилить
Когда начальная и конечная даты в одном месяце, то формула суммирует долю первого месяца и долю последнего месяца, что даёт некорректный результат.
Как вариант:
Код
=ЕСЛИ(КОНМЕСЯЦА(A1;0)=КОНМЕСЯЦА(B1;0);(B1-A1+1)/ДЕНЬ(КОНМЕСЯЦА(A1;0))*C1;(ДЕНЬ(КОНМЕСЯЦА(A1;0))-ДЕНЬ(A1)+1)/ДЕНЬ(КОНМЕСЯЦА(A1;0))*C1+ДЕНЬ(B1)/ДЕНЬ(КОНМЕСЯЦА(B1;0))*C1+РАЗНДАТ(КОНМЕСЯЦА(A1;0)+1;ДАТА(ГОД(B1);МЕСЯЦ(B1);1);"m")*C1)
 
 
 
#26
29.07.2026 09:39:49
В файле несколько вариантов, проверяйте, выбирайте.
 
 
 
#27
29.07.2026 14:30:25
Спасибо большое! Вариант №1 точно как надо!
 
 
 
Страницы: 1
Читают тему
Наверх