Поиск  Пользователи  Правила  Войти
Форумы "Планета Excel" » Вопросы по Microsoft Excel
Страницы: 1
RSS
как вставить пробел в слово
 
#1
11.09.2018 09:58:27
Здравствуйте ,Уважаемые Форумчане, прошу подсказать как вставить пробел в слово., т.е ПРС54 должно получиться ПРС 54. Спасибо заранее
 
 
 
#2
11.09.2018 10:00:51
вы такие примеры делаете что вероятность того что вы вернетесь с этим же вопросом близка к 100%
Код
=ЗАМЕНИТЬ(A1;4;;" ")
Лень двигатель прогресса, доказано!!!
 
 
 
#3
11.09.2018 10:02:31
=TextSplit(A1)
Это в случае если есть Plex ;)
В жизни нет ничего невозможного! Есть только недостаток знаний и умений.
 
 
 
#4
11.09.2018 10:30:45
На вскидку такая неоптимальная формула массива:
=ПСТР(A1;1;МИН(ЕСЛИ(НЕ(ЕОШ(--ПСТР(A1;СТРОКА(ДВССЫЛ("1:"&ДЛСТР(A1)));1)));СТРОКА(ДВССЫЛ("1:"&ДЛСТР(A1)))))-1)&" "&ПСТР(A1;МИН(ЕСЛИ(НЕ(ЕОШ(--ПСТР(A1;СТРОКА(ДВССЫЛ("1:"&ДЛСТР(A1)));1)));СТРОКА(ДВССЫЛ("1:"&ДЛСТР(A1)))));999)

Подойдет для любых сочетаний и вставит пробел в любую строку перед первым числом. Длина текста не имеет значения.
Или можно чуть иначе. За основу взята формула Сергея:
вариант 1
=ЗАМЕНИТЬ(A1;МИН(ЕСЛИ(НЕ(ЕОШ(--ПСТР(A1;СТРОКА(ДВССЫЛ("1:"&ДЛСТР(A1)));1)));СТРОКА(ДВССЫЛ("1:"&ДЛСТР(A1)))));;" ")
вариант 2:
=ЗАМЕНИТЬ(A1;ПОИСКПОЗ(1=1;ЕЧИСЛО(-ПСТР(A1;СТРОКА(ДВССЫЛ("1:"&ДЛСТР(A1)));1));0);;" ")
вариант 3
=ЗАМЕНИТЬ(A1;ПОИСКПОЗ(1=1;ЕЧИСЛО(-ПСТР(A1;СТРОКА($1:$999);1));0);;" ")

Все что выше - формулы массива. Вводятся в ячейку тремя клавишами: Ctrl+Shift+Enter
Изменено: Дмитрий(The_Prist) Щербаков - 11.09.2018 10:38:41
Даже самый простой вопрос можно превратить в огромную проблему. Достаточно не уметь формулировать вопросы...
 
 
 
#5
11.09.2018 10:37:09
Господа спасибо огромное!!!!
 
 
 
#6
11.09.2018 11:08:39
Дмитрий(The_Prist) Щербаков, спасибо огромное, внедряю))
 
 
 
#7
11.09.2018 11:18:14
=ЗАМЕНИТЬ(A1;МИН(ПОИСК({1;2;3;4;5;6;7;8;9;0};A1&1234567890));;" ")
 
 
 
#8
11.09.2018 13:22:34
vikttur, спасибо большое. Очень интересное и простое решение)))
 
 
 
Страницы: 1
Наверх