Если так жалко свой код, то можно использовать библиотеку Microsoft Visual Basic for Applications Extensibility. Используя её, открывая очередной файл для анализа, можно определить наличие в этой книге форм, модулей, а так же кода в них.

Например, по наличию классов, модулей, форм в книге такая функция  
Public Function hasMacro(ByVal inBook As Workbook) As Boolean  
   Dim pVBProject As VBIDE.VBProject  
   Dim pVBComponent As VBIDE.VBComponent  
   Set pVBProject = inBook.VBProject  
   If pVBProject.VBComponents.Count > 0 Then  
       For Each pVBComponent In pVBProject.VBComponents  
           Select Case pVBComponent.Type  
           Case vbext_ComponentType.vbext_ct_MSForm  
               hasMacro = True  
           Case vbext_ComponentType.vbext_ct_ClassModule  
               hasMacro = True  
           Case vbext_ComponentType.vbext_ct_StdModule  
               hasMacro = True  
           Case vbext_ComponentType.vbext_ct_Document  
               'анализ кода листов, книги  
           End Select  
       Next pVBComponent  
   Else  
       hasMacro = False  
   End If  
End Function

Зачем же?  
Создаёте книгу с макросом, который сканирует заданную папку и её подпапки на наличие файлов. Приблизительно, опуская не существенное  
Public sub Scan(ByVal startPath As String)  
Dim pBook As Workbook  
'код сканирования и получения имени файла  
Set pBook = Application.Workbooks.Open("d:\path\bookname.xls")  
If hasMacro(pBook) Then  
ThisWorkbook.Worksheets(1).Cells(i, 1).Value = pBook.FullName  
End If  
End Sub

Спасибо:)  
по этой строчке понимаю,что открывать придётся каждый файл  
Set pBook = Application.Workbooks.Open("d:\path\bookname.xls")  
Но вопрос,Уважаемый anvg,состоял:  
"Быть может есть код VBA умеющий определить о наличии макросов,форм в несколько сотен файлов?"  
 
Понимаю,что косяк мой был в их создании,но может есть ещё выход?

А формат файлов какой - xls, xlsm?

Тоже нашел (не)Служебное произведение  
практика показывает: все равно никто не разберется даже с формулами, а с кодом тем более

У меня вот что получилось (раньше с VBComponents не работал программно)  
 
Function DeleteAllVBA() As Boolean  
'удаляет все компоненты VBA в текущей книге и возвращает True, если они были  
Dim i&, j&  
With ActiveWorkbook.VBProject  
   For i = .VBComponents.Count To 1 Step -1  
       If .VBComponents(i).Type = 100 Then 'vbext_ComponentType.vbext_ct_Document, т.е. модуль книги, листа  
           With .VBComponents(i).CodeModule  
               j = .CountOfLines - .CountOfDeclarationLines  
               If j Then .DeleteLines 1, .CountOfLines: DeleteAllVBA = True  
           End With  
       Else 'остальные типы: модуль, модуль класса, форма  
           .VBComponents.Remove .VBComponents(i): DeleteAllVBA = True  
       End If  
   Next  
End With  
End Function  
 
Sub test()  
Const FLDR = "c:\temp\1\"  
Dim w, q  
If MsgBox("Внимание!!!" & vbLf & _  
   "Будут удалены ВСЕ компоненты VBA (макросы, формы, пользовательские функции) из ВСЕХ файлов Excel в папке " _  
   & FLDR & vbLf & "Продолжить?", vbCritical + vbYesNoCancel + vbDefaultButton2) <> vbYes Then Exit Sub  
Application.EnableEvents = False 'для запрещения макросов Workbook_Open в открываемых книгах  
w = Dir(FLDR & "*.xls") 'фактически *.xls*  
Do While w <> ""  
   With Workbooks.Open(FLDR & w)  
       .Close DeleteAllVBA 'если компонентов VBA не было, закрыть без сохранения  
   End With  
   w = Dir  
Loop  
Application.EnableEvents = True  
End Sub