Страницы: 1
RSS
Формулой проставить единицу напротив первой "сцепки" того или иного магазина и даты
 
Всем доброго времени суток!
Прощу подсказки или помощи в таком вопросе.
Имеется перечень названий магазинов с датами (к примеру, и даты и магазины внутри дат отсортированы по порядку)
Условно эта таблица это продажи любого товара в магазине (в рамках одного магазина может одна и та же дата может повторятся, так как продали более одного товара).
Вопрос в том, какую формулу применить, чтобы напротив названия магазина по строке проставить 1 (единицу), если в этом магазине в том или ином месяце (январь, февраль и т.д.  - могут быть разные годы) произошла первая продажа.
Сейчас проставлено руками. Допустимо использовать доп.столбцы.

.... интересует также решение, если даты и магазины не отсортированы.....
 
=IF(COUNTIFS($B$1:B2;B2;$A$1:A2;">"&EOMONTH(A2;-1);$A$1:A2;"<="&EOMONTH(A2;0))=1;1;"")
По вопросам из тем форума, личку не читаю.
 
формула массива:
Код
=--(A2=МИН(ЕСЛИ($B$2:$B$148=B2;$A$2:$A$148)))
Программисты - это люди, решающие проблемы, о существовании которых Вы не подозревали, методами, которых Вы не понимаете!
 
БМВ, спасибо.
изменил формулу на (не захватываю ячейки из заголовков)
=ЕСЛИ(СЧЁТЕСЛИМН($B$2:B2;B2;$A$2:A2;">"&КОНМЕСЯЦА(A2;-1);$A$2:A2;"<="&КОНМЕСЯЦА(A2;0))=1;1;"")
вроде бы все работает также хорошо...
 
Ігор Гончаренко, классная формула, но минус только в том, что она работает сразу со всем диапазоном данных (в отличие от формулы БМВ, которая делает нужное как бы "нарастающим итогом"). Хотя, с другой стороны, в некоторых случаях более выгодно, когда формула сразу
Потесировал более тщательно. Начиная со второго месяца (февраля) формула дает некорректный результат
Изменено: Konstantin Zhi - 17.02.2019 23:34:38
 
Формула Игоря не требует сортировки, но скорее всего более медлительная и даст сбой в случае если в одну дату будет один и тот же магазин, тогда будет 1 дважды. Ну и наоборот.
По вопросам из тем форума, личку не читаю.
 
Еще варианты
Код
=ТЕКСТ(СУММПРОИЗВ((B$2:B2=B2)*(МЕСЯЦ(A$2:A2)=МЕСЯЦ(A2)));"[=1]1;")
=ЕСЛИ(СУММПРОИЗВ((B$2:B2=B2)*(МЕСЯЦ(A$2:A2)=МЕСЯЦ(A2)))>1;"";1)
Изменено: АlехМ - 17.02.2019 22:36:39
Алексей М.
 
Цитата
АlехМ написал:
Еще варианты
Да, спасибо! обязательно посмотрю!
....
посмотрел.
все корректно работает
прошу раскрыть секрет, а что это за формат такой ""[=1]1;" внутри ф-ции ТЕКСТ() ???
Изменено: Konstantin Zhi - 17.02.2019 23:36:42
 
Цитата
Konstantin Zhi написал:
что это за формат такой ""[=1]1;" внутри ф-ции ТЕКСТ() ???
Это Алексей пытался так сократить но в данном случае ЕСЛИ победило :-)
Это условное форматирование. доступны максимально три условия, они записываются в скобках, а после каждого идет формат, в данном случае при равенстве 1 будет 1 , а при остальных значениях то что после ; то есть ничего.
тут Apply custom number formats based on conditions , правда на ENG, очень хорошо и с примерами и за исключением цвета, что просто формат, что функция TEXT одинаково работают.
Изменено: БМВ - 17.02.2019 23:53:38
По вопросам из тем форума, личку не читаю.
 
Цитата
БМВ написал:
данном случае ЕСЛИ победило
Это точно, аж на 5 символов.  ;)  
Алексей М.
 
в данных может быть так, что эти данные не за один год, а за несколько лет
дополнил формулы так
Код
=ТЕКСТ(СУММПРОИЗВ((B$2:B2=B2)*(МЕСЯЦ(A$2:A2)=МЕСЯЦ(A2))*(ГОД(A$2:A2)=ГОД(A2)));"[=1]1;")
=ЕСЛИ(СУММПРОИЗВ((B$2:B2=B2)*(МЕСЯЦ(A$2:A2)=МЕСЯЦ(A2))*(ГОД(A$2:A2)=ГОД(A2)))>1;"";1)
 
с годом покороче
Код
=ЕСЛИ(СУММПРОИЗВ((B$2:B2=B2)*(ТЕКСТ(A$2:A2;"ММГГГ")=ТЕКСТ(A2;"ММГГГ")))>1;"";1)
Алексей М.
 
Цитата
АlехМ написал:
с годом покороче
да, классно! ) спасибо!
и сам бы мог догадаться глядя на Ваши формулы, да вот некая зашоренность мышления и спешка не позволили это сделать ))
 
Excel - Наверно это единственное, где мужчины меряются и чем короче, тем  лучше
"МГГ"
:-)
Изменено: БМВ - 20.02.2019 21:06:26
По вопросам из тем форума, личку не читаю.
 
Ну тогда достаточно "МГ"
Но смешнее "МОЗГ"  :)  
Изменено: АlехМ - 20.02.2019 21:20:57
Алексей М.
 
АlехМ, Алексей, я не проверил , в результате у вас короче  :D
По вопросам из тем форума, личку не читаю.
 
рад, что такая "сухая" тема для кого-то стала развлечением )))
Страницы: 1
Наверх