<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet version="1.0"
                xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
                xmlns:xs="http://www.w3.org/2001/XMLSchema"
                xmlns:fn="http://www.w3.org/2005/xpath-functions"
                xmlns:msxsl="urn:schemas-microsoft-com:xslt"
                xmlns:exsl="http://exslt.org/common"
                extension-element-prefixes="msxsl exsl"
                exclude-result-prefixes="xs fn msxsl exsl">
    <msxsl:script language="JScript" implements-prefix="exsl">
        this['node-set'] = function(x) {return x;}
    </msxsl:script>
    <xsl:decimal-format name="ru-ru" decimal-separator="," grouping-separator=" " />
    <xsl:output method="html" encoding="windows-1251" indent="yes"/>
    <xsl:template match="/Dmctl2.doc">
        <xsl:variable name="ds209" >
            <xsl:for-each select="DataSet[string(@Id)='209']">
                <xsl:variable name="rows" select="Records/*"/>
                <xsl:for-each select="$rows">
                    <xsl:element name="_">
                        <xsl:attribute name="f0"><xsl:value-of select="@f0"/></xsl:attribute>
                        <xsl:attribute name="f1">
                            <xsl:call-template name="ParentRec">
                                <xsl:with-param name="rows" select="$rows"/>
                                <xsl:with-param name="id" select="string(@f3)"/>
                                <xsl:with-param name="str" select="string(@f5)"/>
                            </xsl:call-template>
                        </xsl:attribute>
                    </xsl:element>
                </xsl:for-each>
            </xsl:for-each>
        </xsl:variable>
        <xsl:variable name="date" >
            <xsl:for-each select="//DataSet[string(@Id)='108']//r0/@f20">
                <xsl:choose>
                    <xsl:when test="function-available('msxsl:format-date')">
                        <xsl:value-of select="msxsl:format-date(.,'dd.MM.yyyy')"/>
                    </xsl:when>
                    <xsl:otherwise>
                        <xsl:variable name="md" select="substring-after(.,'-')"/>
                        <xsl:value-of select="concat(substring-after($md,'-'),'.',substring-before($md,'-'),'.',substring-before(.,'-'))"/>
                    </xsl:otherwise>
                </xsl:choose>
            </xsl:for-each>
        </xsl:variable>
        <xsl:variable name="ds106" select="//DataSet[string(@Id)='106']/Records"/>
        <xsl:variable name="ds226" select="//DataSet[string(@Id)='226']/Records"/>
        <table id="ds300">
            <tr>
                <th>Дата</th><th>f18</th><th>Место реализации</th><th>f19</th><th>Товарная группа</th><th>f20</th><th>f20_value</th>
                <th>Товар</th><th>Количество</th><th>Закупка</th><th>Сумма закупки</th><th>Продажа</th><th>Сумма продажи</th>
            </tr>
            <xsl:for-each select="DataSet[string(@Id)=string(current()/Dmctl2.doc.props/@DocId)]/Records/*">
                <xsl:variable name="RowCount" select="count(../*)"/>
                <xsl:variable name="buy" select="@f1 div 10000"/>
                <xsl:variable name="sell" select="@f2 div 10000"/>
                <xsl:element name="tr">
                    <xsl:if test="position()=1"><td rowspan="{$RowCount}"><xsl:value-of select="$date"/></td></xsl:if>
                    <td><xsl:value-of select="string(current()/@f18)"/></td>
                    <td><xsl:value-of select="$ds106/*[string(@f0)=string(current()/@f18)]/@f1"/></td>
                    <td><xsl:value-of select="current()/@f19"/></td>
                    <td><xsl:value-of select="exsl:node-set($ds209)/*[string(@f0)=string(current()/@f19)]/@f1"/></td>
                    <td><xsl:value-of select="string(current()/@f20)"/></td>
                    <td><xsl:value-of select="$ds226/*[string(@f0)=string(current()/@f20)]/@f1"/></td>
                    <td><xsl:value-of select="@f34"/></td>
                    <td><xsl:value-of select="@f9"/></td>
                    <td><xsl:value-of select="format-number($buy,'#,####','ru-ru')"/></td>
                    <td><xsl:value-of select="format-number($buy*@f9,'#,####','ru-ru')"/></td>
                    <td><xsl:value-of select="format-number($sell,'#,####','ru-ru')"/></td>
                    <td><xsl:value-of select="format-number($sell*@f9,'#,####','ru-ru')"/></td>
                </xsl:element>
            </xsl:for-each>
        </table>
    </xsl:template>
    <xsl:template name="ParentRec">
        <xsl:param name="rows"/>
        <xsl:param name="id"/>
        <xsl:param name="str"/>
        <xsl:variable name="row" select="$rows[string(@f0)=$id]"/>
        <xsl:choose>
            <xsl:when test="count($row/@f4)>0">
                <xsl:call-template name="ParentRec">
                    <xsl:with-param name="rows" select="$rows"/>
                    <xsl:with-param name="id" select="string($row/@f3)"/>
                    <xsl:with-param name="str" select="concat(concat(string($row/@f5),'|'),$str)"/>
                </xsl:call-template>
            </xsl:when>
            <xsl:otherwise>
                <xsl:choose>
                    <xsl:when test="string($row/@f5)!=''">
                        <xsl:value-of select="concat(concat(string($row/@f5),'|'),$str)"/>
                    </xsl:when>
                    <xsl:otherwise>
                        <xsl:value-of select="$str"/>
                    </xsl:otherwise>
                </xsl:choose>
            </xsl:otherwise>
        </xsl:choose>
    </xsl:template>
</xsl:stylesheet>