Option Explicit ' Советую использовать в каждом коде. Подробнее тут: https://www.excel-vba.ru/chto-umeet-excel/variable-not-defined-ili-chto-takoe-option-explicit-i-zachem-ono-nuzhno/
Sub ОсновнойМакрос() ' Уникальное имя нашего макроса, по которому его можно будет запустить

'========== Объявляем переменные
'"cl" это сокращение от "cell" (ячейка), также как и "rng" это сокращение от "Range" (диапазон), и gr от "Group" (группа)
Dim rng As Range, gr As Range, cl As Range 'переменные для диапазонов (Range). Диапазон - это одна и более ячеек.
Dim lr As Long 'Переменная "lr" - это сокращение от "lastrow" (последняя строка).
Dim t 'Переменная "t" нужна в макросе только для измерения скорости выполнения (не обязательная).
' Подробнее о переменных тут: https://www.excel-vba.ru/chto-umeet-excel/chto-takoe-peremennaya-i-kak-pravilno-eyo-obyavit/

'========== Назначаем переменные
t = Timer ' Назначаем переменной "t" текущее системное время. "Timer" - это служебная команда, не переменная.

Application.ScreenUpdating = False ' Отключаем обновление экрана для ускорения работы макроса.

' Определяем последнюю заполненную строку. Подробнее о вариантах тут: https://www.excel-vba.ru/chto-umeet-excel/kak-opredelit-poslednyuyu-yachejku-na-liste-cherez-vba/
lr = Cells.SpecialCells(xlLastCell).Row ' в данном коде не нужно, т.к. работаем с выделенным диапазоном

' Если задействовать диалоговые окна, то можно по-разному взаимодействовать с пользователем.
' Например, можно предложить пользователю выделить диапазон уже когда макрос запущен или предложить ввести № столбца, в котором необходимо обработать данные.
' Подробнее о диалоговых окнах тут: https://www.excel-vba.ru/chto-umeet-excel/rabota-s-dialogami/
' Мы же пойдём другим путём )))

With ActiveSheet.UsedRange: End With ' Переопределяем рабочую область листа (по ссылке определения последней строки есть пояснения)

' макрос работает с предварительно выделенным диапазоном. Выделили диапазон, запустили макрос.
'Выделение (Selection) должно входить в рабочую область (UsedRange) данных активного листа (ActiveSheet). На случай, если вы выделите столбец целиком (более миллиона строк), а обработать нужно только малую часть
Set rng = Intersect(Selection, ActiveSheet.UsedRange)

' Если выделение вообще не входит в рабочую область, то работать макросу там не с чем. Сообщаем об этом ползователю и переходим по метке GoTo на ярлык "fin", который в самом конце макроса. Это для того, чтобы не забыть включить обновление экрана обратно
If rng Is Nothing Then MsgBox "Некорректное выделение!", vbCritical, "ОШИБКА ВЫДЕЛЕНИЯ": GoTo fin

'========== Начало основного кода
    For Each cl In rng ' Для каждой ячейки в диапазоне rng.
        If cl.Font.Bold = True And Len(cl.Offset(1, 0)) = 0 Then ' Начало критерия проверки. Если шрифт в текущей ячейке жирный, а также длина содержимого ячейки, которая на одну строку ниже текущей = 0 (пустая ячейка), то …
            If gr Is Nothing Then Set gr = cl Else: Set gr = Application.Union(gr, cl) ' … собираем ячейки, подходящие под условия в группу ("gr"). Если группа пока пустая, то группа равна этой найденной ячейке, в противном случае добавляем очередную найденную ячейку к уже существующей группе
        End If ' Конец критерия проверки
    Next cl
If gr Is Nothing Then MsgBox "Ни одна ячейка не удовлетворяет условиям", vbInformation, "ЗРЯ СТАРАЛИСЬ": GoTo fin ' Если группа пустая (ни одна ячейка удовлетворяет условиям), то выводим сообщение, что всё было напрасно и по метке идём в самый конец макроса
gr.ClearContents ' Если макрос дошёл до этой строки, значит группа НЕ пустая, и мы махои очищаем значения сразу всех ячеек группы

'========== Конец основного кода
MsgBox "Макрос успешно завершил работу. Время выполнения (сек.): " & Round(Timer - t, 6), vbInformation, "ГОТОВО" ' Выводим сообщение об успешном выполнении и времени выполнения в секундах с округлением до 6 знаков после запятой.
fin:
Application.ScreenUpdating = True ' Включаем обновление экрана обратно
End Sub

'====================================================================================

Sub МакросЗаполнения()
shAdd.Columns(1).Copy ActiveSheet.[a1]
End Sub

Option Explicit
Sub ОсновнойМакрос()
Dim gr As Range, cl As Range, clDown As Range
Dim i As Long, lr As Long 'Переменная "i" - счётчик
Dim t
t = Timer
Application.ScreenUpdating = 0
lr = Cells(Rows.Count, 1).End(xlUp).Row
    For i = lr To 1 Step -1 'для i= от lr (номер последней заполненной ячейки первого столбца) до первой ячейки первого столбца
        Set cl = Cells(i, 1): Set clDown = cl.Offset(1, 0) ' назначаем вспомогательные ячейки: текущая и ниже неё соответственно.
        If (cl.Font.Bold Or Len(cl) = 0) And Len(clDown) = 0 Then cl.EntireRow.Delete
    Next i
MsgBox "Макрос успешно завершил работу. Время выполнения (сек.): " & Round(Timer - t, 6), vbInformation, "ГОТОВО"
Application.ScreenUpdating = True
End Sub