Страницы: 1
Разделить таблицу на несколько согласно правилу
 
Добрый день (вечер) форумчане. Прошу извинить если подобный вопрос поднимался!
Нужна помощь специалистов по решению следующей проблемы.
Необходимо написать макрос или реализовать с помощью формул следующую идею.
Есть таблица состоящая из одного столбца и множества строк, пример

Ссылка_1
текст1
текст2
текст3
Текст_искл.
Ссылка_2
Текст4
текст_искл
текст5
Ссылка_1
.....
Ссылка_2
и т.д.

Необходимо:
- скопировть в одтельную таблицу (отдельный столбец) строки между строками "Ссылка_1" и "Ссылка_2"
- в другую таблицу (столбец) строки между строками "Ссылка_2" и "Ссылка_1"
- при этом исключить из новых таблиц (столбцов) строки содержащие "текст_искл"
Изменено: ARan - 30.12.2017 09:35:45 (исправил файл примера)
 
файл-пример. как есть-как надо
Согласие есть продукт при полном непротивлении сторон
 
Добавил файл примера
 
В примере "Ссылка2" - два раза в столбце. Что делать? Как узнать от какой "Ссылка 1"  и до какой "Ссылка 2" копировать? И от какой "Сылка2"  до какой "Ссылка1"? У Вас их же много, может их обозначить как-то, чтобы первая Ссылка2 - это 1, вторая ссылка2 - это 2 и т.д.? Как узнать-то, между каким "Ссылками" копировать?
 
ARan, вот код, который работает с примером в точности как описано. Что там на самом деле является "ссылкой" и "исключением" - мне неизвестно, так что допиливайте сами.
Код
Sub Aran()
Dim v(), i&, j&, k&, kmax&
  v = Range("A2", Cells(Rows.Count, "A").End(xlUp)).Value
  ReDim w$(1 To UBound(v), 1 To UBound(v) \ 2)
  For i = 1 To UBound(v)
    If LCase$(v(i, 1)) Like "ссылка*" Then
      j = j + 1: k = 0
    ElseIf Not LCase$(v(i, 1)) Like "*_искл*" Then
      k = k + 1
      w(k, j) = v(i, 1)
      If k > kmax Then kmax = k
    End If
  Next
  Range("C2").Resize(kmax, j).Value = w
End Sub
 
_Igor_61, Идея в том, чтобы макрос просматривал весь столбец доходил до первой ячейки где встречается "Ссылка1" и копировал все ячейки за этой до ячейки где встречается "Ссылка2" и вставлял в новый столбец. Затем все ячейки находящиеся за ячейкой "Ссылка2" до следующей ячейки где содержится текст "Ссылка1" копировал в другой столбец и т.д.  
 
Цитата
ARan написал:
до ячейки где встречается "Ссылка2"
В примере "Текст7" после "Ссылка2", перед второй "Ссылка2". Наверное, я не совсем точно задал вопрос по уточнению условий задачи, но точней пока не могу, поэтому повторюсь:
Цитата
_Igor_61 написал:
Как узнать от какой "Ссылка 1"  и до какой "Ссылка 2"
 
Казанский, спасибо за помощь, но немного не так. В моем случае ссылка1 и ссылка2 это два разных ключевых слова, по которым выполняется сортировка основного столбца на два. Так можно как то реализовать?
 
_Igor_61,  спасибо
Цитата
_Igor_61 написал:
В примере "Текст7" после "Ссылка2", перед второй "Ссылка2".
проверил в примере после "текст6" идет "ссылка1"
 
_Igor_61,  Казанский, немного подправил пример, мб станет понятнее что мне надо
 
ARan,
Код
Sub Aran()
Dim v(), i&, k&(1 To 2), j&
  v = Range("A2", Cells(Rows.Count, "A").End(xlUp)).Value
  ReDim w$(1 To UBound(v), 1 To 2)
  For i = 1 To UBound(v)
    If LCase$(v(i, 1)) Like "основ.*" Then
      j = 1
    ElseIf LCase$(v(i, 1)) Like "доп.*" Then
      j = 2
    ElseIf Not LCase$(v(i, 1)) Like "*_искл*" Then
      k(j) = k(j) + 1
      w(k(j), j) = v(i, 1)
    End If
  Next
  If k(2) > k(1) Then i = k(2) Else i = k(1)
  Range("C2").Resize(i, 2).Value = w
End Sub
 
Казанский, спасибо огромное. Это то что надо!
Страницы: 1
Читают тему
Наверх