Поиск  Пользователи  Правила  Войти
Форумы "Планета Excel" » Вопросы по Microsoft Excel
Страницы: 1
RSS
Максимальный, средний, частый показатели за месяц, Максимальный, средний, частый показатели за месяц
 
#1
17.08.2021 07:13:51
Здравствуйте!
В продолжение темы автоматического вывода данных за каждый месяц в привязке к календарному дню, необходима формула для расчёта максимального, среднего, частого показателя за месяц. Пример за январь введён вручную.
 
 
 
#2
17.08.2021 07:37:02
CarBon,
Код
=МАКСЕСЛИ($C$14:$NC$14;$C$13:$NC$13;">="&D2;$C$13:$NC$13;"<="&КОНМЕСЯЦА(D2;0))
=СРЗНАЧЕСЛИМН($C$14:$NC$14;$C$13:$NC$13;">="&D2;$C$13:$NC$13;"<="&КОНМЕСЯЦА(D2;0))
=МОДА(ЕСЛИ(($C$13:$NC$13>=D2)*($C$13:$NC$13<=КОНМЕСЯЦА(D2;0));$C$14:$NC$14))
 
 
 
#3
17.08.2021 07:56:00
Расчёт среднего работает, максимальный и частый - нет. Вроде также копировал формулу. А можете сам файл с вставленными формулами загрузить?
Изменено: vikttur - 17.08.2021 09:07:01
 
 
 
#4
17.08.2021 07:58:27
CarBon,
какая у Вас версия excel?

вводить через ctrl+shift+enter
Код
=МАКС(ЕСЛИ(($C$13:$NC$13>=D2)*($C$13:$NC$13<=КОНМЕСЯЦА(D2;0));$C$14:$NC$14))
=МОДА(ЕСЛИ(($C$13:$NC$13>=D2)*($C$13:$NC$13<=КОНМЕСЯЦА(D2;0));$C$14:$NC$14))
P.S. цитата выше смотрится уж очень не красиво. Лучше выделяйте определенный текст для цитирования  ;)  
Изменено: evgeniygeo - 17.08.2021 08:08:43
 
 
 
#5
17.08.2021 08:05:41
Цитата
evgeniygeo написал: какая у Вас версия excel?
MO профессиональный плюс 2010
14.0.6023.1000 (32-разрядная)
 
 
 
#6
17.08.2021 08:24:35
Еще варианты:
  1. =МАКС(ИНДЕКС($C$14:$NC$14;ПОИСКПОЗ(D$2;$C$13:$NC$13;)):ИНДЕКС($C$14:$NC$14;ПОИСКПОЗ(КОНМЕСЯЦА(D$2;0);$C$13:$NC$13;)))
  2. =СРЗНАЧ(ИНДЕКС($C$14:$NC$14;ПОИСКПОЗ(D$2;$C$13:$NC$13;)):ИНДЕКС($C$14:$NC$14;ПОИСКПОЗ(КОНМЕСЯЦА(D$2;0);$C$13:$NC$13;)))
  3. =МОДА(ИНДЕКС($C$14:$NC$14;ПОИСКПОЗ(D$2;$C$13:$NC$13;)):ИНДЕКС($C$14:$NC$14;ПОИСКПОЗ(КОНМЕСЯЦА(D$2;0);$C$13:$NC$13;)))
Изменено: Максим В. - 17.08.2021 08:25:47
Если в мире всё бессмысленно, — сказала Алиса, — что мешает выдумать какой-нибудь смысл? ©Льюис Кэрролл
 
 
 
#7
17.08.2021 09:07:47
Максим В.,
Всё работает! Благодарю!
Изменено: CarBon - 17.08.2021 09:29:01
 
 
 
#8
17.08.2021 09:09:08
CarBon, не все работает - у Вас не работает понятие цитирования. Вернитесь, приведите в порядок сообщение. Кнопка цитировагия для помощи в создании цитат, а не для копирования
Изменено: vikttur - 17.08.2021 09:09:45
 
 
 
Страницы: 1
Наверх