Поиск  Пользователи  Правила  Войти
Форумы "Планета Excel" » Вопросы по Microsoft Excel
Страницы: 1
RSS
Определение ФИО по предпоследнему посещению с уникальным кодом
 
#1
29.09.2018 08:24:54
У каждой карты с уникальным кодом может быть 4 ФИО, необходимо по уникальному коду определить ФИО с предпоследнем посещением
ПРимер:A  - уникальный код, B - дата посещения, C - ФИО, D - резултат который нам  необходимо получить. Вопрос как его получить((((??
A B C D
1 1.09.2018 ASD FGH
2 2.09.2018 ASD
3 1.09.2018 ASD
1 20.08.2018 FGH
5 11.09.2018 ASD
9 28.08.2018 FGH
1 01.07.2018 RTY
 
 
 
#2
29.09.2018 08:47:41
Вот и у меня
Цитата
FAYT написал:
Вопрос как его получить
нормальный пример в нормальном формате XLS.
По вопросам из тем форума, личку не читаю.
 
 
 
#3
29.09.2018 08:58:03
Решение
Мой канал
 
 
 
#4
29.09.2018 09:31:43
кросс
По вопросам из тем форума, личку не читаю.
 
 
 
#5
29.09.2018 11:20:13
Друзья прошу прощение за отсутствие примера. Вложил.
skais675 - решение не подходит к сожалению
 
 
 
#6
29.09.2018 13:29:28
По какой причине в одном случае "не найдено", а в другом "не определено"?

=IFERROR(LOOKUP(2;1/(A2&MAX($B$2:$B$9*($A$2:$A$9=A2)*($B$2:$B$9<B2))=($A$2:$A$9&--$B$2:$B$9));$C$2:$C$9);"не найдено")
По вопросам из тем форума, личку не читаю.
 
 
 
#7
29.09.2018 13:37:31
Из кросса
=ПРОСМОТР(;-1/(МАКС((A2=A$2:A$99)*(B$2:B$99<B2)*B$2:B$99)=--B$2:B$99);C$2:C$99)&""
Изменено: _Boroda_ - 29.09.2018 13:37:58
Скажи мне, кудесник, любимец ба’гов...
 
 
 
#8
29.09.2018 13:41:23
_Boroda_,  Александр, может я и перебдел, но что будет при одинаковом времени у разных карт? Я по этому составной ключ и включил.
По вопросам из тем форума, личку не читаю.
 
 
 
#9
29.09.2018 14:15:10
FAYT - почему не подошло, что не так?
Мой канал
 
 
 
#10
29.09.2018 14:17:23
skais675, вы не учли что предпоследний не только по времени, но и в пределах одной карты.
По вопросам из тем форума, личку не читаю.
 
 
 
#11
29.09.2018 20:53:53
_Boroda_ и БМВ, СПАСИБО! Помогли обе формулы), в результате они дополнили друг друга. Одна формула нашла ФИО тех, кого не нашла 2-ая формула. Подскажите как эти формулы объединить?
 
 
 
#12
29.09.2018 21:46:34
Цитата
FAYT написал:
Одна формула нашла ФИО тех, кого не нашла 2-ая формула.
Хм, странно , формулы идентичны, моя немного страхует от равенства времени, но на примере этого нет.
По вопросам из тем форума, личку не читаю.
 
 
 
#13
30.09.2018 15:54:58
Цитата
БМВ написал:
что будет при одинаковом времени у разных карт?
Я исходил из того, что поскольку время в секундах, то это явно считыватель (или человечий ввод с автопроставкой времени) на проходной. Два человека с одной картой одновременно пройти не могут.
Цитата
БМВ написал:
странно , формулы идентичны
Действительно, что-то здесь автор явно недоговаривает. На ExcelWorld я то же самое написал:
"Вообще-то это одинаковые формулы. Если у Вас они дали разные результаты, то покажите в файле"

В общем, Алексей Максимович когда файл приложит, то посмотрим
Скажи мне, кудесник, любимец ба’гов...
 
 
 
#14
30.09.2018 18:16:07
формулы одинаковы)))точно.
если мы добавляем месяц август, то формулы не корректно работают, или я что-то не правильно делаю?
 
 
 
#15
30.09.2018 18:24:02
=IFERROR(LOOKUP(2;1/(A2&MAX($B$2:$B$9*($A$2:$A$9=A2)*(--$B$2:$B$9<--B2))=($A$2:$A$9&--$B$2:$B$9));$C$2:$C$9);"не найдено")

Ну ни я ни Александр не знали, что у вас там будет текст а не числа со временем.
По вопросам из тем форума, личку не читаю.
 
 
 
#16
30.09.2018 21:05:47
Цитата
БМВ написал:
ни я ни Александр не знали, что у вас там будет текст а не числа со временем.
Я знал. Иначе бы не поставил два минуса здесь =--B$2:B$99
Это действительно косяк. Вот тк нужно
=ЕСЛИОШИБКА(ПРОСМОТР(;-1/(МАКС((A2=A$2:A$9)*(B$2:B$9-B2<0)*B$2:B$9)=--B$2:B$9);C$2:C$9);"--")
С самого начала хотел так написать, потом почему-то (типа короче и вроде работает) написал так, как написал в посте выше
Скажи мне, кудесник, любимец ба’гов...
 
 
 
#17
30.09.2018 21:15:56
_Boroda_,  ну значит я не знал а _Boroda_, знал, но забыл :-)

хотя смотрю на свою первую фоомулу из #6 и думаю , не просто так $A$2:$A$9&--$B$2:$B$9 было написано
Изменено: БМВ - 30.09.2018 21:25:56
По вопросам из тем форума, личку не читаю.
 
 
 
#18
30.09.2018 21:23:15
Цитата
БМВ написал:
смотрю на свою первую и думаю...
)))
 
 
 
#19
30.09.2018 21:25:23
Кот, без домыслов попрошу. Она у меня первая и единственная. :-)
По вопросам из тем форума, личку не читаю.
 
 
 
#20
30.09.2018 21:26:20
А что сразу кот?
 
 
 
#21
01.10.2018 10:30:12
_Boroda_ - огромное спасибо!
формула подошла.
 
 
 
#22
02.10.2018 12:58:43
Друзья,  подскажите как сделать ограничение по поиску в месяц? то есть если есть  даты более чем 30 дней, что бы он их не учитывал?
 
 
 
#23
02.10.2018 19:56:16
=IFERROR(LOOKUP(2;1/(A2&MAX($B$2:$B$9*($A$2:$A$9=A2)*($B$2:$B$9-B2<0)*(B2-$B$2:$B$9<30))=($A$2:$A$9&--$B$2:$B$9));$C$2:$C$9);"не найдено")
или корректируя формулу _Boroda_,
=ЕСЛИОШИБКА(ПРОСМОТР(;-1/(МАКС((A2=A$2:A$9)*(B$2:B$9-B2<0)*(B2-$B$2:$B$9<30)*B$2:B$9)=--B$2:B$9);C$2:C$9);"--")
По вопросам из тем форума, личку не читаю.
 
 
 
Страницы: 1
Наверх