Private Sub Worksheet_Change(ByVal Target As Range)
    If Target.Address(0, 0) = "B4" Then
        GetWb Target
    End If
End Sub

Sub GetWb(rInput As Range)
    Dim car As String
    car = rInput.Value
    
    Dim a As Variant
    a = Range("T4:U6")
    Dim fso As Object
    Set fso = CreateObject("Scripting.FileSystemObject")
    Dim y As Long
    Dim sFull As String
    Dim sName As String
    Dim wb As Workbook
    Dim r As Range
    Dim bClose As Boolean
    
    Application.ScreenUpdating = False
    
    On Error Resume Next
        For y = 1 To UBound(a, 1)
            sFull = a(y, 2)
            sName = fso.getfilename(sFull)
            Set wb = Nothing
            Set wb = Workbooks(sName)
            bClose = False
            If wb Is Nothing Then
                Set wb = Workbooks.Open(sFull, False, True)
                bClose = True
            End If
            If Not wb Is Nothing Then
                Set r = wb.Sheets(1).Columns("C:D")
                If WorksheetFunction.CountIfs(r.Columns(1), car) Then
                    rInput.Cells(1, 2).Value = WorksheetFunction.VLookup(car, r, 2, 0)
                    If bClose Then wb.Close False
                    Exit For
                Else
                    If bClose Then wb.Close False
                End If
            End If
            Set wb = Nothing
        Next
    On Error GoTo 0
    
    Application.ScreenUpdating = True
    
End Sub