Страницы: 1
RSS
Макрос из Excel для ответа на письмо в Outlook, Ответ на письмо в Outlook из макроса в Excel с сохранением данных письма, на которое происходит ответ
 
Друзья всем привет, помогите пожалуйста с такой проблемой: есть макрос, который ищет письмо по указанной теме во всех входящих папках Outlook, затем отвечает на найденное письмо с определенным текстом, в который будет состоять в том числе из переменной равной теме письма. Когда я вставляю тело письма "".Body = "blah blah hello world" весь текст предыдущего стирается, остается только   "blah blah hello world. Как оставить весь текст предыдущего письма и поля  From..., СС.. и т. д предыдущего письма, которые автоматически формируется если отвечаешь на какое-либо письмо?
Всем спасибо за помощь)
Код
Public Sub Example(ByVal Tema As String)
    
    Dim OutApp As Outlook.Application
    Dim Namespace As Outlook.Namespace
    Dim Inbox As Outlook.MAPIFolder

    Set OutApp = New Outlook.Application 'активируем почту
    Set Namespace = OutApp.GetNamespace("MAPI") 'доступ ко всем данным Outlook, хранящимся в почтовых хранилищах пользователя.
'    Set Inbox = olNs.GetDefaultFolder(olFolderInbox)
    Set Inbox = Namespace.GetDefaultFolder(olFolderInbox) 'возвращается папка в коллекции папок

'   запускаем функцию - ищет письма с определенной темой во всех входящих с подпапками
    LoopFolders Inbox, Tema

    Set Inbox = Nothing
    
    MsgBox "Поиск писем закончен"
    
End Sub

Private Function LoopFolders(ByVal ParentFldr As Outlook.MAPIFolder, ByVal Tema As String)

    'тема письма, которую ищем
    Dim Subject As String
        Subject = Tema

'    Фильтр поиска по теме
    Dim Filter As String
    Filter = "@SQL=" & Chr(34) & "urn:schemas:httpmail:datereceived" & _
                       Chr(34) & " >= '01/01/1900' And " & _
                       Chr(34) & "urn:schemas:httpmail:datereceived" & _
                       Chr(34) & " < '12/31/2100' And " & _
                       Chr(34) & "urn:schemas:httpmail:subject" & _
                       Chr(34) & "Like '%" & Subject & "%'"

    Dim Items As Outlook.Items
    Set Items = ParentFldr.Items.Restrict(Filter) 'возвращая новую коллекцию, содержащую все элементы из исходного объекта, которые совпадают с фильтром
        Items.Sort "[ReceivedTime]", False 'Сортирует коллекцию элементов по указанному свойству, по возрастанию
     
'    Если письмо с указанной темой было найдено
    If Items.Count <> 0 Then
        Found = True
        ' Для найденного письма формируем ответное письмо
        For Each itm In Items
          Set ReplyAll = itm.ReplyAll 'ответить всем в письме
            With ReplyAll
                .SentOnBehalfOfName = "#*@*.ru" ' Поле "От" если необходимо отправить письмо от рассылки
                .To = "#*@*.ru" 'Поле "Кому"
                .CC = "#*@*.ru" 'Поле "Копия"
                .Body = "blah blah hello world"  'вставить заготовку тескта-ответа
                .Display 'показать письмо
            End With
        Next
    End If
    
'    myOlApp.Quit
'    Set myOlApp = Nothing
    

    Dim SubFldr As Outlook.MAPIFolder
'   //Рекурсировать через SubFldrs
    If ParentFldr.Folders.Count > 0 Then
        For Each SubFldr In ParentFldr.Folders
            LoopFolders SubFldr, Tema
            Debug.Print SubFldr.Name
        Next
    End If
   
End Function
Изменено: elena_VVV - 12.01.2020 21:27:14
 
Первое, что пришло в голову:
Код
 .Body = "blah blah hello world" & vbnewline & .body 

Не проверял, но скорее всего From, CC и прочее не получится сделать через приложенный код. Это все можно воссоздать через (не тестировал, пишу вслепую):
Код
dim tmp
tmp = "From: " & .From & vbnewline & _
          "To: " & .to & vbnewline & _'здесь нужно итерировать по всем получателям
          "CC: " & .CC 'здесь нужно итерировать всех кто в копии и т.д.
'используем tmp дальше, где потребуется
Изменено: Все_просто - 12.01.2020 23:24:34
С уважением,
Федор/Все_просто
 
если законспектировать строку ".Body = "blah blah hello world"  '" то эти все данные формируются автоматически, пример на скрине ( во вложении). Если я добавляю ответ с помощью .body, то эти все данные исчезают, как их сохранить и добавить текст ответа?
Изменено: elena_VVV - 12.01.2020 23:50:23
 
.HTMLBody = "blah blah hello world" & "<br>" & .HTMLBody

TO заполняется автоматически, да и CC тоже должно.
По вопросам из тем форума, личку не читаю.
 
Спасибо, ваш код работает отлично)
Изменено: elena_VVV - 15.01.2020 19:33:25
Страницы: 1
Наверх