Поиск  Пользователи  Правила  Войти
Форумы "Планета Excel" » Вопросы по Microsoft Excel
Страницы: 1
RSS
Выделить из текста дату в формате DD.MM.YYYY
 
#1
17.08.2019 15:23:34
привет!
Подскажите, пож-ста, как например в тексте "оказание услуг за 20 августа 2019 г." выделить из текста дату в соседней ячейке в формате DD.MM.YYYY?
Изменено: Gulya1 - 17.08.2019 15:50:11
 
 
 
#2
17.08.2019 15:38:36
Здравствуйте
Код
=(ЛЕВСИМВ(ПСТР(A1;19;ДЛСТР(A1));6)&" "&ЛЕВСИМВ(ПРАВСИМВ(A1;7);4))*1

а вообще файл-пример нужно прикреплять

Изменено: Настя_Nastya - 17.08.2019 15:46:35
 
 
 
#3
17.08.2019 15:52:30
Простите, вложила.
Не могли бы на примере еще раз посмотреть?И как в англоязычной версии прописать формулу? :)
 
 
 
#4
17.08.2019 16:12:42
Код
=ПРОСМОТР(99^99;--ЛЕВСИМВ(ПСТР(ПОДСТАВИТЬ(A2;"мая";"май")&"_0";МИН(НАЙТИ({0;1;2;3;4;5;6;7;8;9};ПОДСТАВИТЬ(A2;"мая";"май")&"_0123456789"));100);{1;2;3;4;5;6;7;8;9;10;11;12;13;14;15}))

Изменено: Настя_Nastya - 17.08.2019 16:40:43
 
 
 
#5
17.08.2019 16:19:24
=MAX(IFERROR(--SUBSTITUTE(LOWER(TRIM(LEFT(RIGHT(SUBSTITUTE(A2;" ";REPT(" ";99));500);300)));TEXT(ROW(1:12)*28;"[$-ru-RU-x-genlower]ММММ");TEXT(ROW(1:12)*28;"МММ"));))

UPD
или
=MAX(IFERROR(--SUBSTITUTE(LOWER(TRIM(LEFT(RIGHT(SUBSTITUTE(A2;" ";REPT(" ";99));500);300)));TEXT(ROW(1:12)*28;"[$-FC19]ММММ");TEXT(ROW(1:12)*28;"МММ"));))
Изменено: БМВ - 17.08.2019 17:59:45
По вопросам из тем форума, личку не читаю.
 
 
 
#6
17.08.2019 16:27:57
Здравствуйте, коллеги! Михаил, родительный падеж месяцев в такой нотации понимают только последние версии Excel. При прочих равных, мне кажется, лучше по-старому.
Владимир
 
 
 
#7
17.08.2019 16:29:18
БМВ, не работает с "мая"
Изменено: Настя_Nastya - 17.08.2019 16:31:01
 
 
 
#8
17.08.2019 16:33:46
sokol92, Владимир, приветствую. Скорее всего да, но я не помню что там за код. Предположу что [$-FC19]
Изменено: БМВ - 17.08.2019 16:34:27
По вопросам из тем форума, личку не читаю.
 
 
 
#9
17.08.2019 16:34:07
Cпасибо всем большое!Очень помогли)
 
 
 
#10
17.08.2019 16:38:24
Цитата
БМВ написал:
Предположу что [$-FC19]
Да. У меня в Закладках ссылка сюда.  :)  
Владимир
 
 
 
#11
17.08.2019 16:41:32
Что-то в #5 (вложенный пример) не исправлено: "27 марта 2019"
Изменено: sokol92 - 17.08.2019 16:42:57
Владимир
 
 
 
#12
17.08.2019 17:26:24
Не знаю что там с маем, к меня все работает, но файл перезолил с двумя вариантами.

Цитата
sokol92 написал:
У меня в Закладках ссылка  сюда .
а у меня сюда :-)
Изменено: БМВ - 17.08.2019 17:29:31
По вопросам из тем форума, личку не читаю.
 
 
 
#13
17.08.2019 17:44:23
Теперь всё хорошо, работает с именительным и родительным падежoм и позволяет сокращать наименование месяца вплоть до 3 букв. Если кодовая страница по умолчанию отлична от Windows-1251, то работать не будет (из-за русских букв М в формате).
Владимир
 
 
 
#14
17.08.2019 17:51:11
Цитата
sokol92 написал:
Windows-1251, то работать не будет (из-за русских букв М в формате).
ДА по тому что какой-то идиот предложил локализовать то , что не надо было трогать. Странно, что не стали трогать тригонометрические.
Глупо выглядит "MMMM";"ММММ" :-)
=MAX(IFERROR(--SUBSTITUTE(LOWER(TRIM(LEFT(RIGHT(SUBSTITUTE(A2;" ";REPT(" ";99));500);300)));TEXT(ROW(1:12)*28;"[$-ru-RU-x-genlower]"&IF(TEXT(1;"D")=1;"MMMM";"ММММ"));TEXT(ROW(1:12)*28;IF(TEXT(1;"D")=1;"MMM";"МММ")));))
Изменено: БМВ - 17.08.2019 17:53:30
По вопросам из тем форума, личку не читаю.
 
 
 
#15
17.08.2019 17:56:56
Цитата
БМВ написал:
какой-то идиот предложил локализовать то , что не надо было трогать
Я выражаюсь мягче, но суть та же.

Нужно поправить очепятку:

=МАКС(ЕСЛИОШИБКА(--ПОДСТАВИТЬ(СТРОЧН(СЖПРОБЕЛЫ(ЛЕВСИМВ(ПРАВСИМВ(ПОДСТАВИТЬ(A2;" ";ПОВТОР(" ";99));500);300)));ТЕКСТ(СТРОКА(1:12)*28;"[$-ru-RU-x-genlower]"&ЕСЛИ(ТЕКСТ(1;"D")="1";"MMMM";"ММММ"));ТЕКСТ(СТРОКА(1:12)*28;ЕСЛИ(ТЕКСТ(1;"D")="1";"MMM";"МММ")));))
Изменено: sokol92 - 17.08.2019 18:36:56
Владимир
 
 
 
Страницы: 1
Наверх