Страницы: 1
VBA всех значений с подстановкой данных
 
Доброго времени суток. Есть таблица с выгрузкой. Данные потом загружаются в другую программу, но предварительно их необходимо привести к виду как на листе "что должно получиться". Нужно чтобы макрос искал в столбце В значение 10 и подставлял в напротив в стоблцы H и I значения из макроса. Проблема в том что "десяток" может не быть, а может быть много. Макрос (большая часть записана макрорекордером) который есть сейчас, находит только первое значение.
Прошу помощи в доработке макроса.
 
Забыл прикрепить файл.
 
А что такое "VBA всех значений"? Это на каком языке?
Я сам - дурнее всякого примера! ...
 
Цитата
kuklp написал:
А что такое "VBA всех значений"?
*поиск всех значений.
 
Удаляйте пустые строки снизу и пустые столбцы справа...
Обратите внимание размер Вашего ужатого файла и моего
Код
Function DataQ(ByVal dataField As String, ByVal dataValue As Variant, _
  Optional ByVal parField, Optional ByVal parVal)
'dataField - заголовок столбца где поиск
'dataValue - что ищем (если пустая, то проставит значения в каждую строку)
'parField - массив заголовков столбцов с параметрами
'parVal - массив со вставляемыми значениями в соответственном порядке
'данные вставляются только в существующие заранее столбцы
Dim a, a2, i As Long, i2 As Long, j As Long, rng As Range
Set rng = Sheets("База").Cells(1).CurrentRegion ' лист источник
a = rng.Value
Set rng = Sheets("Выборка").Cells(1).CurrentRegion ' лист приемник
rng.Offset(1).ClearContents
Set rng = rng.Resize(UBound(a))
ReDim a2(1 To UBound(a), 1 To rng.Columns.Count)
For i = 1 To UBound(a2, 2)
  a2(1, i) = rng.Cells(i)
Next
For i2 = 1 To UBound(a2, 2)
  For i = 1 To UBound(a, 2)
    If a2(1, i2) = a(1, i) Then
      For j = 1 To UBound(a)
        a2(j, i2) = a(j, i)
      Next
      Exit For
    End If
  Next
Next
If IsArray(parField) Then
  ReDim c(LBound(parField) To UBound(parField))
  ReDim p(LBound(parField) To UBound(parField))
  i = LBound(parField) - 1
  For j = LBound(parField) To UBound(parField)
    For i2 = 1 To UBound(a2, 2)
      If a2(1, i2) = parField(j) Then
        i = i + 1
        c(i) = i2
        If j <= UBound(parVal) Then p(i) = parVal(j)
        Exit For
      End If
    Next
  Next
  If i >= LBound(c) Then
    ReDim Preserve c(LBound(c) To i)
    ReDim Preserve p(LBound(p) To i)
  Else
    Exit Function
  End If
Else
  If IsMissing(parField) Then Exit Function
End If
For i2 = 1 To UBound(a2, 2)
  If a2(1, i2) = dataField Then Exit For
Next
If i2 > UBound(a2, 2) Then Exit Function
a = 0
For j = 2 To UBound(a2)
  If a2(j, i2) = dataValue Or dataValue = "" Then
    For i = LBound(c) To UBound(c)
      a2(j, c(i)) = p(i)
    Next
    a = a + 1
  End If
Next
rng.Value = a2
DataQ = a
End Function

Sub ПримерПрименения()
Dim k
k = DataQ("Результат", 10, Array("par1", "par2"), Array(1100181645062#, 1800000000181#))
MsgBox ("Найдено записей " & k)
'Call DataQ("Результат", "", Array("par3"), Array(9999))'или так можно
End Sub
Изменено: AAF - 21.07.2017 05:54:29
 
AAF, большое спасибо! Работает:)
Страницы: 1
Читают тему
Наверх