Страницы: 1
RSS
Одной формулой определить идут ли даты в диапазоне по порядку
 
Всем доброго времени суток!
В файле небольшая задача суть которой в том, что хочется получить некую формулу, которая бы определяла идут ли даты в диапазоне по порядку (от А до Я, то есть сначала "старые", а потом более "свежие").
Сейчас сделано через доп.столбец. Это решение почти устраивает, но вот интересно, можно ли (подозреваю, что можно) создать одну формулу, которая бы это проверяла.
(в примере видно, но на всякий случай сделаю акцент на том, что одна и та же дата может повторятся много раз)
 
Konstantin Zhi, формула массива
Код
=И(A4:A38<=A5:A39)
 
да, верно, но что делать, если даты находятся в соответствующем столбце "Дата" умной таблицы? ))
 
Konstantin Zhi, возможно неоптимально, формула массива
Код
=И(СМЕЩ(Таблица1[Дата];;;СЧЁТ(Таблица1[Дата])-1)<=СМЕЩ(Таблица1[Дата];1;;СЧЁТ(Таблица1[Дата])-1))
 
=SUM(--(COUNTIF(A4:A39;">"&A4:A39)>ROWS(A4:A39)-ROW(A4:A39)+3))=0

Думал перемудрил ан нет, для умной таблицы тоже сработает. ну естественно +3 надо заменить на соответствующий сдвиг. если таблица перемещается
=SUM(--(COUNTIF(Table1[Дата];">"&Table1[Дата])>ROWS(Table1[Дата])-ROW(Table1[Дата])+3))=0
Изменено: БМВ - 20.02.2019 22:22:00
По вопросам из тем форума, личку не читаю.
 
Цитата
Konstantin Zhi написал:
если даты находятся в соответствующем столбце "Дата" умной таблицы?
А это как? Покажите.
Еще вариант
Код
=ЕСЛИ(СУММПРОИЗВ(--(D5:D39<D4:D38));СУММПРОИЗВ(--(D5:D39<D4:D38))&" даты не по порядку";"Все даты по порядку")
 
Цитата
gling написал: А это как? Покажите.
вот уже с решением от уважаемого Казанского
Изменено: Konstantin Zhi - 20.02.2019 22:22:15
 
Формула массива
Код
=НЕ(ИЛИ(Ч(A4:A38>A5:A39)))

PS. не обратил внимание на сообщение №3

Изменено: АlехМ - 20.02.2019 23:23:18
Алексей М.
Страницы: 1
Наверх