let
    FnRunSum = (sub as table, sort as text, col as text)=>
        let
            setRunningOrder = Table.Sort( sub, {{sort, Order.Ascending}} ),
            itemCount = Table.RowCount( sub ),
            sumList = List.Buffer( Table.ToColumns( Table.SelectColumns( setRunningOrder, {col}) ){0} ),
            calcRunningTotal = List.Generate(
                () => [id = 0, runningSum = sumList{id}],
                each [id] < itemCount,
                each [id = [id] + 1, runningSum = [runningSum] + sumList{id}],
                each {[id], [runningSum]}
            ),
            makeRunningTable = Table.FromRows( calcRunningTotal, {"id", "runningSum"} ),
            addIdxForRunningJoin = Table.AddIndexColumn( setRunningOrder, "id"),
            result = Table.Join( addIdxForRunningJoin, {"id"}, makeRunningTable, {"id"} )
        in
            result,

    Source = Excel.CurrentWorkbook(){[Name="Таблица1"]}[Content],
    ChangedType = Table.TransformColumnTypes(Source,{{"Date", type date}, {"Sale", Int64.Type}}),
    Custom1 = FnRunSum( ChangedType, "Date", "Sale" )
in
    Custom1

let
    FnRunSum = (sub as table, sort as text, col as text)=> /*Получаем в функцию таблицу, 
название столбца, по которому нужно сделать сортировку, и название столбца, по которому нужна, собственно, сумма.*/
        let
            setRunningOrder = Table.Sort( sub, {{sort, Order.Ascending}} ), //сортируем
            itemCount = Table.RowCount( sub ), //считаем количество элементов списка
            sumList = List.Buffer( Table.ToColumns( Table.SelectColumns( setRunningOrder, {col}) ){0} ),      /*выбираем нужный столбец 
и помещаем его в буфер */
            calcRunningTotal = List.Generate(             // самое интересное - генерим список записей с индексом и накоплением
                () => [id = 0, runningSum = sumList{id}],
                each [id] < itemCount,
                each [id = [id] + 1, runningSum = [runningSum] + sumList{id}],
                each {[id], [runningSum]}
            ),
            makeRunningTable = Table.FromRows( calcRunningTotal, {"id", "runningSum"} ),  //из списка создаем новую таблицу
            addIdxForRunningJoin = Table.AddIndexColumn( setRunningOrder, "id"),    /* берем таблицу, которая получилась после сортировки 
в начале функции и добавляем к ней столбец с индексами */
            result = Table.Join( addIdxForRunningJoin, {"id"}, makeRunningTable, {"id"} ) // джойним к этой таблице сгенерированный столбец с накоплением 
        in
            result,  //ПРОФИТ!
 
    Source = Excel.CurrentWorkbook(){[Name="Таблица1"]}[Content],
    ChangedType = Table.TransformColumnTypes(Source,{{"Date", type date}, {"Sale", Int64.Type}}),
    Custom1 = FnRunSum( ChangedType, "Date", "Sale" )
in
    Custom1

let
    Source        = Table.TransformColumnTypes(Excel.CurrentWorkbook(){[Name="Таблица1"]}[Content],{{"День", type date},{"Час", type time}}),
    Filter        = Table.SelectRows(Source,each [#"Накопительный Т_1 (час)"]<>null),
    Filter1       = Table.SelectRows(Source, each [#"Накопительный Т_1 (час)"]=null)[[День],[Час],[T_1],[N_1]],
    GroupByDate   = Table.Buffer(Table.Group(Filter1, {"День"}, {{"a", each _, type table},{"b",each List.Sum([T_1])}})),
    f1=(a)        =>List.Buffer(List.Generate(()=>[i=0,v=a{0}],each [i] < List.Count(a),each [i=[i]+1,v=[v]+a{i}],each [v])),
    f2=(t)=>let
        rec       = Cumulatively{[День=t[День]{0}]},
        a         = f1(List.Buffer(t[T_1])),
        b         = List.Zip(List.Reverse(((a)=>List.Zip({a,{rec[b]}}))(List.Reverse(a)))),
        c         = Table.FromColumns(Table.ToColumns(t)&b,Table.ColumnNames(Source))
    in Table.RemoveColumns(c,{"День"}),
    Cumulatively  = Table.FromColumns(List.RemoveLastN(Table.ToColumns(GroupByDate),1)&{f1(GroupByDate[b])},Table.ColumnNames(GroupByDate)),
    Cumulatively1 = Table.ExpandTableColumn(Table.TransformColumns(Cumulatively,{{"a",f2}}), "a", List.Skip(Table.ColumnNames(Source),1))
in
    if Table.RowCount(Filter1)>0 then Table.Combine({Filter,Table.RemoveColumns(Cumulatively1,{"b"})}) else Source