Страницы: 1
RSS
Найти ближайшее время ранее заданного по условию..
 
Добрый день.
есть проблема...

Необходимо для ячейки "номер ТС" найти с листа "ТС" ближайшую дату которая меньше указанной в стоблце С и вставить в столбец E/
Например: в ячейку Е3 необходимо с листа "ТС" подставить дату которая меньше чем дата в ячейке "С3" при условии что ячейки "Номер ТС" одинаковые.



Заранее огромное спасибо!!!!
 
№ ТС на листе ТС идет всегда группой не может быть один № в начале списка группой а потом появится в другом месте среди других номеров
Лень двигатель прогресса, доказано!!!
 
Может. Если это добавляет проблем то буду сортировать по номеру ТС.  
 
МАССИВНАЯ
Код
=МАКС(ЕСЛИ(ИНДЕКС(ТС!C:C;ПОИСКПОЗ(B2;ТС!A:A;0)):ИНДЕКС(ТС!C:C;ПОИСКПОЗ(B2;ТС!A:A;0)+СЧЁТЕСЛИ(ТС!A:A;B2)-1)<=C2;ИНДЕКС(ТС!C:C;ПОИСКПОЗ(B2;ТС!A:A;0)):ИНДЕКС(ТС!C:C;ПОИСКПОЗ(B2;ТС!A:A;0)+СЧЁТЕСЛИ(ТС!A:A;B2)-1)))
Лень двигатель прогресса, доказано!!!
 
Огромное спасибо!!!!
 
Формула без массивного ввода
Код
=IFERROR(INDEX(ТС!C$2:C$5000;AGGREGATE(14;6;ROW($1:$5000)/(ТС!C$2:C$5000>C2)/(ТС!A$2:A$5000=B2);1));"")
 
для ИД обычная
Код
=ПРОСМОТР(2;1/(ИНДЕКС(ТС!C:C;ПОИСКПОЗ(B2;ТС!A:A;0)):ИНДЕКС(ТС!C:C;ПОИСКПОЗ(B2;ТС!A:A;0)+СЧЁТЕСЛИ(ТС!A:A;B2)-1)=E2);ИНДЕКС(ТС!B:B;ПОИСКПОЗ(B2;ТС!A:A;0)):ИНДЕКС(ТС!B:B;ПОИСКПОЗ(B2;ТС!A:A;0)+СЧЁТЕСЛИ(ТС!A:A;B2)-1))
Лень двигатель прогресса, доказано!!!
 
Дата+время, выдает ближайшее меньшее дата+время
Код
=АГРЕГАТ(14;6;1/(B2=ТС!$A$2:$A$1826)/(C2>ТС!$C$2:$C$1826)*(ТС!$C$2:$C$1826);1)

ИД на основе полученной даты
Код
=АГРЕГАТ(14;6;1/(B2=ТС!$A$2:$A$1826)/(E2=ТС!$C$2:$C$1826)*(ТС!$B$2:$B$1826);1)


Если нужна только дата
Код
=АГРЕГАТ(14;6;1/(B3=ТС!$A$2:$A$1826)/(ЦЕЛОЕ(C3)>ЦЕЛОЕ(ТС!$C$2:$C$1826))*(ЦЕЛОЕ(ТС!$C$2:$C$1826));1)
Изменено: kain - 19.05.2020 19:52:47
 
Огромное спасибо ВСЕМ за помощь, все работает.  
 
bill12, в армию забирали  :)  
Лень двигатель прогресса, доказано!!!
 
Да нет. После твоего сообщения не заглядывал, а сегодня понадобилась заглянул, а тут еще вариантов накидали!!!
Страницы: 1
Наверх