Option Explicit

' Удаляет из листа Excel скрытые строки.
' Возвращает число удаленных строк
' - r: прямоугольный диапазон (объект, имя, адрес), строки которого анализируются
Function RangeDeleteHiddenRows(ByVal r) As Long
    Dim rg As Range, sh As Worksheet, arr(), i As Long, row As Range, n As Long, rg1 As Range
    If IsObject(r) Then
        Set rg = r
    Else
        Set rg = Range(r)
    End If
  
    Set rg = rg.CurrentRegion
    Set sh = rg.Parent
    ReDim arr(1 To rg.Rows.Count, 1 To 1)   ' для сортировки
    For Each row In rg.Rows
        i = i + 1
        If row.EntireRow.Hidden Then
            n = n + 1 ' счетчик скрытых строк
            arr(i, 1) = 10000000 + i
        Else
            arr(i, 1) = i
        End If
    Next row
  
    If n = 0 Then
        Exit Function
    End If
  
    If rg.Column + rg.Columns.Count > sh.Columns.Count Then
        Exit Function     ' последний столбец листа заполнен
    End If
  
    Set rg = rg.Resize(, rg.Columns.Count + 1) ' захватываем столбец
    Set rg1 = rg.Columns(rg.Columns.Count)
    If sh.FilterMode Then
        rg.AutoFilter   ' убираем автофильтр
    End If
  
    rg1.Value = arr
    rg.Sort rg1
    rg1.ClearContents
    rg.Offset(rg.Rows.Count - n).Resize(n).EntireRow.Delete
    RangeDeleteHiddenRows = n
End Function

' Удаляет скрытые строки из всех листов книги
Sub DeleteHiddenRows()
  Dim sh As Worksheet
  For Each sh In ActiveWorkbook.Worksheets
    RangeDeleteHiddenRows sh.UsedRange
  Next sh
End Sub