Страницы: 1
RSS
Вывод дат из списка по условию
 
Здравствуйте форумчане, не смог найти ответ, возможно не правильно формулировал вопрос.
Требуется из списка дат, расположенных по порядку в ячейках A1:A10 в ячейки C1:C10 вывести только даты больше даты указанной в ячейке B1.
Реализовать сие нужно посредством формул.
Еще в ячейки С1:С10 следует выводить без пропусков, начиная с первой даты удовлетворяющей условию.
Изменено: sfs - 28.11.2019 17:41:14
 
Добрый вечер!
Цитата
sfs написал:
ывести только даты больше даты указанной в ячейке B1.
Запросто:
массивная
Код
=ЕСЛИОШИБКА(ИНДЕКС($A$1:$A$10;НАИМЕНЬШИЙ(ЕСЛИ($A$1:$A$10>$B$1;СТРОКА($A$1:$A$10);"");СТРОКА()));"")
 
Цитата
Aleksey1107 написал:
=ЕСЛИОШИБКА(ИНДЕКС($A$1:$A$10;НАИМЕНЬШИЙ(ЕСЛИ($A$1:$A$10>$B$1;СТРОКА($A$1:$A$10);"");СТРОКА()));"")
Что-то работает не так, выводит в С1:С10 пустые значения. возможно из-за того что первое (ячейка А1) значение в А1:А10 меньше В1
 
sfs, файл пример покажите. Как есть, как надо.
Если в мире всё бессмысленно, — сказала Алиса, — что мешает выдумать какой-нибудь смысл? ©Льюис Кэрролл
 
Цитата
sfs написал:
Что-то работает не так,
У меня в файле ;)   все корректно работает
Изменено: Aleksey1107 - 28.11.2019 17:47:10
 
Долго думаете. Формула:
=НАИМЕНЬШИЙ($A$1:$A$19;СЧЁТЕСЛИ($A$1:$A$19;"<"&$B$1)+СТРОКА(B2))
Если в мире всё бессмысленно, — сказала Алиса, — что мешает выдумать какой-нибудь смысл? ©Льюис Кэрролл
 
Цитата
Максим В. написал:
sfs , файл пример покажите. Как есть, как надо.
В Примере другие ячейки:  На Лист 1. Выбираем из ячеек F39:F44 в ячейки C48:C52 только даты большие G37
По порядку, без пропусков чтобы корректно считалась пеня.
Изменено: sfs - 28.11.2019 17:49:52
 
=НАИМЕНЬШИЙ($F$39:$F$44;СЧЁТЕСЛИ($F$39:$F$44;"<"&$G$37)+СТРОКА(B1))
Если в мире всё бессмысленно, — сказала Алиса, — что мешает выдумать какой-нибудь смысл? ©Льюис Кэрролл
 
Формула
Код
=IFERROR(AGGREGATE(15;6;A$1:A$200/(A$1:A$200>B$1);ROWS($1:1));"")
 
Цитата
Максим В. написал:
=НАИМЕНЬШИЙ($F$39:$F$44;СЧЁТЕСЛИ($F$39:$F$44;"<"&$G$37)+СТРОКА(B1))
Спасибо за подсказку решения
 
Цитата
jakim написал:
=IFERROR(AGGREGATE(15;6;A$1:A$200/(A$1:A$200>B$1);ROWS($1:1));"")
А на руссифицированом  экселе как будет?
 
Код
=ЕСЛИОШИБКА(АГРЕГАТ(15;6;A$1:A$200/(A$1:A$200>B$1);ЧСТРОК($1:1));"")
 
sfs,НУ и в догонку, мой работающий вариант

=ЕСЛИОШИБКА(ИНДЕКС($F$39:$F$44;НАИМЕНЬШИЙ(ЕСЛИ($F$39:$F$44>$G$37;СТРОКА($F$39:$F$44)-СТРОКА($F$39)+1;"");СТРОКА()-СТРОКА($C$48)+1));"")
 
Цитата
Aleksey1107 написал:
=ЕСЛИОШИБКА(ИНДЕКС($F$39:$F$44;НАИМЕНЬШИЙ(ЕСЛИ($F$39:$F$44>$G$37;СТРОКА($F$39:$F$44)-СТРОКА($F$39)+1;"");СТРОКА()-СТРОКА($C$48)+1));"")
Благодарю
 
Цитата
jakim написал:
=ЕСЛИОШИБКА(АГРЕГАТ(15;6;A$1:A$200/(A$1:A$200>B$1);ЧСТРОК($1:1));"")
А это самое компактное и клевое решение, если у Вас конечно Excel 2010 и новее. Вообще АГРЕГАТ было бы неплохо раскрыть в отдельном уроке с демонстрацией наибольшего количества побочных возможностей данной функции.
Изменено: sfs - 29.11.2019 10:06:00
Страницы: 1
Наверх