Поиск  Пользователи  Правила  Войти
Форумы "Планета Excel" » Вопросы по Microsoft Excel
Страницы: 1
RSS
Как не отображать ноль, если нет даты?
 
#1
25.02.2019 13:09:10
Привет всем! Прошу Вашей помощи)

Дело в том, что при вычислении формулы, Excel, вместо пустой ячейки с датой, выдает дату 00.01.1900, снятие галки в настройках не подходит, так как будут другие столбцы с нулевыми значениями.
Сильно меня не ругайте, я только начал постигать азы Excel, дилетант, так сказать) А еще, я возможно не правильно, поставил вопрос по своей проблеме, возможно поэтому то и не нашел ответ в интернете. Заранее, Вас, благодарю за помощь)  
 
 
 
#2
25.02.2019 13:15:49
В параметрах листа снять галку отображения нулевых значений
 
 
 
#3
25.02.2019 13:17:23
=ЕСЛИ(формула="";"";формула)
 
 
 
#4
25.02.2019 13:18:29
Цитата
vikttur написал:
ходит, так как будут другие столбцы с нулевыми значениями.
Дело в том, что при вычислении формулы, Excel, вместо пустой ячейки с датой, выдает дату 00.01.1900, снятие галки в настройках не подходит, так как будут другие столбцы с нулевыми значениями.
 
 
 
#5
25.02.2019 13:19:45
Пустую строку вводить - не очень хороший вариант.
Правильно, когда данные в диапазоне одного формата. Но дата - число, а пустая строка - текст, хоть и нулевой длины.
 
 
 
#6
25.02.2019 13:20:00
Есть еще, варианты друзья?
Изменено: Rey&Boy - 25.02.2019 13:20:09
 
 
 
#7
25.02.2019 13:21:41
Цитата
vikttur написал:
Пустую строку вводить - не очень хороший вариант.Правильно, когда данные в диапазоне одного формата. Но дата - число, а пустая строка - текст, хоть и нулевой длины.
Пусть будет хотя бы ноль....но не 00.01.1900
 
 
 
#8
25.02.2019 13:22:10
Попробуйте использовать функцию условия
Код
=ЕСЛИ(ВПР($B2;БАЗА!$A$2:$C$20;3;0)="";"";ВПР($B2;БАЗА!$A$2:$C$20;3;0))
или
Код
=ЕСЛИОШИБКА(ЕСЛИ(ВПР($B2;БАЗА!$A$2:$C$20;3;0)="";"";ВПР($B2;БАЗА!$A$2:$C$20;3;0));"")
а если Вы готовы вместо пустот указывать в базе нечисловые символы (например "-"), то формулу получится еще больше упростить:
Код
=ЕСЛИОШИБКА(--ВПР($B3;БАЗА!$A$2:$C$20;3;0);"")
Кроме того, для ускорения работы MS Excel рекомендую отказаться от ссылок на весь столбец целиком
Изменено: IKor - 25.02.2019 13:22:47
 
 
 
#9
25.02.2019 13:22:25
Вам ведь подсказали в #3
Код
=ЕСЛИ(ИНДЕКС(БАЗА!C:C;ПОИСКПОЗ(ТОП!B:B;БАЗА!A:A;0))=0;"";)
В жизни нет ничего невозможного! Есть только недостаток знаний и умений.
 
 
 
#10
25.02.2019 13:22:47
Можно так
=IF(INDEX(БАЗА!C:C;MATCH(ТОП!B:B;БАЗА!A:A;0))<>"";INDEX(БАЗА!C:C;MATCH(ТОП!B:B;БАЗА!A:A;0));"")
можно иначе
=IFERROR(1/(1/INDEX(БАЗА!C:C;MATCH(ТОП!B:B;БАЗА!A:A;0)));""),
По вопросам из тем форума, личку не читаю.
 
 
 
#11
25.02.2019 13:23:26
Александр,
Проглядел) Пардон, сейчас попробую
 
 
 
#12
25.02.2019 13:26:27
Цитата
БМВ написал: =IFERROR(1/(1/INDEX(БАЗА!C:C;MATCH(ТОП!B:B;БАЗА!A:A;0)));"")
Супер - мне понравилась эта идея :)

Цитата
Rey&Boy написал: Пусть будет хотя бы ноль....но не 00.01.1900
В меню формата ячейки вместо формата даты можно использовать:
все форматы => ДД.ММ.ГГГГ;ДД.ММ.ГГГГ;"";@
 
 
 
#13
25.02.2019 13:28:56
Друзья, спасибо Вам всем) Спасибо, что ВЫ есть)
 
 
 
#14
25.02.2019 14:38:01
Цитата
=ЕСЛИ(формула="";"";формула)
Код
=ЕСЛИОШИБКА(ЕСЛИ(ИНДЕКС(БАЗА!C:C;ПОИСКПОЗ(ТОП!B:B;БАЗА!A:A;0))="";"";ИНДЕКС(БАЗА!C:C;ПОИСКПОЗ(ТОП!B:B;БАЗА!A:A;0)));" ")

без Н/Д
 
 
 
#15
26.02.2019 04:49:38
Можно еще, не трогая формул, просто в УФ добавить для ячеек, =0, формат ";;;"
Всё сложное - не нужно. Всё нужное - просто /М. Т. Калашников/
 
 
 
Страницы: 1
Наверх