Страницы: 1
RSS
Сложение промежутка чисел "от" и "до"
 
Всем доброго времени суток.

Никак не могу сообразить, как реализовать сложение интервала чисел из таблицы.
Во вложении таблица из 2-ух столбцов, в ячейках D2 и D3 задается начальное и конечное значение из столбца "B", нужно вывести в желтую ячейку сумму ячеек заданного промежутка из столбца "C".
Пробовал привязать к ВПРу, но не хватило знаний, как учесть именно интервал, а не просто конкретное соответствие.
Надеюсь подскажите.
 
Код
=СУММ(ИНДЕКС(C3;ПОИСКПОЗ(RC[-1];C2;)):ИНДЕКС(C3;ПОИСКПОЗ(R[1]C[-1];C2;)))
Программисты - это люди, решающие проблемы, о существовании которых Вы не подозревали, методами, которых Вы не понимаете!
 
А не проще sumifs или из суммы до последнего заданного вычесть сумму до первого и все это через sumif? Файл не смотрел.

Посмотрел
=SUMIFS(C14:C22;B14:B22;">="&D2;B14:B22;"<="&D3)
=SUMIF(B:B;"<="&D3;C:C)-SUMIF(B:B;"<"&D2;C:C)
Изменено: БМВ - 22.07.2019 20:02:13
По вопросам из тем форума, личку не читаю.
 
Еще так можно
Код
=СУММ(СМЕЩ(C14;ПОИСКПОЗ(D2;B14:B22;)-1;;D3-D2+1))
Алексей М.
 
Ігор Гончаренко, АlехМ, спасибо вам большое. Обе формулы работают, буду изучать и разбираться.
 
Еще можно формулу массива применить. Ввод Ctrl+Shift+Enter
Код
=СУММ(СУММЕСЛИ(B:B;{"<":"<="}&D2:D3;C:C)*{-1:1}) 

или обычную

Код
=СУММПРОИЗВ(СУММЕСЛИ(B:B;{"<":"<="}&D2:D3;C:C)*{-1:1})
Изменено: АlехМ - 22.07.2019 20:27:17
Алексей М.
 
АlехМ,  горшочек, не вари :-) ТСу было достаточно или длинной или летучей. Мои были не поняты в виду англосакского диалекта.  :D
По вопросам из тем форума, личку не читаю.
 
Ф-ла АlехМ
Код
=СУММПРОИЗВ(СУММЕСЛИ(B:B;{"<":"<="}&D2:D3;C:C)*{-1:1})

хороша тем, что если в столбце  В есть значение, не входящее в заданный диапазон, например 90,
то формула возьмёт сумму только в указанном диапазоне , без 90
Страницы: 1
Наверх