Страницы: 1
RSS
Суммы значений с распределением по месяцам и дням недели., Нужна единая формула, позволяющая суммировать определенные значения
 
Коллеги, нужна ваша помощь.
Во вложении файл. В нем необходимо посчитать значения в "красных" ячейках.

Подробности:
Левая часть файла - это сетка. значения расставлены в определенные дни (будни и выходные) и в определенные месяцы.
Правая часть - ячейки, в которых должны быть суммы по строкам. Но для каждой строки необходимы отдельные суммы: июНь будни, июНь выходные, июЛь будни, июЛь выходные и т.д.

Я знаю, как посчитать сумму всех значений для определенного месяца. Пример специально оставил в августе, будни.
Но как в единой формуле сделать еще и распределение будни/выходные я совсем не понимаю. Нужна ваша помощь.

П.С. знаю, что можно решить эту проблему, просто выделив ячейки с выходными отдельно, а не всю строку целиком, но мне такое решение не подходит.  
 
Можно как-то так, формулами массива:
Код
в BS8:
=СУММ(($A8:$U8>0)*(МЕСЯЦ($A$5:$U$5)=МЕСЯЦ(BS$6))*(ДЕНЬНЕД($A$5:$U$5)<6))
в BT8:
=СУММ(($A8:$U8>0)*(МЕСЯЦ($A$5:$U$5)=МЕСЯЦ(BT$6))*(ДЕНЬНЕД($A$5:$U$5)>5))

(ввод формулы массива заканчиваем одновременно нажимая Ctrl+Shift+Enter)
Кому решение нужно - тот пример и рисует.
 
ortodox.frank, у вас данные за 2019, а посчитать хотите за 2018....
две формулы; для рабочих дней:
=СУММПРОИЗВ(СУММЕСЛИМН($A8:$U8;$A$6:$U$6;$A$6:$E$6;$A$5:$U$5;">="&BS$6;$A$5:$U$5;"<="&КОНМЕСЯЦА(BS$6;0)))
и для выходных:
=СУММПРОИЗВ(СУММЕСЛИМН($A8:$U8;$A$6:$U$6;$F$6:$G$6;$A$5:$U$5;">="&BS$6;$A$5:$U$5;"<="&КОНМЕСЯЦА(BS$6;0)))
 
Михаил Витальевич С., ваша работает!)

Супер)

Но вот такой вопрос: возможно ли вашу формулу скорректировать так, чтобы она не привязывалась к году? Как вы правильно заметили, раньше в ячейке отображался просто "июнь", и не важно, какого года. Для вашей формулы это важно.

Может, есть идеи, как это поправить? Возможно, как-то изменить формат записи месяца...


Пытливый, не работает, к сожалению.  
 
Покажите в файле, где не работает моя формула?
Кому решение нужно - тот пример и рисует.
 
Пытливый, вот скрин.
Сделал, как вы писали. Но значение не правильное.  
 
Цитата
ortodox.frank написал:
возможно ли вашу формулу скорректировать так, чтобы она не привязывалась к году?
Эту формулу - нет; другая формула:
=СУММ(МУМНОЖ((МЕСЯЦ($A$5:$U$5)=МЕСЯЦ(BY$6))*$A8:$U8;--(ТРАНСП($A$6:$U$6)=($A$6:$E$6))))
=СУММ(МУМНОЖ((МЕСЯЦ($A$5:$U$5)=МЕСЯЦ(BY$6))*$A8:$U8;--(ТРАНСП($A$6:$U$6)=($F$6:$G$6))))
Обе массивные
Изменено: Михаил Витальевич С. - 07.05.2019 21:43:55
 
Точно. Забыл в Деньнед еще один параметр указать. Надо вот так:
Код
=СУММ(($A8:$U8>0)*(МЕСЯЦ($A$5:$U$5)=МЕСЯЦ(BS$6))*(ДЕНЬНЕД($A$5:$U$5;2)<6))
Кому решение нужно - тот пример и рисует.
 
Цитата
Пытливый написал:
Точно. Забыл в Деньнед еще один параметр указать. Надо вот так:Код ? 1=СУММ(($A8:$U8>0)*(МЕСЯЦ($A$5:$U$5)=МЕСЯЦ(BS$6))*(ДЕНЬНЕД($A$5:$U$5;2)<6))
Немного поправил вашу версию:
=СУММ(($C8:$BT8)*(МЕСЯЦ($C$6:$BT$6)=МЕСЯЦ(BU$6))*(ДЕНЬНЕД($C$6:$BT$6;2)<6))

А то считалось кол-во значений, а не их сумма.

Теперь, вроде бы, формула идеальная, продолжу тестить.

Михаил Витальевич С., Пытливый, Спасибо вам большое, вы настоящие гуру)  
 
Цитата
ortodox.frank написал:
вы настоящие гуру
Настоящие гуру в этой теме - Пытливый, только вместо СУММ лучше использовать СУММПРОИЗВ, и работает быстрее, и массивный ввод не нужен.
Изменено: Михаил Витальевич С. - 08.05.2019 15:36:55
 
Михаил Витальевич С., я категорически не согласен быть гурой в одиночку! Только если с Вами. :)
Кому решение нужно - тот пример и рисует.
 
Я конкретно по выложенным решениям. Моё какое-то перегруженное. Как-будто за деньги, с оплатой в зависимости от сложности решения :)
Страницы: 1
Наверх