Поиск  Пользователи  Правила  Войти
Форумы "Планета Excel" » Вопросы по Microsoft Excel
Страницы: 1
RSS
Суммирование отрицательных и положительных числа в диапозоне при наличии текстовых значений
 
#1
15.10.2018 09:05:41
Доброго дня всем. Подскажите пож-та какой формулой можно получить сумму абсолютных  величин,  если в диапазоне имеются положительные и отрицательные числа, а также  текстовые значения.
 
 
 
#2
15.10.2018 09:12:03
Массивная:
=СУММ(ЕСЛИ(ЕЧИСЛО($A$3:$AD$3);ABS($A$3:$AD$3);0))

Формула массива (ФМ) вводится Ctrl+Shift+Enter
Memento mori
 
 
 
#3
15.10.2018 09:18:22
Спасибо большое. Все получилось. Еще раз благодарю за помощь
 
 
 
#4
15.10.2018 09:19:39
Ещё вариант. Массивная.
Код
=СУММ(ЕСЛИОШИБКА(ABS(A3:AE3);0))
P.S. Вы неверную сумму в примере указали
Изменено: Александр П. - 15.10.2018 09:20:14
 
 
 
#5
15.10.2018 09:25:42
Да, заметил, должно 190. Александр спасибо за замечание. вам большое спасибо за вариант.
 
 
 
#6
15.10.2018 10:33:22
Немассивные:
=СУММЕСЛИ(A3:AE3;">0")-СУММЕСЛИ(A3:AE3;"<0")
=СУММ(СУММЕСЛИ(A3:AE3;{">0";"<0"})*{1;-1})
 
 
 
#7
15.10.2018 13:17:52
Прошу прощения, возник еще один вопрос а как вот эту формулу( массивную) преобразовать, чтобы также учитывала отрицательные значения как абсолютные и какой вариант возможен не массивной формулы
Код
=СУММ(ЕСЛИ(ЕЧИСЛО(А3:AD3);ЕСЛИ(A3:AD3>8;A3:AD3-8))
Изменено: Gideon - 15.10.2018 13:31:16
 
 
 
#8
15.10.2018 14:38:27
В Вашей логике -12 - это тоже >8 или учитывать только положительные значения?
 
 
 
#9
15.10.2018 14:48:21
Учитывать нужно -12 это тоже >8, т.е все значения с минусом впереди должны приниматься как положительные, как абсолютные величины
 
 
 
#10
15.10.2018 15:03:01
Gideon, а что мешает заменить А3:AD3 на ABS(А3:AD3)?
Массивная
Код
=СУММ(ЕСЛИ(ЕЧИСЛО(A3:AD3);ЕСЛИ(ABS(A3:AD3)>8;ABS(A3:AD3)-8)))

Немассивная
Код
=СУММ(СУММЕСЛИ(A3:AD3;{">8";"<-8"})*{1;-1}-СЧЁТЕСЛИ(A3:AD3;{">8";"<-8"})*8)
Изменено: Казанский - 15.10.2018 15:17:06
 
 
 
#11
15.10.2018 15:22:21
Супер,что и  нужно, Огромное спасибо Вам, Вы просто гений. От души благодарю за оказанное мне внимание и помощь.
 
 
 
#12
15.10.2018 16:10:40
Еще пара немассивных вариантов
=СУММПРОИЗВ((ABS(Ч(+A3:AD3))>8)*(ABS(Ч(+A3:AD3))-8))
=СУММПРОИЗВ(ТЕКСТ(A3:AD3;"[>8]0;[<-8]0;\8;\8")-8)
Скажи мне, кудесник, любимец ба’гов...
 
 
 
#13
16.10.2018 07:30:25
_Boroda_, это сногсшибательно  8-0
Можно и без \ для нуля
Код
=СУММПРОИЗВ(ТЕКСТ(A3:AD3;"[>8]0;[<-8]0;8;\8")-8)
 
 
 
#14
17.10.2018 09:20:35
Добрый день. Возвращаюсь к своей теме. Кто нибудь может мне подсказать, а как в готовой формуле следующего характера вписать функцию модуля ABS с целью подсчета отрицательных и положительных значений. Буду очень благодарен за оказанную помощь.
Код
=ЕСЛИ(ВПР($B3;лист2!$B$2:$C$5;2;0)=7;СУММ(D3:AF3;(AJ3*7));ЕСЛИ(ВПР($B3;лист2!$B$2:$C$5;2;0)=8;СУММ(D3:AF3;(AJ3*8);ЕСЛИ(ВПР($B3;лист2!$B$2:$C$5;2;0)="другой";СУММ(D3:AF3;(AJ3*7));2)))
 
 
 
#15
17.10.2018 09:48:42
Ваше новое:
Цитата
Gideon написал: как в готовой формуле следующего характера вписать функцию модуля ABS с целью подсчета отрицательных и положительных значений
не согласуется с темой:
Цитата
Суммирование отрицательных и положительных числа в диапозоне при наличии текстовых значений
Создайте новую тему. И файл-пример обязательно - что есть и что должно получится.

Формула массива (ФМ) вводится Ctrl+Shift+Enter
Memento mori
 
 
 
Страницы: 1
Наверх