Страницы: 1
Замена множества вложенных функций "ЕСЛИ", не макросом; не формулой массива.
 
Добрый день.
Возникла необходимость заменить работу макроса на формулу. Получилась формула с 12-ю вложенными "ЕСЛИ".
Но в связи с разными версиями установленного офиса на рабочих машинах - теперь необходимо избавиться от множества вложенных "ЕСЛИ".
Код
=ИНДЕКС(ЕСЛИ(AF3>0;Лист2!$G$2:$G$3;ЕСЛИ(AH3>0;Лист2!$H$2:$H$3;ЕСЛИ(AJ3>0;Лист2!$I$2:$I$3;ЕСЛИ(AL3>0;Лист2!$J$2:$J$3;ЕСЛИ(AN3>0;Лист2!$K$2:$K$3;
ЕСЛИ(AP3>0;Лист2!$L$2:$L$3;ЕСЛИ(AR3>0;Лист2!$M$2:$M$3;ЕСЛИ(AT3>0;Лист2!$N$2:$N$3;ЕСЛИ(AV3>0;Лист2!$O$2:$O$3;ЕСЛИ(AX3>0;Лист2!$P$2:$P$3;
ЕСЛИ(AZ3>0;Лист2!$Q$2:$Q$3;ЕСЛИ(BB3>0;Лист2!$R$2:$R$3;Лист2!$F$2:$F$3))))))))))));ПОИСКПОЗ(Лист1!L3;Лист2!$A$2:$A$3;0))
Получается: по уникальному номеру необходимо найти и подтянуть цену со второго листа соответственно требуемого месяца. Т.е. если на первом листе AN3>0 (строка 3) то со второго листа подтягиваем значение из K3.
Возможно ли это и если ДА то как?
 
чем формула массива не нравится?
 
В связи с большим объёмом более 30 000 строк файл будет постоянно пересчитываться и тормозить. Ведь формула массива является летучей?
 
а какая логика у Вас заложена, если данные введены по нескольким месяцам: первое число по порядку?
 
mamalot, вот вариант не менее громоздкий, хотя и без вложенности:
Код
=ИНДЕКС(
   Лист2!$G$2:$R$3;
   ПОИСКПОЗ($L2;Лист2!$A$2:$A$3;0);
   ЛЕВСИМВ(
      ПОДСТАВИТЬ(
         СЦЕПИТЬ(
            (AF2>0)*(10*$AF$1);
            (AH2>0)*(10*$AH$1);
            (AJ2>0)*(10*$AJ$1);
            (AL2>0)*(10*$AL$1);
            (AN2>0)*(10*$AN$1);
            (AP2>0)*(10*$AP$1);
            (AR2>0)*(10*$AR$1);
            (AT2>0)*(10*$AT$1);
            (AV2>0)*(10*$AV$1);
            (AX2>0)*(10*$AX$1);
            (AZ2>0)*(10*$AZ$1);
            (BB2>0)*(10*$BB$1)
            );
         "0";
         ""
      );
   1)
)
In GoTo we trust
 
вместо агрегата другой функции не придумал.
Код
=ВЫБОР((АГРЕГАТ(15;6;СТОЛБЕЦ($A$1:$AA$1)/($AF2:$BC2>0);1)-1)/2+1;Лист2!G2;Лист2!H2;Лист2!I2;Лист2!J2;Лист2!K2;Лист2!L2;Лист2!M2;Лист2!N2;Лист2!O2;Лист2!P2;Лист2!Q2;Лист2!R2)
массивная
Код
=ГПР(МИН(ЕСЛИ(AF2:BC2>0;$AF$1:$BC$1));Лист2!$G$1:$R$3;СТРОКА(M2);0)
Изменено: copper-top - 25.08.2017 16:38:15
 
Формулы массива не волатильны в общем виде.
Такое родилось: =ИНДЕКС(Лист2!G2:R2;(1+МИН(ЕСЛИ(AF1:$BB$1*AF2:BB2;СТОЛБЕЦ(AG1:BC1)-СТОЛБЕЦ(AF2);"")))/2)[/COLOR]
Соблюдение правил форума не освобождает от модераторского произвола
 
Vladimir Chebykin или первый или последний месяц.
Буду разбираться.
Спасибо всем.
Страницы: 1
Читают тему
Наверх