Option Explicit
Option Private Module
'====================================================================================================
Sub Test()
Dim v, arrV(), res#, t!, tt!, n&

arrV = Array(19000, 39000, 59000, 79000, 99000, 199000): tt = Timer
For Each v In arrV
    t = Timer
    For n = 1 To 10000000
        res = TaxProgressive(v)
    Next n
    Debug.Print v, res, Timer - t
Next v
Debug.Print "Total time (6 values in 10 mln cycles):"; Timer - tt
End Sub
'====================================================================================================
'====================================================================================================
' Прогрессивное налогообложение на примере подоходного налога. Результат с точностью до копеек (математическое округление)
' Post: https://www.planetaexcel.ru/forum/index.php?PAGE_NAME=message&FID=5&TID=142573&TITLE_SEO=142573-progressivnoe-nalogooblozhenie.-realizatsiya-kodom_-funktsiyami-lista_-power-query-i-drugimi-instrumentami
Function TaxProgressive(iVal) As Double
    If iVal < 20001 Then TaxProgressive = RoundZVI(iVal * 0.12, 2):                     Exit Function
    If iVal < 40001 Then TaxProgressive = 2400 + RoundZVI((iVal - 20000) * 0.15, 2):    Exit Function
    If iVal < 60001 Then TaxProgressive = 5400 + RoundZVI((iVal - 40000) * 0.2, 2):     Exit Function
    If iVal < 80001 Then TaxProgressive = 9400 + RoundZVI((iVal - 60000) * 0.25, 2):    Exit Function
    If iVal < 100001 Then TaxProgressive = 14400 + RoundZVI((iVal - 80000) * 0.3, 2):   Exit Function
    TaxProgressive = 20400 + RoundZVI((iVal - 100000) * 0.35, 2)
End Function
'====================================================================================================
' Функция от ZVI: https://www.planetaexcel.ru/forum/index.php?PAGE_NAME=message&FID=8&TID=3483&TITLE_SEO=3483&MID=303275#message303275
'====================================================================================================
Function RoundZVI(ByVal v#, Optional ByVal dig&) As Double

If dig < 0 Then
    RoundZVI = Round(v / 10 ^ -dig + v * 2E-16, 0) * 10 ^ -dig
Else
    RoundZVI = Round(v + v * 2E-16, dig)
End If
If Abs(RoundZVI) = 0 Then RoundZVI = 0
End Function
'====================================================================================================