Страницы: 1
RSS
преобразовать дроби в виде текста в значения
 
Данные из 1С выгружаются в формате дробей, то есть текста вида "1/10", "1/4", "3/4", "1/2".
Как перевести их формулой в значения (в прикреплённом примере - как значения из столбца A сделать значениями в столбце B)?
! Обязательно формулой - так как работать с получившимся файлом потом будут неопытные пользователи.
 
Код
=ЕСЛИОШИБКА(--(ЛЕВБ($A3;ПОИСК("/";$A3)-1))/--(ПСТР($A3;ПОИСК("/";$A3)+1;ДЛСТР($A3)));--$A3)
Вполне такой нормальный кинжальчик. Процентов на 100
 
perminovandr, так?
Код
=ЛЕВСИМВ(A3;1)/ЕСЛИОШИБКА(ПСТР(A3;ПОИСК("/";A3)+1;99);1)
 
еще до кучи
Код
=СЖПРОБЕЛЫ(ЛЕВБ(ПОДСТАВИТЬ(A3;"/";ПОВТОР(" ";10));5))/СЖПРОБЕЛЫ(ПРАВБ(ПОДСТАВИТЬ(A3;"/";ПОВТОР(" ";10));5))
Лень двигатель прогресса, доказано!!!
 
китин, спасибо... А не через деление текста, расположенного до знака "/" на текст, расположенный после знака "/" возможно?
Кстати, в чём сакральный смысл применения "ЛЕВБ" вместо "ЛЕВСИМВ"? Да и "--", на мой взгляд здесь излишни. Или нет?
 
ну и для коллекции
Код
=--ЕСЛИ(ЕЧИСЛО(ПОИСК("/";A3));--ПСТР(A3;1;ПОИСК("/";A3)-1)/--ПОДСТАВИТЬ(A3;ПСТР(A3;1;ПОИСК("/";A3));"");A3)
 
С помощью макрофункции ВЫЧИСЛИТЬ()
Если в мире всё бессмысленно, — сказала Алиса, — что мешает выдумать какой-нибудь смысл? ©Льюис Кэрролл
 
Цитата
perminovandr написал:
в чём сакральный смысл применения "ЛЕВБ"
просто короче
Цитата
perminovandr написал:
и "--", на мой взгляд здесь излишни
да, излишни, но привычка вторая натура.
и, кстати да, если тут
Код
--$A3
убрать --, то будет текст. а если дальше будут расчеты это не есть хорошо
Вполне такой нормальный кинжальчик. Процентов на 100
 
Коллеги, всем спасибо за помощь!
Немного взгрустнул, что нет прямой функции / комбинации функций для перевода значения "1/10" в 0,1.
Вариант Максима В. с помощью макрофункции "ВЫЧИСЛИТЬ" мне показался более логичным, его и реализовал (хоть и пришлось пересохранить файл в формат .xlsm)
Страницы: 1
Наверх