let
    fn=(t) => 
        let
            Source = Table.RenameColumns(t[[Номенклатура],[Путь],[Уровень]],{"Номенклатура","Владелец/номенклатура"}),

            Nested1 = Table.NestedJoin(Source,"Владелец/номенклатура", Source1, "Владелец/номенклатура" ,"a"),
            Expand1 = Table.ExpandTableColumn(Nested1, "a", {"Спецификация"}),
            
            Nested2 = Table.NestedJoin(Expand1,"Спецификация", Source2, "Спецификация" ,"a"),
            Expand2 = Table.ExpandTableColumn(Nested2, "a", {"Номенклатура"}),
            
            Nested3 = Table.NestedJoin(Expand2,"Номенклатура", Source3, "Владелец" ,"a"),
            Expand3 = Table.ExpandTableColumn(Nested3, "a", {"Индекс"}),
            
            Nested4 = Table.NestedJoin(Expand3,"Номенклатура", Source4, "Номенклатура" ,"a"),
            Expand4 = Table.ExpandTableColumn(Nested4, "a", {"Цена"}),
            
            Filter = Table.SelectRows(Expand4 ,each [Номенклатура]<>null),
            Path   = Table.ReplaceValue(Filter,each [Номенклатура],null,(a,b,c)=>a&"_"&b,{"Путь"}),
            Inc    = Table.TransformColumns(Path,{{"Уровень",each _+1}})

        in Inc,
    Source  = Table.AddColumn(Table.DuplicateColumn(Excel.CurrentWorkbook(){[Name="Таблица1"]}[Content],"Номенклатура","Путь"),"Уровень",each 1),
    
    Source1 = Table.Buffer(Влад_ном_спец),
    Source2 = Table.Buffer(Спец_ном),
    Source3 = Table.Buffer(Влад_спец_индекс),
    Source4 = Table.Buffer(Цена),

    Generate  = Table.Combine(
      List.Generate(                                 /*формируем список таблиц, каждая таблица - один уровень*/
          ()=>Source,                                /*начальное значение - уровень1, сформированный в Source*/
          each List.NonNullCount([Номенклатура])>0,  /*условие формирования элементов массива - 
                                                       в столбце Номенклатура должно быть хотя бы 1 не null значение*/
          each fn(_)                                 /*пока выполняется условие, продолжаем формировать элементы
                                                       списка, передавая в функцию fn предыдущую сформированную таблицу
                                                       таблицы, не прошедшие проверку в выдачу не попадают*/
      )
  ),
    Reorder = Table.ReorderColumns(Generate,{"Владелец/номенклатура", "Спецификация", "Номенклатура","Путь","Уровень"})    
in
    Reorder

= List.Generate(                                 
          ()=>Source,                                
           each List.NonNullCount([Номенклатура])>0,   
           each fn(_))