Страницы: 1
RSS
Подсчет кол-во позиций в группе
 
Добрый день! Подскажите пожалуйста как посчитать кол-во позиций которые входят в конкретную группу для конкретного время с разбивкой по типам товара? Некоторые позиции имеют 2 группы их нужно считать по двум группам.
 
=COUNTIFS($C$1:$C$107;H2;$D$1:$D$107;I2)
и если не мудрить и не извлекать из шапки Тлф и подобное
=COUNTIFS($C$1:$C$107;H2;$D$1:$D$107;I2;$A$1:$A$107;"Тлф")
По вопросам из тем форума, личку не читаю.
 
БМВ,  Приветствую.
Давай те чуть по мудрим:
для общего кол-ва позиций:
=СУММПРОИЗВ(($I2=$D$2:$D$107)*($H2=$C$2:$C$107))
для категорий товаров:
=СУММПРОИЗВ((СЖПРОБЕЛЫ(ПСТР(ПОДСТАВИТЬ(K$1;" ";ПОВТОР(" ";ДЛСТР(K$1)));ДЛСТР(K$1)*(2-1)+1;ДЛСТР(K$1)))=$A$2:$A$107)*($I2=$D$2:$D$107)*($H2=$C$2:$C$107))

Только вот это мне как то не совсем понятно:
Цитата
Dusha написал:
имеют 2 группы их нужно считать по двум группам.
 
Два варианта в приложении
 
Aleksey1107, в данном случае нет  смысла использовать SUMPRODUCT, а мудрить можно так
=COUNTIFS($C$1:$C$107;$H2;$D$1:$D$107;$I2;$A$1:$A$107;TRIM(RIGHT(SUBSTITUTE(K$1;" ";REPT(" ";99));99)))

что касаемо
Цитата
Dusha написал:
Некоторые позиции имеют 2
то скорее всего
=COUNTIFS($C$1:$C$107;H6;$D$1:$D$107;I6)+COUNTIFS($E$1:$E$107;H6;$F$1:$F$107;I6)
и
=COUNTIFS($C$1:$C$107;$H6;$D$1:$D$107;$I6;$A$1:$A$107;TRIM(RIGHT(SUBSTITUTE(K$1;" ";REPT(" ";99));99)))+COUNTIFS($E$1:$E$107;$H6;$F$1:$F$107;$I6;$A$1:$A$107;TRIM(RIGHT(SUBSTITUTE(K$1;" ";REPT(" ";99));99)))

не думаю что в летучий вариант стоит уходить, несмотря на компактность
=SUM(COUNTIFS(OFFSET($C$1:$C$107;;{0;2});H11;OFFSET($D$1:$D$107;;{0;2});I11))
=SUM(COUNTIFS(OFFSET($C$1:$C$107;;{0;2});$H11;OFFSET($D$1:$D$107;;{0;2});$I11;$A$1:$A$107;TRIM(RIGHT(SUBSTITUTE(K$1;" ";REPT(" ";99));99))))

jakim,  Как это не удивительно, но доказано на опытах, при использовании SUMIFS/COUNTIFS в отличии от SUMIF/COUNTIF, не рационально использовать диапазон столбца. Страдает производительность ибо не умеют они работать с используемым диапазоном и весь столбец берут в расчет. Правда заметно это только на большом количестве, но помнить надо.
Изменено: БМВ - 13.11.2019 23:43:33
По вопросам из тем форума, личку не читаю.
 
БМВ, формула со СМЕЩ прям космос  :) .
Можно чуть расшифровки? Массив столбца {0:2} это как ?
 
Цитата
Aleksey1107 написал:
Массив столбца {0:2} это как ?
просто смещаем исходный диапазон на 0 или 2 столбца,  получаем или C или D.
По вопросам из тем форума, личку не читаю.
 
Цитата
БМВ написал:
Прикрепленные файлы
Copy of пример1271.xlsx  (12.68 КБ)
Спасибо работает! Но подскажите если Тип товара идет из 2х слов и он перестает считать, что в этом случаи нужно поправить?  
 
Dusha,  именно по этому и не хотел мудрить. Это другой вопрос и другая тема.
По вопросам из тем форума, личку не читаю.
 
БМВ, подскажите а что-то можно с этим сделать?
 
Dusha, , Вы посмотрели бы, другие варианты решения вашей задачи, для Вас тут набросали под любые данные!
Для ваших исходных данных вариант jakim, Вам подходит полностью.

БМВ, Спасибо за расшифровку!
Пока еще в процессе понимания.  
 
Цитата
Aleksey1107 написал:
Для ваших исходных данных вариант  jakim , Вам подходит полностью
ну это неверное утверждение, так как второй набор данных не охвачен.

Dusha, ну если у вас всегда "Кол-во xxxx"
MID(K$1;8;99) без премудростей .
По вопросам из тем форума, личку не читаю.
 
Цитата
БМВ написал:
ну это неверное утверждение,
Согласен криво написал.
Но готовый вариант для исходных данных есть. Это использовать файл jakim, и к его формуле по аналогии Вашей БМВ, + еще одну СЧЁТЕСЛИМН.
Или же просто в Вашей формуле БМВ,  заменить Диапазон условия товара ссылкой на ячейку.
=СЧЁТЕСЛИМН($C$1:$C$107;$H8;$D$1:$D$107;$I8;$A$1:$A$107;L1)+СЧЁТЕСЛИМН($E$1:$E$107;$H8;$F$1:$F$107;$I8;$A$1:$A$107;L1)
И все заработает  
 
БМВ,jakim, спасибо! Все работает!)))
Страницы: 1
Наверх