Sub ButtonCSVExport()
    Dim pt As PivotTable, exportWb As Workbook
    ' Текущий лист
    Set curSh = ActiveSheet
    ' Создать новую книгу
    Set exportWb = Workbooks.Add
    ' Скопировать диапазон значений сводной таблицы с листа в новый файл
    curSh.PivotTables(1).RowRange.Offset(1, 0).Resize(RowSize:=curSh.PivotTables(1).RowRange.Rows.Count - 1).Copy _
        Destination:=exportWb.Sheets(1).Cells(1)
    
    ' Сохранить новую книгу как CSV, разделитель - точки с запятыми
    
    ' Адрес сохранения - папка в которой сохранен файл-источник
    exportWb.SaveAs Filename:=ThisWorkbook.Path & "\export.csv", FileFormat:=xlCSV, Local:=True
        
    ' Альтернативно - прописываем путь сохранения файла
    'fileSavePath = "C:/export.csv"
    'exportWb.SaveAs Filename:=fileSavePath, FileFormat:=xlCSV, Local:=True
    
    ' Закрыть новую книгу без сохранения
    exportWb.Close SaveChanges:=False
End Sub

Sub primer()
    Dim curSh As Worksheet, LO As ListObject, copyRn As Range, FinalCopyRn As Range
    ' Текущий лист
    Set curSh = ActiveSheet
    ' Умная таблица на листе
    Set LO = curSh.ListObjects(1)
    ' Для каждой строки диапазона значений умной таблицы
    For Each rrow In LO.DataBodyRange.Rows
        ' Если в первом столбце единица, то...
        If rrow.Cells(1).Value = 1 Then
            ' Сохранить строчку в диапазон copyRn
            If copyRn Is Nothing Then
                Set copyRn = rrow
            Else
                Set copyRn = Union(copyRn, rrow)
            End If
        End If
    Next rrow
    
    ' Если есть хотя бы одна строчка для экспорта, то...
    If Not copyRn Is Nothing Then
        ' Создать новую книгу
        Set exportWb = Workbooks.Add
        ' Данные для экспорта - пересечение Столбцов C и E со строками, где единицы в первой колонке
        Set FinalCopyRn = Union(Intersect(curSh.Range("C:C"), copyRn), Intersect(curSh.Range("E:E"), copyRn))
        ' Копируем нужные данные на новую книгу
        FinalCopyRn.Copy Destination:=exportWb.Sheets(1).Cells(1)
        
        ' Сохраняем книгу как CSV
        exportWb.SaveAs Filename:=ThisWorkbook.Path & "\export.csv", FileFormat:=xlCSV, Local:=True
        ' Альтернативно - прописываем путь сохранения файла
        'fileSavePath = "C:/export.csv"
        'exportWb.SaveAs Filename:=fileSavePath, FileFormat:=xlCSV, Local:=True
        
        ' Закрыть новую книгу без сохранения
        exportWb.Close SaveChanges:=False
    End If
End Sub