let
    Source = Excel.CurrentWorkbook(){[Name="Table1"]}[Content],
    Fil = Table.SelectRows(Source, each [Название работ] <> null and [Название работ] <> ""),
    Ct = Table.TransformColumnTypes(Fil,{{"С", type date}, {"ПО", type date}, {"Длительность, дней", type number}, {"Связь/Очередность", type text}, {"Название работ", type text}}),

    // Определение ключа состоящего из номера раздела и подраздела.
    T1 = Table.TransformColumns
           (
            Ct,
            {"Связь/Очередность", each if _ = null then null else Text.End(_, Text.Length(_) - 5)}
            ),
    List = List.Accumulate
            (
             T1[Название работ], 
             [A = 0, B = 0, Out = {}], 
             (acc, this) =>
              let
               NewA = try Text.From(Text.Range(this, 7, Text.PositionOf(this, ".", Occurrence.First) - 7)) otherwise acc[A],
               NewB = if acc[A] <> NewA then 0 else acc[B] + 1
              in [A = NewA, B = NewB, Out = acc[Out] & {Text.From(NewA) & "." & Text.From(NewB)}]
            )[Out],
     T2 = Table.FromList(List),


    AddI1 = Table.AddIndexColumn(T1, "Index", 0, 1),
    AddI2 = Table.AddIndexColumn(T2, "Index", 0, 1),
    MQ = Table.NestedJoin(AddI1,{"Index"},AddI2,{"Index"},"Exp",JoinKind.LeftOuter),
    Tr1 = Table.ExpandTableColumn(MQ, "Exp", {"Column1"}, {"Column1"}),
    Tr2 = Table.RenameColumns(Tr1,{{"Column1", "Ref"}, {"Длительность, дней", "Длит"}, {"С", "Start"}, {"Связь/Очередность", "LinkTo"}}),
    Tr3 = Table.Buffer(Tr2),

    // Решение зависимостей
    DeepDive = (Ref, optional Deep) =>
      let
       CheckDeep = if Deep = null then 0 else Deep,
       Row = Tr3{[Ref = Ref]}
      in
       if Row[Start] = null then 
         if CheckDeep < 1000 then 
           try Date.AddDays(@DeepDive(Row[LinkTo], CheckDeep + 1), Tr3{[Ref = Row[LinkTo]]}[Длит]) otherwise null
         else
           null
       else 
         Row[Start],


    Tr5 = Table.AddColumn(Tr3, "NewStart", each DeepDive([Ref])),
    Tr6 = Table.AddColumn(Tr5, "NewEnd", each try Date.AddDays([NewStart], [Длит]) otherwise null),
    Rc = Table.RemoveColumns(Tr6,{"LinkTo", "Ref", "Start", "ПО", "Index"}),
    Ct2 = Table.TransformColumnTypes(Rc,{{"NewStart", type text}, {"NewEnd", type text}}),
    Final = Table.RenameColumns(Ct2,{{"NewStart", "Начало"}, {"NewEnd", "Конец"}})

in
    Final