Поиск  Пользователи  Правила 
Закрыть
Логин:
Пароль:
Забыли свой пароль?
Регистрация
Войти
 
Страницы: 1
RSS
Форматирование сложного числа с разбивкой по ячейкам
 
Здравствуйте.
Требуется прописать более менее универсальные формулы для преобразования ячеек формата 5:2 (11:5, 8:11, 11:9, 7:11, 8:0, 15:13, 11:7). Вывести все числа, разделенные двоеточиями и запятыми в отдельные ячейки. В скобках может быть от 1 до 7 пар цифр. Если пар меньше 7, в соответствующие ячейки забиваются нули. Файл пример в прицепе - желтым выделены исходные данные, зеленые нужно получить. Дотумкал только как разделить цифры до скобок.
Изменено: Jesuit - 25 Мар 2020 11:21:38
 
Jesuit, А если заменить все разделители на пробел, а потом применить Текст по столбцам?
Если в мире всё бессмысленно, — сказала Алиса, — что мешает выдумать какой-нибудь смысл? ©Льюис Кэрролл
 
Код
=ЕСЛИОШИБКА(--ПСТР(ПОДСТАВИТЬ(ПОДСТАВИТЬ(ПОДСТАВИТЬ(ПОДСТАВИТЬ(ПОДСТАВИТЬ(" "&$A2;"(";);",";);":";" ");")";);" ";ПОВТОР(" ";99));СТОЛБЕЦ(A2)*99;99);)
 
Гениально....И формула всего одна. На все. Бог в простоте! СПАСИБО!
 
Вдогонку еще одно решение на том же принципе, что и у Андрей Лящук
 
Сначала привести к единому виду:
=ПОДСТАВИТЬ(ПОДСТАВИТЬ(ПОДСТАВИТЬ(A2;" (";":");", ";":");")";)
Потом разносить:
=СЖПРОБЕЛЫ(ПСТР(ПОДСТАВИТЬ(":"&$B2;":";ПОВТОР(" ";99));СТОЛБЕЦ(A1)*99;99))
Можно объединить в одной формуле (заменить ссылку первой формулой)

P.S. Оказывается... Андрей Лящук уже предложил такое )
 
Опа. Столкнулся со сложностью. Если в файле Андрея Лящука ячейки вырезать и вставить в другие столбцы - то рассчитывается все неверно. Причем ссылки на ячейки меняются верно. Но вот выводит всякую фигню. Как то можно это исправить? А то работает только в том случае, если форматируемые ячейки именно в столбце A  стоят. Удаление $ как абсолютной ссылки не помогает. Т.е. если просто даже сдвигать столбцы, то последовательно смещаюца данные выводимые с затиранием первичных. Первый раз такое вижу.
Изменено: Jesuit - 25 Мар 2020 14:15:25
 
Цитата
=ЕСЛИОШИБКА(--ПСТР(ПОДСТАВИТЬ(ПОДСТАВИТЬ(ПОДСТАВИТЬ(ПОДСТАВИТЬ(ПОДСТАВИТЬ(" "&ссылка_на_ячейку_с_данными_с_закреплением_столбца;"(";);",";);":";" ");")";);" ";ПОВТОР(" ";99));СТОЛБЕЦ(ссылка_на_любую_ячейку_в_1_столбце)*99;99); )
Изменено: Андрей Лящук - 25 Мар 2020 15:25:08
 
На вкладке 2 те же самые данные - тока сдвинул на 2 столбца. Как сделать так чтобы считалось правильно? Столбец откреплял, не помогает
Попробовал поменять местами привязку к столбцам. Вроде получилось:
=ЕСЛИОШИБКА(--ПСТР(ПОДСТАВИТЬ(ПОДСТАВИТЬ(ПОДСТАВИТЬ(ПОДСТАВИТЬ(ПОДСТАВИТЬ(" "&D2;"(";);",";);":";" ");")";);" ";ПОВТОР(" ";99));СТОЛБЕЦ($H2)*99;99);)
Изменено: Jesuit - 25 Мар 2020 17:56:43
 
Код
=ЕСЛИОШИБКА(--ПСТР(ПОДСТАВИТЬ(ПОДСТАВИТЬ(ПОДСТАВИТЬ(ПОДСТАВИТЬ(ПОДСТАВИТЬ(" "&ИНДЕКС(2:2;ПОИСКПОЗ("Score";$1:$1;));"(";);",";);":";" ");")";);" ";ПОВТОР(" ";99));(СТОЛБЕЦ()-ПОИСКПОЗ("Score";$1:$1;))*99;99);)
 
А вот это прям много лучше! СПАСИБО! )
Страницы: 1
Читают тему (гостей: 1)
Наверх