Поиск  Пользователи  Правила  Войти
Форумы "Планета Excel" » Вопросы по Microsoft Excel
Страницы: 1
RSS
Не могу найти значения в массиве данных
 
#1
12.07.2018 11:21:15
Соучастники, привет!
Пробовал функцию ПРОСМОТР, ИНДЕКС, ПОИСКПОЗ. не помогло
Нужно каждое значение из столбца A искать в столбце G. При нахождении такового, в столбец В напротив искомого значения прописать значение из столбца F напротив найденного. Как пример сделал в ячейке B24
Можно конечно и макросом, но на офисном ПК нет по ходу версии с ним Excel

Помогите, пожалуйста, с задачей.
 
 
 
#2
12.07.2018 11:34:21
а так =IFERROR(INDEX(F:F;MATCH("*"&A24&"*";G:G;0));"")
По вопросам из тем форума, личку не читаю.
 
 
 
#3
12.07.2018 11:43:09
БМВ, Огромное спасибо!
Изменено: mikhail.T - 12.07.2018 14:56:38
 
 
 
#4
12.07.2018 11:43:40
дополню вариант БМВ, наверное так будет более точный поиск, но формула становится массивной
Код
=ЕСЛИОШИБКА(ИНДЕКС($F$2:$F$296;ПОИСКПОЗ("*/"&A2&"/*";"/"&$G$2:$G$296&"/";0));"")
Изменено: Сергей - 12.07.2018 11:44:37 (косякнул малехо)
Лень двигатель прогресса, доказано!!!
 
 
 
#5
12.07.2018 11:56:45
Сергей, Но так не ищет
Изменено: mikhail.T - 12.07.2018 14:57:21
 
 
 
#6
12.07.2018 12:05:08
Цитата
Сергей написал:
становится массивной
Лень двигатель прогресса, доказано!!!
 
 
 
#7
12.07.2018 12:25:34
хм
=IFERROR(INDEX(F:F;LOOKUP(2;1/ISNUMBER(SEARCH("/"&A2&"/";"/"&$G$2:$G$296&"/"));ROW($G$2:$G$296)));"")
и результат тоже отличен
Выборочно проверил  - ок

upd
=IFERROR(LOOKUP(2;1/ISNUMBER(SEARCH("/"&A2&"/";"/"&$G$2:$G$296&"/"));$F$2:$F$296);"")
Изменено: БМВ - 12.07.2018 14:34:10
По вопросам из тем форума, личку не читаю.
 
 
 
#8
12.07.2018 12:42:22
блин замута реальная ПОИСКПОЗ не находит если текст длиннее 255 знаков, анализ в файле
Лень двигатель прогресса, доказано!!!
 
 
 
#9
12.07.2018 12:53:59
Сергей, Черт, я даже не смотрел что там так длинно :-) . выходит праведный результат #7
По вопросам из тем форума, личку не читаю.
 
 
 
#10
12.07.2018 13:03:18
БМВ, да с таким результатом первый раз сталкиваюсь если б не твоя конструкция из #7 так бы даже и не знал
Лень двигатель прогресса, доказано!!!
 
 
 
#11
12.07.2018 14:00:21
То есть правильная формула?
=IFERROR(INDEX(F:F;LOOKUP(2;1/ISNUMBER(SEARCH("/"&A2&"/";"/"&$G$2:$G$296&"/"));ROW($G$2:$G$296)));"")
 
 
 
#12
12.07.2018 14:03:10
правильная - любая формула, которая выдает правильный результат
Вас результат устраивает? - формула правильная!
Программисты - это люди, решающие проблемы, о существовании которых Вы не подозревали, методами, которых Вы не понимаете!
 
 
 
#13
12.07.2018 14:33:16
mikhail.T,

правильная да, корректная эта
=IFERROR(LOOKUP(2;1/ISNUMBER(SEARCH("/"&A2&"/";"/"&$G$2:$G$296&"/"));$F$2:$F$296);"")
заменил в #7
Изменено: БМВ - 12.07.2018 14:33:57
По вопросам из тем форума, личку не читаю.
 
 
 
#14
12.07.2018 14:48:36
БМВ, В итоге вот эта максимально точно выдаёт результат
=ЕСЛИОШИБКА(ИНДЕКС(F:F;ПРОСМОТР(2;1/ЕЧИСЛО(ПОИСК("/"&A2&"/";"/"&$G$2:$G$296&"/"));СТРОКА($G$2:$G$296)));"")
Изменено: mikhail.T - 12.07.2018 14:58:07
 
 
 
#15
12.07.2018 14:52:19
mikhail.T, кнопка цитирования не для ответа! Вернитесь в свои сообщения и удалите эти горе-цитаты.
 
 
 
#16
12.07.2018 14:57:32
не менее точно будет
=ЕСЛИОШИБКА(ПРОСМОТР(2;1/ЕЧИСЛО(ПОИСК("/"&A2&"/";"/"&$G$2:$G$296&"/"));$F$2:$F$296);"")
но короче
одна оговорочка, все формулы рассчитаны на единственное искомое значение. Если будет 2, то с ПРОСМОТР выдаст последний.
По вопросам из тем форума, личку не читаю.
 
 
 
#17
12.07.2018 15:00:04
БМВ, ну искомое одно значение, но оно может повторятся в массиве для поиска. Но в данном примере мне без разницы какое будет подставлять, важен сам факт наличия совпадения
 
 
 
Страницы: 1
Наверх