VBA. ВПР данных с разных листов

Пользователь

Сообщений: 15 Регистрация: 01.01.1970

03.04.2020 22:26:05

Доброго времени суток, форумчане!

Нужен совет, в каком направлении двигаться в моем вопросе. Пока что не могу даже конкретизировать свой запрос для гуглирования

Задачка с примером во вложении:

хочется, чтобы при запуске макроса в файле1 в ячейку вставлялась формула ВПР, которая подтягивает значение из файла2. Просто сделать ВПР из нужного листа и перенести это в VBA не проблема. Сложность в том, что в файле 2 имеются отдельные листы с данными для каждой недели (формат названия листа: 14_нед, где 14- номер текущей недели). И макрос/формула должны возвращать значения с определенной недели (например указанной в названии столбца)

Такое вообще возможно?

Прикрепленные файлы

файл1.xlsx (11.15 КБ)
файл2.xlsx (10.48 КБ)

Kuzmich

Пользователь

Сообщений: 8050 Регистрация: 21.12.2012

03.04.2020 23:41:06

Цитата
хочется, чтобы при запуске макроса в файле1

При условии, что оба файла открыты и в файле2 ("Файл2.xls") точно есть листы с номерами недели,
макрос в стандартный модуль файла1

Код

Sub SborFromFile2()
Dim i As Long
Dim iLastRow As Long
Dim j As Integer
Dim FoundCell As Range
Dim File2 As Workbook
Dim iFile2ShtName As String
  Set File2 = Workbooks("Файл2.xls")
   iLastRow = Cells(Rows.Count, "A").End(xlUp).Row
   Range("B3:D" & iLastRow).ClearContents
  For i = 3 To iLastRow
    For j = 2 To 4
      iFile2ShtName = Cells(2, j) & "_нед"
      With File2.Worksheets(iFile2ShtName)
       Set FoundCell = .Columns(1).Find(Cells(i, "A"), , xlValues, xlWhole)
       If Not FoundCell Is Nothing Then
         Cells(i, j) = .Cells(FoundCell.Row, 2)
       End If
      End With
    Next
  Next
End Sub

Александр Пользователь Сообщений: 15 Регистрация: 01.01.1970	#3 04.04.2020 13:12:46 Kuzmich, Низкий Вам поклон! С помощью гугла переделал все это под свои потребности, работает на отличненько!