Страницы: 1
RSS
Как вытащить дату из ячейки
 
Добрый день, Уважаемые знатоки экселя,

Есть столбец с данными вида:
Белеберда 27th Apr
Белеберда Белеберда 1st May
Белеберда (Белеберда) 2nd May
и т.д.
Нужно вытащить даты, т.е. сделать отдельный столбец с датой.
А в идеале разделить на 2 столбца, чтобы в первом столбце оказалась Белеберда, а в следующем - дата, относящаяся к этой Белеберде
Дата должна быть в формате 27.04.2019, 01.05.2019, 02.05.2019
 
Файл пример выложите.
 
Пожалуйста..
 
=СЖПРОБЕЛЫ(ЛЕВБ(RC[-2];ДЛСТР(RC[-2])-8))
=--(--ПСТР(RC[-1];ДЛСТР(RC[-1])-7;2)&"."&ПОИСК(ПРАВБ(RC[-1];2);"ьanebarprayunulugepctovec")/2)

или
=СЖПРОБЕЛЫ(ЛЕВБ(A1;ДЛСТР(A1)-8))
=--(--ПСТР(A1;ДЛСТР(A1)-7;2)&"."&ПОИСК(ПРАВБ(A1;2);"ьanebarprayunulugepctovec")/2)
 
как вариант на PQ.
топорно в лоб.
Приёмы удаления текста можно посмотреть по ссылке
 
.
Код
=ДАТАЗНАЧ(ЕСЛИОШИБКА(--ПСТР(СЖПРОБЕЛЫ(ПСТР(ПРАВСИМВ(ПОДСТАВИТЬ(A1;" ";ПОВТОР(" ";50));99);1;60));1;2);--ПСТР(СЖПРОБЕЛЫ(ПСТР(ПРАВСИМВ(ПОДСТАВИТЬ(A1;" ";ПОВТОР(" ";50));99);1;60));1;1))&"/"&ЦЕЛОЕ(ПОИСК(ПСТР(СЖПРОБЕЛЫ(ПРАВСИМВ(ПОДСТАВИТЬ(A1;" ";ПОВТОР(" ";50));50));3;3);"77janfebmaraprmayjunjulaugsepoctnovdec")/3)&"/"&2019)
 
vikttur, что-то не очень получается, особенно дата, можете в моем файле отредактировать, если не трудно?
Изменено: sibstar75 - 19.05.2019 21:02:41
 
=--(LEFT(SUBSTITUTE(SUBSTITUTE(SUBSTITUTE(SUBSTITUTE(TRIM(RIGHT(SUBSTITUTE(A1;" ";REPT(" ";50));99));"th";);"rd";);"nd";);"st";);2) &"/"&FIND(RIGHT(A1;2);{"_anebarprayunulugepctovec"})/2)
или
=--(LEFT(TRIM(RIGHT(SUBSTITUTE(A1;" ";REPT(" ";50));99));FIND(" ";TRIM(RIGHT(SUBSTITUTE(A1;" ";REPT(" ";50));99)))-3)&"/"&FIND(RIGHT(A1;2);{"_anebarprayunulugepctovec"})/2)

А ведт и правда там всегда 6 символов в конце :-) . Вариант Виктора лучшее :-)
Изменено: БМВ - 19.05.2019 21:01:41
По вопросам из тем форума, личку не читаю.
 
Цитата
БМВ написал: . Вариант Виктора лучшее
А как же поворчать по поводу года? )

В файле
 
БМВ, спасибо!
Всем спасибо, работает!
vikttur, а что не так? Формулы нельзя цитировать?
 
Цитировать можно все, что угодно. Но ЦИТИРОВАТЬ, а не копировать БЕЗДУМНО!
 
чуть короче для даты
Код
=--(--ЛЕВБ(ПРАВБ(A1;8);2)&-ПОИСК(ПРАВБ(A1;2);" anebarprayunulugepctovec")/2)
Изменено: АlехМ - 19.05.2019 21:08:38
Алексей М.
Страницы: 1
Наверх