Поиск  Пользователи  Правила  Войти
Форумы "Планета Excel" » Вопросы по Microsoft Excel
Страницы: 1
RSS
вычисление значения на основе текста в других ячейках
 
#1
28.08.2026 10:13:40

Добрый день! Подскажите, как сделать, чтобы значение в столбце С (Вывод) вычислялось автоматически исходя из значений столбца А (было) и B (стало), как в образце?
 
 
 
#2
28.08.2026 10:22:36
Добрый день! Вариант в файле.
Код
=ЕСЛИ(A2=B2; "без изменений"; СЦЕП("был "; ВПР(A2; $I$2:$J$4; 2; 0); " - стал "; ВПР(B2; $I$2:$J$4; 2; 0)))
 
 
 
#3
28.08.2026 10:23:32
Код
=ЕСЛИ(A2=B2;"без изменений";ПОДСТАВИТЬ(ПОДСТАВИТЬ(ПОДСТАВИТЬ("был "&A2&" - стал "&B2;"green";"зеленый");"red";"красный");"yellow";"желтый"))
но если наименований(цветов) много - лучше делать через таблицу подстановок:
Код
=ЕСЛИ(A2=B2;"без изменений";"был "&ВПР(A2;$K$2:$L$4;2;0)&" - стал "&ВПР(B2;$K$2:$L$4;2;0))
в $K$2:$L$4 таблица вида:
red красный
green зеленый
yellow желтый
Даже самый простой вопрос можно превратить в огромную проблему. Достаточно не уметь формулировать вопросы...
 
 
 
#4
28.08.2026 11:17:16
Здравствуйте.
Ещё вариант для трёх цветов
Код
=ЕСЛИ(A2=B2; "без изменений";"был "&ПРОСМОТР(A2;{"green";"red";"yellow"};{"зеленый";"красный";"желтый"})&" - стал "&ПРОСМОТР(B2;{"green";"red";"yellow"};{"зеленый";"красный";"желтый"}) )
 
 
 
#5
28.08.2026 11:24:44
эта задача больше для новых функций =TRANSLATE(A2;"en";"ru")
 
 
 
#6
28.08.2026 12:18:04
Цитата
написал:
Ещё вариант для трёх цветов
Спасибо, ваш вариант наиболее подходящий.
 
 
 
#7
28.08.2026 16:29:46
как вариант:
=ЕСЛИ(B2<>A2;СЦЕП({"был ";" - стал "}&ВПР(A2:B2;{"green";"зеленый":"red";"красный":"yellow";"желтый"};2;));"без изменений")
 
 
 
Страницы: 1
Читают тему
Наверх