Страницы: 1
RSS
Расположить значения в порядке убывания их чисел
 
Помогите изменить формулу. Нужно чтобы значения распологались в порядке убывания их чисел. Пример прикрепляю.
 
доп столбцы допустимы
Лень двигатель прогресса, доказано!!!
 
Да, допустимы. Спасибо, вполне подойдет!
 
А можно ли сделать так, что если количество 0 или пустая ячейка, в результатах тоже бы ничего не было, а то отображаются буквы.
И сверхмаленькая просьба: а не массивную формулу можно сделать?
 
Без доп столбцов формула массива. Ошибку можно скрыть функцией ЕСЛИОШИБКА()
Код
=ВПР(НАИБОЛЬШИЙ(C$2:C$29-СТРОКА(C$2:C$29)%;F7);ЕСЛИ({1;0};C$2:C$29-СТРОКА(C$2:C$29)%;B$2:B$29);2;)
Алексей М.
 
А как же её (ЕСЛИОШИБКА()) в эту формулу, или формулу Сергея, вставить?
Простите, но с простыми формулами то сложность, а замудреные вообще боишься трогать.
 
Код
 =ИНДЕКС($B$2:$B$20;ПОИСКПОЗ(НАИБОЛЬШИЙ(C$2:C$20-СТРОКА($C$2:$C$20)%%%;$F2);C$2:C$20-СТРОКА($C$2:$C$20)%%%;))
Соблюдение правил форума не освобождает от модераторского произвола
 
Цитата
dim284 написал:
А как же её (ЕСЛИОШИБКА()) в эту формулу
Если данных больше 100, то добавьте еще по одному % в двух местах
Код
=ЕСЛИОШИБКА(ВПР(НАИБОЛЬШИЙ(C$2:C$29-СТРОКА(C$2:C$29)%;F7);ЕСЛИ({1;0};C$2:C$29-СТРОКА(C$2:C$29)%;B$2:B$29);2;);"")
Изменено: АlехМ - 01.04.2020 14:10:30
Алексей М.
 
Смотрите приложение с формулой без дополнительных столбцов
Код
=IFERROR(INDEX(B$1:B$200;AGGREGATE(15;6;ROW($1:$200)/(C$1:C$200=LARGE(C$1:C$200;F2))/(COUNTIF(I$1:I1;B$1:B$200)=0);1));"")
 
Все равно не получается, я тоже так пробовал. Дело в том, что ноль или пустая ячейка в столбце С. А в данной формуле ЕСЛИОШИБКА ставит пусто если ноль или ничего в столбце F, а это не верная постановка задачи, нужно ориентироваться на столбец С. Посмотрите пожалуйста ещё разок.
Изменено: dim284 - 01.04.2020 14:56:54
 
Цитата
dim284 написал:
Все равно не получается
Если вы используете формулу из сообщения №8 и она выводит значения против пустых ячеек, значит вы с излишком протянули номера в столбце F
Для номеров можно применить формулу. Для ячейки F2
Код
=ЕСЛИ(СТРОКА(A1)>СЧЁТЕСЛИ(C:C;">0");"";СТРОКА(A1))
Алексей М.
 
AlexM, сажите пожалуйста, а можно как-то объединить эти две формулы. Дело в том, что в действительности у меня много столбцов с данными. Прикрепляю файл.
jakim мне Ваша формула очень нравиться, но на большом количестве данных что-то где-то не так, не пойму. Посмотрите пожалуйста Лист2 ячейка E73.
 
Если объединять, то ЕСЛИОШИБКА() не нужна
Код
=ЕСЛИ(СТРОКА(A1)>СЧЁТЕСЛИ(C:C;">0");"";ВПР(НАИБОЛЬШИЙ(C$2:C$29-СТРОКА(C$2:C$29)%;F2);ЕСЛИ({1;0};C$2:C$29-СТРОКА(C$2:C$29)%;B$2:B$29);2;))
Алексей М.
 
Все получилось, всем большое СПАСИБО!

Остановился на формуле AlexM, вот она, формула счастья:
=ЕСЛИ(СТРОКА(A1)>СЧЁТЕСЛИ(D$2:D$65,">0"),"",ВПР(НАИБОЛЬШИЙ(D$2:D$65-СТРОКА(D$2:D$65)%,$C72),ЕСЛИ({1;0},D$2:D$65-СТРОКА(D$2:D$65)%,$C$2:$C$65),2,))

Отдельное спасибо AlexM!
 
Формулу немного исправил.
Код
=IFERROR(INDEX($C$2:$C$65;AGGREGATE(15;6;ROW($1:$65)/(D$2:D$65=LARGE(D$2:D$65;$C72))/(D$2:D$65>0)/(COUNTIF(D$71:D71;$C$2:$C$65)=0);1));"")
 
Спасибо Jakim, все работает!
Страницы: 1
Наверх