вариант c комментами
P.S.
MY REVIEW:
манипулировать подструктурами удобнее через UDF (с точки зрения синтаксиса)
ещё более глубокими подструктурами (иными по строению) - новыми (иными по обработке) UDF
и т.д. [особенно на первых порах]
| Код |
|---|
let
dateList = Excel.CurrentWorkbook(){[Name="Таблица1"]}[Content],
typed = Table.TransformColumnTypes(dateList,{{"Дата С", type date}, {"Дата ПО", type date}}),
sorted = Table.Sort(typed, {"Код", {"Дата С", Order.Descending} }),
grouped=Table.Group(sorted,"Код", {"lastRenew", each List.Max([Дата С])} ),
joined=Table.NestedJoin(grouped,"Код", sorted,"Код", "nest"),
indexed = Table.TransformColumns(joined, { {"nest", each Table.AddIndexColumn(_, "Index", 1, 1) } }),
//-UDF1
listrng = (this as table) => let
// те Статусы, которые выше
add= Table.AddColumn(this, "Initial", each Table.Range(this[[Статус],[Дата С],[Дата ПО]],0,[Index]-1)), //CUMMULATED PREVIOUS
// развернули массивы Дат в колонку [dts] в prior_cummulated_subgroup of Initial:
// -- UDF2
listdts = (this2 as table) => let
aa= Table.AddColumn(this2, "dts", each List.Dates(_[Дата С],Duration.Days(_[Дата ПО] - _[Дата С]) + 1, #duration(1, 0, 0, 0)), type datetime )
in aa,
// -- implementation of UDF2
trans= Table.TransformColumns(add, {"Initial", each listdts(_) } ),
// вывод в строки Initial - всех prior Дат
trans2= Table.TransformColumns(trans, {"Initial", each List.Sort(List.Distinct(List.Combine(_[dts])))}),
// исключение из каждого текущего prior Дат (т.е. тех, у которык уже более приоритетный Статус есть)
current= Table.AddColumn(trans2, "curretdts", each List.Dates(_[Дата С],Duration.Days(_[Дата ПО] - _[Дата С]) + 1, #duration(1, 0, 0, 0)), type datetime ),
crossremove= Table.AddColumn(current, "dts_In_Work", each List.RemoveItems( _[curretdts], _[Initial]) )
in
crossremove,
// - implementation of UDF1
cumm = Table.TransformColumns(indexed, {"nest", each listrng(_)} ),
#"Expanded nest" = Table.ExpandTableColumn(cumm, "nest", {"Статус", "dts_In_Work"}, {"Статус", "dts_In_Work"}),
#"Expanded nest.dtsInWork" = Table.ExpandListColumn(#"Expanded nest", "dts_In_Work"),
#"Changed Type" = Table.TransformColumnTypes(#"Expanded nest.dtsInWork",{{"dts_In_Work", type date}}),
#"Removed Columns" = Table.RemoveColumns(#"Changed Type",{"lastRenew"})
in
#"Removed Columns" |
MY REVIEW:
манипулировать подструктурами удобнее через UDF (с точки зрения синтаксиса)
ещё более глубокими подструктурами (иными по строению) - новыми (иными по обработке) UDF
и т.д. [особенно на первых порах]
Изменено: - 30.10.2018 09:40:39
чтобы не гадать на кофейной гуще, кто вам отвечает и после этого не совершать кучу ошибок - обратитесь к собеседнику на ВЫ - ответ на ваш вопрос получите - а остальное вас не касается (п.п.п. на форумах)
