Поиск  Пользователи  Правила 
Закрыть
Логин:
Пароль:
Забыли свой пароль?
Регистрация
Войти
 
Страницы: 1
RSS
Суммировать время из записи 2d 2h 15m
 
Уважаемые, подскажите, как можно разобрать следующие данные
2d 2h 15m
2d 15m
2d 2h 16m
2d 9m
2d 3h 31m
2d 1h 15m
2d 3h 15m
2d 2h 41m
2d 14m
так чтобы получилось или дни/часы/минуты в разных ячейках или в одной в виде минут (например 2d 15m = 2895 мин) или днях (например 2d 15m =  2,01 дня).

Спасибо за помощь!
 
Цитата
DJVU написал:
например 2d 15m =  2,01
=ОКРУГЛ(ЕСЛИОШИБКА(ЛЕВБ(A1;ПОИСК("d";A1)-1);0)+ЕСЛИОШИБКА(ПСТР(" "&A1;ПОИСК("h";" "&A1)-2;2);0)/24+ЕСЛИОШИБКА(ПСТР(" "&A1;ПОИСК("m";" "&A1)-2;2);0)/24/60;2)
Цитата
2d 15m = 2895
=ЕСЛИОШИБКА(ЛЕВБ(A1;ПОИСК("d";A1)-1);0)*24*60+ЕСЛИОШИБКА(ПСТР(" "&A1;ПОИСК("h";" "&A1)-2;2);0)*60+ЕСЛИОШИБКА(ПСТР(" "&A1;ПОИСК("m";" "&A1)-2;2);0)
Изменено: Catboyun - 9 Сен 2018 23:09:07
 
В имя
=EVALUATE(SUBSTITUTE(SUBSTITUTE(SUBSTITUTE(SUBSTITUTE(TRIM(Sheet1!A1);"d";"");"h";"/24");"m";"/24/60");" ";"+"))
Просто для комплекта.
 
Цитата
БМВ написал:
Просто для комплекта.
я так понимаю  - плантации оставлены, уже дома у компа?  :)
 
На лист, для комплекта :)
=СУММПРОИЗВ(ЕСЛИОШИБКА(ПОДСТАВИТЬ(ПСТР(ПОДСТАВИТЬ(A1;" ";ПОВТОР(" ";9));1*{1;9;18};9);{"d":"h":"m"};)/{1:24:1440};))
 
О!!! Низкий поклон!
Вчера полвечера потратил на это... Причем вроде проблем с экселем не испытывал до этого. Но с разбором строк редко имею дело

Еще раз - благодарности всем!
 
DJVU, не жмите на Enter по несколько раз - не пишите через 1-2 строки.
 
Еще парочка:
=СУММПРОИЗВ(ЕСЛИОШИБКА(ПСТР(0&A1;ПОИСК({"d";"h";"m"};0&A1)-2;2)/{1;24;1440};))
=СУММ(ПСТР(0&A1&"00000";ПОИСК({"d";"h";"m"};0&A1&"iidhm")-2;2)/{1;24;1440})
Страницы: 1
Читают тему (гостей: 1)
Наверх