Страницы: 1
Поиск адреса ячейки по 2 параметрам и подстановка в нее определенных значений
 
Добрый день. Прошу помощи. Столкнулся с проблемой. Есть некая база : Лист 5
На Листе3 реализована функция считывания штрих кода и определение что есть что (номер заказа, код операции и соответственно вид операции)
Необходимо, чтобы программа Искала ячейку в Листе 5 соответствующую Значениям из Листа3 (например № заказа 6440 и Раскрой) и вставляла в эту ячейку данные из Колонки "Дата" на Листе3. И т.д. Учитывая, что сканер работает в режиме клавиатуры, то последующие вводы значений записываются в следующую ячейку.
 
las23rus,
Почему на листе5 нет колонки Докрой?
 
Kuzmich, Это не принципиально..Я показал пример хотя бы из 3 операций..У меня их порядка 25..Если понять суть в одной, то потом можно и с остальными разобраться.
 
Вам нужно на Лист5 подтянуть даты Раскроя, Фрезеровки и т.д. с Лист3 в зависимости от №заказа?
 
Kuzmich,Совершенно верно. + Как Вы видите на листе 3 при вводе со сканера новое значение вводится в новую строку. Если можно было бы реализовать "окно ввода" статическое и из этого окна данные подтягивались в ячейки было бы еще круче)...Моей головы к сожалению на такое не хватает..
 
На Листе5 делаете вашу кнопочку и к ней привязываете макрос, который  № заказа из столбца G
ищет на Листе3 и подтягивает даты в соответствующие столбцы Лист5
Код
Sub iZakaz()
Dim i As Long
Dim iLastRow As Long
Dim FoundCell As Range
Dim FAdr As String
Dim Stolb As Integer
   iLastRow = Cells(Rows.Count, "G").End(xlUp).Row
   Range("J3:L" & iLastRow).ClearContents
 With Worksheets("Лист3")
  For i = 3 To iLastRow
    Set FoundCell = .Columns(3).Find(Cells(i, "G"), , xlValues, xlWhole)
     If Not FoundCell Is Nothing Then
      FAdr = FoundCell.Address
      Do
        Select Case FoundCell.Offset(, 2)
          Case "Раскрой"
            Stolb = 10
          Case "Фрезеровка"
            Stolb = 11
           Case "Шлифовка заготовки"
            Stolb = 12
         Case "Докрой"
            Stolb = 13
        End Select
         Cells(i, Stolb) = FoundCell.Offset(, -1)
         Cells(i, Stolb).NumberFormat = "dd.mm.yyyy"
       Set FoundCell = .Columns(3).FindNext(FoundCell)
      Loop While FoundCell.Address <> FAdr
     End If
  Next
 End With
End Sub
 
Kuzmich, Спасибо Огромнейшее..
 
Kuzmich, Добрый день. Прошу прощения за беспокойство. Попробовал Ваш макрос подстроить под окончательную мою таблицу на примере первых  8 операций.
Выдает ошибку суть которой уловить не могу.
Не могли бы Вы посмотреть.
 
В редакторе VBE зайдите в Tools - References...- найдите строку начинающуюся с MISSING.. и снимите на ней галочку
Согласие есть продукт при полном непротивлении сторон
 
Sanja,это немного не то..такого нет.
 
Цитата
Выдает ошибку суть которой уловить не могу.
У вас на листе "общий" в столбце G кроме номера заказа есть пустые ячейки и ячейки с символом *, которые и приводят к ошибке
Код
Sub iZakaz()
Dim i As Long
Dim iLastRow As Long
Dim FoundCell As Range
Dim FAdr As String
Dim Stolb As Integer
   iLastRow = Cells(Rows.Count, "G").End(xlUp).Row
   Range("M2:L" & iLastRow).ClearContents
 With Worksheets("ввод")
  For i = 3 To iLastRow
    If Cells(i, "G") <> "" And Cells(i, "G") <> "*" Then
    Set FoundCell = .Columns(3).Find(Cells(i, "G"), , xlValues, xlWhole)
     If Not FoundCell Is Nothing Then
      FAdr = FoundCell.Address
      Do
        Select Case FoundCell.Offset(, 2)
         Case "Раскрой Сигма"
            Stolb = 13
          Case "Раскрой пратикс"
            Stolb = 14
           Case "Фрезерование ЧПУ"
            Stolb = 15
         Case "Пресование шпона (Альбико)"
            Stolb = 16
         Case "Раскрой кромки шпон"
            Stolb = 17
         Case "Кромление шпон"
            Stolb = 18
         Case "Кромление ЛДСП"
            Stolb = 19
         Case "Сборка рамки"
            Stolb = 20
                End Select
         Cells(i, Stolb) = FoundCell.Offset(, -1)
         Cells(i, Stolb).NumberFormat = "dd.mm.yyyy"
       Set FoundCell = .Columns(3).FindNext(FoundCell)
      Loop While FoundCell.Address <> FAdr
     End If
    End If
  Next
 End With
End Sub
 
Kuzmich,Просто человечище)))..Спасибо..Респект!!
Страницы: 1
Читают тему
Наверх